is their anyway to get the 7zip archives not to show the extraction process?

@j4ever: I'm in contact with Igor about that.

And OMG, I'm on Suprnova! (OK, a torrent of the .NET pack I made is anyway ). Come to think of it, a custom XP CD with my old RAID pack was on there once upon a time too.

LOL yeah...earlier today when i was checking it for UltraISO 7.22 i saw your file on there. LOL that was very funny.

I do not know who i was, but thanks for the tip on msiexec for Windows XP SP1 and SP2 beeing different. I created a package for SP2 in SP1 and I did not get it to work. When creating it from SP2 it did work.

I do not know who i was, but thanks for the tip on msiexec for Windows XP SP1 and SP2 beeing different. I created a package for SP2 in SP1 and I did not get it to work. When creating it from SP2 it did work.

Hmm, actually it should be the other way round.

An msiexec.exe from SP1 should run on both SP1 and SP2. But the msiexec.exe from SP2 only runs on SP2.

And I have yesterday read this topic again, posts from the last weekend, and FINALLY solved my problem with installing NETfxSP1 which didn't succeed for me after the more then several attempts in unattended installation.

after adding MSXMLSP2 patch too (thanx RyanVM ) the symptoms were the same:

Windows Installer popups, but it wasn't follwed by the application (NET, MSXML) popup.

It clicks to me that I've set the renaming of Administrator account PRIOR to installing MS apps (strangely - Adobe Reader and FFDshow installs with no problem even the account was renamed).

I changed the order and now everything works like a charm

OK, I made some more tests on an XP-SP2-install and everything runs fine so far. Would be nice if XP-SP1-users could test this out.

Here is a small guide how to create your own:

Start the make.bat and wait 2 minutes. At the end you should have a netfxsp1.exe in your folder with a size of about 11.3 MB.

You can run this standalone file through svcpack.inf or any other batch without any commandline switches. But if you use a batch instead of svcpack.inf you should use the start-command:

start /wait netfxsp1.exe

Absolutely brilliant instructions. Perfect example of what a Guide for dummies/newbies should read like.

Great work. Thanks a ton.

just thought I would pass this attachment along.. made this myself.

its a autoit script for Don Net Frame Work 1.1

along with another one... for the sp1 update for it...

just point them to the exe's no silent switches needed...

just make sure frame work 1.1 is set to install first.. then the sp1 update after...

read the scripts before compiling.. set your file names to be correct... in the script... nither file has to be extracted....

its just put it in directory.... and rename and there ya go

piece out see ya.. have fun guys!

Framework 1.1 Auto It

Dotnet11.au3

Frame Work 1.1 Sp1 Update Auto It

Dotnetsp1.au3

Don't wanna sound like a nark a lotta trouble to go to Cybri2k but the self extracting version that RyanVM has forwarded does all this & its very small in size?

*Nevermind, I can't read.*

EDIT: But yes, I think the admin install point is considerably better than AutoIt.

Is posible to add langpack.exe (Spanish) to the admin install point?

The files extracted are:

langpac1.cab

langpack.msi

inst.exe

setup.ini

Off topic: Attempting to do the same trick with Adobe Reader 6.0.1 (Spanish), I notice that the original package, "Package for the web", compress much better than 7zip; even if msiexec is removed.

Is posible to add langpack.exe (Spanish) to the admin install point?

Not directly. You can't integrate it to the installpoint of .NET (as far is I know) but you can create an own installpoint for it and pack both into one sfx.

Here is a version that I use to also include JViewer and HighMAT into the same SFX so they all compress better. Just put your langpack.exe in the same folder as described in my guide and create this batch file as make.bat:

SET TmpDir=%~dp0tmp

SET BuildDir=%~dp0build\

%~d0

CD "%~p0"

MD "%TmpDir%"

MD "%BuildDir%"

MD "%BuildDir%netfxsp1"

START /wait dotnetfx.exe /C /T:"%TmpDir%"

START /wait NDP1.1sp1-KB867460-X86.exe /XP:"%TmpDir%"

CD "%TmpDir%"

START /wait msiexec /a netfx.msi TARGETDIR="%BuildDir%netfxsp1" /QB

START /wait msiexec /p S867460.msp /a "%BuildDir%netfxsp1\netfx.msi"

CD..

RMDIR /S /Q tmp

COPY StartX.exe "%BuildDir%StartX.exe"

CD "%BuildDir%"

ECHO START /WAIT /Dnetfxsp1 msiexec.exe /i netfx.msi /qb>install.bat

CD..

SET Target=langpack

IF EXIST %Target%.exe CALL :make_add

SET Target=jviewer

IF EXIST %Target%.exe CALL :make_add

SET Target=Q831240

IF EXIST %Target%.exe CALL :make_add

CD "%BuildDir%"

..\7za.exe a "%~dp0netfxsp1.7z" -r -mx=7 -mfb=255 -md=48m *

CD..

RMDIR /S /Q "%BuildDir%"

COPY 7zS.sfx 7zSC.sfx

upx.exe 7zSC.sfx

ECHO ;!@Install@!UTF-8!>config.txt

ECHO RunProgram="StartX.exe /WAIT /B \"install.bat\"">>config.txt

ECHO ;!@InstallEnd@!>>config.txt

COPY /b 7zSC.sfx + config.txt + netfxsp1.7z netfxsp1.exe

DEL 7zSC.sfx

DEL config.txt

DEL netfxsp1.7z

GOTO:EOF

:make_add

MD "%TmpDir%"

MD "%BuildDir%%Target%"

START /wait %Target%.exe /C /T:"%TmpDir%"

CD "%TmpDir%"

SET MsiName=

FOR %%I in (*.*) DO IF /I "%%~xI" == ".MSI" SET MsiName=%%I

START /wait msiexec /a "%MsiName%" TARGETDIR="%BuildDir%%Target%" /QB

CD..

RMDIR /S /Q tmp

CD "%BuildDir%"

ECHO START /WAIT /D%Target% msiexec.exe /i "%MsiName%" /qb>>install.bat

CD..

GOTO:EOF

If you want to also include JViewer and/or HighMAT just copy JViewer.exe and/or Q831240.exe to the folder and the batch will automatically include them to the netfxsp1.exe.

@bitmonster

If I get you right your installing the .netfx1.1sp1 plus the language pack, highmat and jviewer all at the same time with this script? Also, while looking over the code, it seems to be missing some of it, such as where is EOF, and wont it cause an error without it? It looks as if it should be just before the line:

:make_add

instead of

GOTO:EOF

two lines above it, unless there is more to it?

One more question, while I am at it, in the following:

ECHO START /WAIT /Dnetfxsp1 msiexec.exe /i netfx.msi /qb>install.bat

what is a /Dnetfxsp1 switch?

Edited September 29, 200421 yr by DisabledTrucker