Jump to content

Up-to-date Windows 2000 universal install media creation guide


Kurt_Aust

Recommended Posts

Some of you might also be interested in these similar guides for Windows 98se, XP x32 SP4 or XP x64 SP2.

So you want to create a fully up-to-date Windows 2000 installation CD / DVD ?  Well here's how (minor update for December 2019).

Important Security Notice: As Windows 2000 has been out of support since July 2010 and no major web browser (or plugin) still supports it, it is not safe to use Windows 2000 on an Internet facing machine.  At this stage Windows 2000 is mainly recommended for use in a virtual machine or on unconnected old hardware to run legacy applications.  If you wish to use old hardware connected to the Internet a Linux Distribution is a much safer choice.


First you are going to need some files: is a direct link to the executable
Microsoft's download pages for Windows 2000 seem to be going MiA of late, so if you can't find what you're looking for there try Tomasz86's archive.

From MediaFire, the Config2000sp5_date.7z file and extract it, this will also setup the necessary directory structure (read \Misc\FileList.txt for contents).

From MediaFire the Unofficial Windows 2000 Service Pack 5.1.2195.24 Refresh (w2ksp51.exe) and save it to \Misc\.
SHA-1: A422A40C062989BFE95AA428C094321E82394ACC

EXTRACT the February 2010 (June fails) DirectX redistributable to \W2K\DirectX\ (you can get back 45MB by deleting the x64.cab files).
SHA-1: A97C820915DC20929E84B49646EC275760012A42


Now you can either:
Download the current Hotfix 7-Zip archives from MediaFire, extracting them into the same directory that you chose to extract the Config archive into, this method is recommended for new users.
A - SHA-1: B893A40F31CFF4E4C44CED54EFF7BF20E47CA99E - 95 files that won't change
B - SHA-1: 98B8720F5995F6DD8B642A1F2FF7B4AF66448E88 - 33 files that might change
C - SHA-1: 7A8EDCF7CAAF8106A56CD7D14AC98C89070404DB - 9 files being .Net 2.0 sp2
OR
Open the Hotfix2000sp5_date.torent (from \Misc\) into the same directory that you chose to extract the Config archive into.  Due to slow speed (about 36 hours for a full download) this method is recommended for returning users updating their hotfix list, it can also be used to error check the downloads.  They both have the contents listed in the next post.

If you prefer to directly download all the hotfixes, \Misc\UpdatePrep.bat will rename them (and the optional applications) as appropriate.  If you've done everything correctly \Hotfix\ should have 77 files 81,544,808 and \W2K\RunOnce\ should have 37 files 148,245,434.

Of course you won't get very far without \Misc\nLite and a Windows 2000 install CD.


Now it's time to fire up nLite.
NB: must be run with administrator privileges, might need to disable anti-virus software, Vista/Win7/Win8/Win10 users should run in XP compatibility mode and there is an archive of screenshots available at my MediaFire page.

  1. Run \Misc\UpdatePrep.bat
  2. Locate your source (my session file is located at \Misc\Win2000sp5.ini, you should probably use it as a base).
  3. Slipstream the unofficial service pack 5 (\Misc\w2ksp51.exe), this must be done on a Win NT 5.x host (2000/XP/XPx64/2003/2003x64).
  4. Add all the hotfixes listed in the \Hotfix\ directory (use Crtl-A, check the order) and any ProgramAddons.cab files (see notes part 1).
  5. If NOT using the DriverPacks add any drivers you may need here, especially textmode SATA AHCI & RAID drivers (Intel, nVidia).  I've found that 7-Zip will extract some things WinRAR won't (also see notes part 2).
  6. Unattended settings, this is the most important one.  Your RunOnce file should look like this:
     
    Ping -n 61 127.0.0.1 > nul
    For %%I in (Z Y X W V U T S R Q P O N M L K J I H G F E D) do if exist %%I:\W2K\Run1.bat set Drive=%%I&& goto Found
    :Found
    CMD /R "%Drive%:\W2K\Run1.bat %Drive%"

    You must also set it to autologon twice to an administrator class account (read the note), fully automated mode would be an excellent idea Smithers.
  7. Make any tweaks you want, then run the process.
  8. If using the DriverPacks add them now (note 2 below).
  9. If your device can read from a DVD then you can copy the \W2K\ folder and all its contents to your nLite working directory (\W2K\AddOns\ contains optional files, see notes part 1) OR
  10. If your device can only read from a CD then copy the \W2K\ folder and all its contents to a USB flash drive.  If you've added the DriverPacks delete the BootDisk, Discover, Support & ValueAdd folders from your nLite working directory.  In this case when applications change you only need update the USB stick.
  11. After you drag n drop anything else that you may want / need, go ahead and burn that image / CD / DVD (unfortunately no utility supports W2K installation via USB stick).


Installation
Ensure the PC is disconnected from the internet, set your HDD as the first boot device and then insert the DVD (or CD + USB flash drive).  Boot to the CD/DVD using BIOS boot options and then follow the standard textmode installation steps. If you have gone for the fully unattended / autologon x2 option, then all you have to do is let it be for roughly 2 hours (assuming lots of AddOns).  If you have a removable media drive, you might get "No Disk" messages on the first reboot, just "Continue".  The system will be ready for use when a logon box is waiting for your input.

Notes:

Part 1: Application addons (do not place multiple versions of the same application in \W2K\AddOns\)
nLite supports the use of ProgramAddOns.cab (or .zip/.rar/.7z) files at the hotfix integration step, however a lot of programs no longer work with Windows 2000 and often the older AddOn.cab files are no longer available.  Hence the batch files have been written to support a number of key applications for which links are provided below, simply save them to \W2K\AddOns\ (\Misc\UpdatePrep.bat will rename some).  Unless otherwise noted these are the last versions to work on Windows 2000 and they will work with minimal rights (guest account).

It should be obvious, but installing these applications is completely optional, for instance there is very little point in installing both supported PDF readers.  If you want to include something not listed below then add the appropriate silent install command to the batch files.

For internet connectivity set your browser's home page to http://kproxy.com/ or http://jailbreaked.net/ (converts https to http)

Recommended
dexpot_1518_r2098.exe multiple desktops
ToolTipFixer 2.0.0.exe stops tooltips hiding behind taskbar
Firefox Setup 10.0.12esr.exe web browser
install_flash_player_32bit-11-1-102-55.exe plugin for Firefox, Seamonkey & Opera
jre-6u31-windows-i586.exe Java runtime enviroment
LibO_3.6.7.2_Win_x86_install_multi.msi office suite, US Help, GB Help, spell check info (corner case 2)
FoxitReader543.0920_enu.msi PDF reader
iview444_setup.exe photo viewer/editor iview444_plugins_setup.exe
DOSBox*.**-*-win32-installer.exe DOS emulator - still works as of version 0.74-3
FileZilla_3.7.4.1_win32-setup.exe FTP client
DTLite4356-0091.exe virtual CD/DVD drive, requires SPTDinst-v***-x86.exe - SPTD still works as of version 1.90
SetupImgBurn_*.*.*.*.exe DVD burner - still works as of version 2.5.8.0, requires NeroBurnRightsInstaller.exe for non-admin accounts
K-Lite_Codec_Pack_710_Mega.exe media player, lots of stuff option
ultradefrag-6.1.2.bin.i386.exe advanced disk defrag utility, requires Admin rights
CFP_Setup_English_2.4.18.184.exe Comodo firewall - requires Comodo2.exe (a basic AutoIt script) - manual
Supported
Opera_1164_int_Setup.exe web browser
Thunderbird Setup 12.0.1.exe email client
SeaMonkey Setup 2.9.1.exe web browser & email client
Shockwave_Installer_Full-11-6-1-629.exe browser plugin
Silverlight-4-1-10329-0.exe browser plugin
SumatraPDF-2.1.1-install.exe PDF reader
gimp-2.6.7-i686-setup.exe Photoshop replacement gimp-help-2-2.6.0-en-setup.exe
nLite-1.4.9.3.setup.exe requires Admin rights
VirtualBox_1.5.6-1_Win_x86.msi virtual machine
GoogleEarthWin-5-1-3535-3218.exe
Vuze_5600_Installer32.exe BitTorrent client, can upgrade to latest version (5760) except for Platform-specific support plugin then run \W2K\AddOns\VuzeFix.cmd
uTorrent-3-1-2-26821.exe BitTorrent client
SetupAnyDVD7690.exe break DVD region coding
dvdshrink32setup.exe DVD backup utility
cdbxp_setup_*.*.*.****_minimal.exe DVD burner - still works as of version 4.5.8.7128, requires .Net 2.0
vlc-1.1.11-win32.exe media player
Quicktimealt181lite.exe QuickTime plugin for use with K-Lite Mega Codec Pack
Real_Alternative_202_Lite.exe RealMedia plugin for use with K-Lite Mega Codec Pack


Part 2: Bashrat the Sneaky's Driver Packs (3rd party DriverPacks not supported)
Adding the DriverPacks to your install media allows you to create a universal install media, however while almost all chipset, storage, networking, video and audio drivers are included not all classes of drivers are supported, for instance no modem or bluetooth drivers will be included on your install media unless you run that hardware's silent installer (integrating them at step 5 will likely fail).

This setup will work with the DriverPacks finisher, however due to the forced reboot at the end of \W2K\Run1a.bat you must use the custom finisher method.  Hence the %SystemDrive%\DPsFnshr.exe line in \W2K\Run2.bat (this has only been tested with slipstream method 2). Again you should either use the DriverPacks at step 8 or add drivers at step 5, not both.

If you get an "out of memory" or "file is corrupt" error during the textmode section of installation, then do NOT integrate the mass storage DriverPack as textmode (you can rerun DPbase to remove mass storage textmode).  In this case you'll have to integrate any mass storage drivers you need with nLite at step 5 (or use a floppy).  In Virtual PC 2007 there was an error about a denied request to install / upgrade a game port, but that did not appear to hinder the installation.

As there are some problems with the latest DriverPacks releases when working with W2K, I recommend using the May 2008 versions of the DriverPacks, available via MediaFire or torent.  My settings file is located at \Misc\DPs_BASE.ini, you may wish to use it as a base.


Part 3: Official Microsoft hotfixes released after July 2010
Microsoft has released a few hotfixes for Windows 2000 after support was officially terminated, however these are not included in the base download as they lack the widespread community testing the other hotfixes have received.  If you wish to include them they are available as a seperate archive from MediaFire.

Another useful addition is Legacy Update which reroutes Windows Update so that it still works with older versions of Windows, unfortunately it can't be installed offline and isn't quite complete as it still depends on the whims ofMicrosoft.

 

Part 4: Optional components (currently GrantAccess/SubInACL & SchTasks)
Any small (<2MB) but useful optional components will be placed in the \W2K\AddOns\ directory.  The batch files will be written to support their installation if \W2K\AddOns\ is copied to the install media.

SubInACL is a command line utility meant for network administrators, but it can be useful to us mere mortals as it makes running as a limited user feasible.  Using the "Access *" commands I only have to logon as the Administrator about once a fortnight.  Since I started setting up my friend's computers this way I haven't had to deal with the "I cancelled a print job and now my printer is gone" (they deleted the printer) or "Why do I get all these annoying pop-ups" (opened Amazing_Photos.pps.vbs) type service calls.  How many of us can truly say they have never clicked the wrong button or typed the wrong command?  Remember, the neck you save might just be your own.  To use this nifty utility on WinXP and later OS versions, install 7-Zip on the system and use \W2K\AddOns\GrantAccess.cmd on this version of GrantAccess.7z.

SchTasks.exe from XP SP2 (modified to work with Windows 2000) was originally used to launch \W2K\Run2.bat, so it's inclusion is a legacy item, none the less it does add advanced command line task scheduling abilities to Windows 2000.


Part 5: Testing
There are 3 free Virtualization programs that you can use to test your creation - Oracle VirtualBox (recommended), VMware Server/Player and Microsoft VirtualPC 2007.  Automatic installation of Virtual Machine drivers is supported, just place the appropriate *.iso file at \W2K\AddOns\ (you MUST include 7-Zip for this to work).

Oracle VirtualBox v6.x.x (64 bit only - Win7+, Linux), v5.2.44 or v4.3.40 (32 or 64 bit - WinXP-Win10, Linux) or v1.5.6.1 (Win2000)
Pros: Also good for virtualizing Linux, supports x64 guest OS's if CPU has AMD-V or VT-x
Cons: Will not virtualize Win9x easily, v2.2.4  & earlier - do NOT install Comodo Firewall on the guest
ISO: %ProgramFiles%\[Sun|Oracle]\VirtualBox\VBoxGuestAdditions.iso
Please read \Misc\VirtualBoxSetting.txt

VMware Player 15/16 (64 bit only - Win7{15}, Win8+{16}, Linux), VMware Player 12 (64 bit only, pre-2010 CPU - Windows, Linux),
VMware Player 6 (32 or 64 bit, Win8-) or VMware Server 1.0.10 (32 or 64 bit, Vista-)
Pros: Can virtualize just about anything, including x64 guest OS's (x64 support check)
Cons: Larger than the others, registration required for Server
ISO: %ProgramFiles(x86)%\VMware\VMware Server|Player\Windows.iso|WinPreVista.iso
If the BIOS flashes past too fast to access add bios.bootDelay = "5000" to the VMname.vmx config file

Microsoft VirtualPC 2007  & patch & patch (Host OS - XP to W7)
Pros: Easier to virtualize Win9x, guest usuable even without VM drivers
Cons: Will not virtualize non Microsoft OS's properly
ISO: %ProgramFiles%\Microsoft Virtual PC\Virtual Machine Additions\VMAdditions.iso


Part 6: .Net framework
The installers linked to in the downloads section were created by User Hidden (unfortunately Yumeyao's version is outdated), they are used rather than the  original Microsoft installers as they save considerable time and 90MB on your install media.  If you prefer to use the original files then delete the 2 dotNet*_UH_*.exe files and save the following 9 to \W2K\RunOnce\:

NetFx20SP2_x86.exe .. . . . . . . 25,001,480
NDP20SP2-KB958481-x86.exe . . . 8,981,856
NDP20SP2-KB2729450-x86.exe .. 14,682,632
NDP20SP2-KB2742596-x86.exe .. 10,264,104
NDP20SP2-KB2844285-v2-x86.exe 2,724,504
NDP30SP2-KB982524-x86.exe .. . 16,945,512

dotNetFx.exe .. . . . . . . . . . . . 24,265,736
NDP1.1sp1-KB867460-x86.exe . . 10,703,680
NDP1.1sp1-KB2833941-x86.exe . 15,908,664


Part 7: Unofficial Windows 2000 Service Pack 5.1.2195.21
Both Major Geeks and Softpedia host this older version of the service pack.  If at all possible the use of version 5.1.2195.24 via BitTorent or MediaFire is preferred, however if you must use this version then you will need 3 additional hotfixes:

Hotfix\010-Windows2000-KB913580-x86-ENU.exe 5,470,696
Hotfix\015-Windows2000-KB914388-x86-ENU.exe . 618,472
Hotfix\055-Windows2000-KB917537-x86-ENU.exe . 626,152


Part 8: Space / Time
A clean install CD with the DriverPacks (deleted the x64 DirectX cabs and the BootDisk, Discover, Support & ValueAdd folders) uses 687 MB.
An installation with ALL the applications and ALL the DriverPacks on my test virtual machine takes 45 minutes (keeping all the drivers).

System specs: Oracle VirtualBox running on Win 10 x64 Pro platform
Core i7-5930K (6-core, 3.5GHz, 15MB cache), 32GB RAM, 400GB NVMe PCIe SDD
The Virtual PC was allocated 2 CPU cores, 4GB RAM and a 16GB HDD on the SSD
No other applications were running during the test.

As these tests were performed using Oracle VirtualBox, please post about your real world experiences.

For those interested, here is how it works:

Gurglemeyer's excellent unofficial service pack 5 has most of the post service pack 4 updates and more importantly Internet Explorer 6 SP1, so once that is slipstreamed most of the updating is done.  The updates that are directly integrated are those that show up when you first run Windows Update on Win2000 SP5.

Note that because %Source% does not work with Windows 2000, nLite's RunOnce command has to search for \W2K\Run1.bat, this means having an unusual location\filename is important.  Here we install .Net 1.1 SP1 & .Net 2.0 SP2, DirectX 9.0c, some minor updates and the hotfixes that fail under nLite to integrate into the source.  Then once the desktop is initialised we force a system reboot as a restart is recommended between the installation of DirectX 9.0c and Windows Media Player 9 and is required for some of the application installs.

\W2K\Run1.bat

rem add command line TaskKill ability to Windows 2000
Copy %1:\W2K\RunOnce\Kill.exe %SystemRoot%
	rem add command line ShutDown ability to Windows 2000
Copy %1:\W2K\RunOnce\ShutDown.exe %SystemRoot%
	rem archive utility
Copy /B %1:\W2K\RunOnce\7z*.msi %Temp%\7z.msi
msiexec /I %Temp%\7z.msi /Passive /NoRestart /Log %Temp%\7zInstall.log
Del %Temp%\7z.msi
	rem first pass of updates
%1:\W2K\RunOnce\Windows2000-KB923191-x86-ENU.exe /Passive /NoRestart
%1:\W2K\RunOnce\Windows2000-KB924667-x86-ENU.exe /Passive /NoRestart
%1:\W2K\RunOnce\Windows2000-KB958470-x86-ENU.exe /Passive /NoRestart
%1:\W2K\RunOnce\Windows2000-KB973904-x86-ENU.exe /Passive /NoRestart
%1:\W2K\RunOnce\MDAC_TYP.exe /Q /C:"Setup /Q"
%1:\W2K\RunOnce\MDAC281-KB927779-x86-ENU.exe /Passive /NoRestart
%1:\W2K\RunOnce\rootsupd.exe
%1:\W2K\RunOnce\rvkroots.exe /Q
%1:\W2K\RunOnce\vcredist_x86_2005sp1c.exe /Q
%1:\W2K\RunOnce\vcredist_x86_2008sp1c.exe /Q
"%ProgramFiles%\7-Zip\7z.exe" X %1:\W2K\RunOnce\vcredist_x86_2010sp1c.exe -O%Temp%\VC2010 -Y
msiexec /I %Temp%\VC2010\vc_red.msi /Passive /NoRestart /Log %Temp%\VC2010Install.log
msiexec /P %Temp%\VC2010\msp_kb2565063.msp /Passive /NoRestart /Log %Temp%\VC2010Patch.log
RmDir /S /Q %Temp%\VC2010
%1:\W2K\RunOnce\dotNet20SP2_UH_Oct13.exe -ai1
%1:\W2K\RunOnce\dotNet11SP1_UH_Jul13.exe -ai1
	rem .Net silent install option
%1:\W2K\RunOnce\NetFx20SP2_x86.exe /Passive /NoRestart
%1:\W2K\RunOnce\NDP20SP2-KB958481-x86.exe /Passive /NoRestart
%1:\W2K\RunOnce\NDP20SP2-KB971111-x86.exe /Passive /NoRestart
%1:\W2K\RunOnce\NDP20SP2-KB2729450-x86.exe /Passive /NoRestart
%1:\W2K\RunOnce\NDP20SP2-KB2742596-x86.exe /Passive /NoRestart
%1:\W2K\RunOnce\NDP20SP2-KB2844285-v2-x86.exe /Passive /NoRestart
%1:\W2K\RunOnce\NDP20SP2-KB2972214-x86.exe /Passive /NoRestart
%1:\W2K\RunOnce\NDP20SP2-KB2972105-x86.exe /Passive /NoRestart
%1:\W2K\RunOnce\NDP20SP2-KB2979574-v2-x86.exe /Passive /NoRestart
%1:\W2K\RunOnce\NDP20SP2-KB2978124-x86.exe /Passive /NoRestart
%1:\W2K\RunOnce\NDP20SP2-KB3037577-x86.exe /Passive /NoRestart
%1:\W2K\RunOnce\NDP20SP2-KB3035488-x86.exe /Passive /NoRestart
%1:\W2K\RunOnce\NDP20SP2-KB3023220-x86.exe /Passive /NoRestart
%1:\W2K\RunOnce\NDP30SP2-KB982524-x86.exe /Passive /NoRestart
%1:\W2K\RunOnce\dotNetFx.exe /Q /C:"Install /Qb"
%1:\W2K\RunOnce\NDP1.1sp1-KB867460-x86.exe /Q
%1:\W2K\RunOnce\NDP1.1sp1-KB971108-x86.exe /Q
%1:\W2K\RunOnce\NDP1.1sp1-KB2833941-X86.exe /Q
	rem more updates
%1:\W2K\DirectX\DXsetup.exe /Silent
%1:\W2K\RunOnce\WindowsUpdateAgent30-x86.exe /Q /WUforce
Copy %SystemRoot%\Microsoft.NET\Framework\v2.0.50727\gdiplus.dll %SystemRoot%\System32\
	
rem silent installers go here
	
rem this makes running as a limited user feasible and uses no system resources
"%ProgramFiles%\7-Zip\7z.exe" X %1:\W2K\AddOns\GrantAccess.7z -O%SystemRoot% -X!*.lnk -R
If exist %1:\W2K\MenuReorg.bat "%ProgramFiles%\7-Zip\7z.exe" X %1:\W2K\AddOns\GrantAccess.7z -O"%AllUsersProfile%\Start Menu\Programs\Utilities" *.lnk -R
If not exist %1:\W2K\MenuReorg.bat "%ProgramFiles%\7-Zip\7z.exe" X %1:\W2K\AddOns\GrantAccess.7z -O"%AllUsersProfile%\Start Menu\Programs\Accessories" *.lnk -R
	rem add advanced command line task scheduling ability to Windows 2000
Copy %1:\W2K\AddOns\SchTasks.exe %SystemRoot%
	rem fix tooltips hiding behind taskbar
"%1:\W2K\AddOns\ToolTipFixer 2.0.0.exe" /S
	rem multiple desktops
%1:\W2K\AddOns\dexpot_1518_r2098.exe /S
Xcopy "%UserProfile%\Start Menu\Programs\Dexpot" "%AllUsersProfile%\Start Menu\Programs\Dexpot\" /e
	
rem alternate web browsers, Firefox ESR recommended
%1:\W2K\AddOns\Opera_1164_int_Setup.exe /Silent /NoRestart
If exist %1:\W2K\AddOns\Opera_1164_int_Setup.exe ping -n 21 127.0.0.1 > nul
Kill Opera.exe
	"%1:\W2K\AddOns\Firefox Setup 10.0.12esr.exe" /S /V"/Passive /NoRestart"
If exist "%1:\W2K\AddOns\Firefox Setup 10.0.12esr.exe" "%ProgramFiles%\7-Zip\7z.exe" E %1:\W2K\AddOns\Dictionaries.7z -O"%ProgramFiles%\Mozilla Firefox\dictionaries"
	"%1:\W2K\AddOns\Thunderbird Setup 12.0.1.exe" /S /V"/Passive /NoRestart"
If exist "%1:\W2K\AddOns\Thunderbird Setup 12.0.1.exe" "%ProgramFiles%\7-Zip\7z.exe" E %1:\W2K\AddOns\Dictionaries.7z -O"%ProgramFiles%\Mozilla Thunderbird\dictionaries"
	"%1:\W2K\AddOns\SeaMonkey Setup 2.9.1.exe" /S /V"/Passive /NoRestart"
If exist "%1:\W2K\AddOns\SeaMonkey Setup 2.9.1.exe" "%ProgramFiles%\7-Zip\7z.exe" E %1:\W2K\AddOns\Dictionaries.7z -O"%ProgramFiles%\SeaMonkey\dictionaries" -Y
	
rem Java runtime enviroment
%1:\W2K\AddOns\jre-6u31-windows-i586.exe /s IEXPLORER=1 MOZILLA=1
	rem Virtualisation applications
Copy /B %1:\W2K\AddOns\DOSBox*win32-installer.exe %Temp%\DOSBox-win32-installer.exe
%Temp%\DOSBox-win32-installer.exe /S
Del %Temp%\DOSBox-win32-installer.exe
msiexec /I %1:\W2K\AddOns\VirtualBox_1.5.6-1_Win_x86.msi /Passive /NoRestart /Log %Temp%\VirtualBoxInstall.log
	rem Daemon Tools (Part 1, SCSI Pass Through Direct layer)
If Not exist %1:\W2K\AddOns\SPTDinst-v190-x86.exe "%ProgramFiles%\7-Zip\7z" X %1:\W2K\AddOns\DTLite4356-0091.exe -O%Temp%\Daemon
%Temp%\Daemon\$PLUGINSDIR\SPTDinst-x86.exe Add /Q
RmDir /S /Q %Temp%\Daemon
%1:\W2K\AddOns\SPTDinst-v190-x86.exe Add /Q
	rem DVD playback utility (21 day trial)
%1:\W2K\AddOns\SetupAnyDVD7690.exe /S
If exist %1:\W2K\AddOns\Key.AnyDVD Regedit /S %1:\W2K\AddOns\Key.AnyDVD
	
rem all GUI run once commands go here
	
rem UltraDefrag - set boot defrag
%1:\W2K\AddOns\ultradefrag-6.1.2.bin.i386.exe /S
%SystemRoot%\system32\bootexctrl.exe /r defrag_native
	rem initialise account, setup for second pass and force reboot
Start %1:\W2K\Run1a.bat %1


\W2K\Run1a.bat

Ping -n 121 127.0.0.1 > nul
	rem VMware drivers
"%ProgramFiles%\7-Zip\7z.exe" X %1:\W2K\AddOns\Windows.iso -O%Temp%\VMwareServerTools
msiexec /I "%Temp%\VMwareServerTools\VMware Tools.msi" ADDLOCAL=ALL /Passive /NoRestart /Log %Temp%\VMwareToolsInstall.log
RmDir /S /Q %Temp%\VMwareServerTools
"%ProgramFiles%\7-Zip\7z.exe" X %1:\W2K\AddOns\WinPreVista.iso -O%Temp%\VMwarePlayerTools
%Temp%\VMwarePlayerTools\Setup.exe /S /V"/Qn REBOOT=R ADDLOCAL=ALL REMOVE=ThinPrint"
RmDir /S /Q %Temp%\VMwarePlayerTools
	rem setup for second pass
Echo Windows Registry Editor Version 5.00 > %Temp%\2ndPass.reg
Echo. >> %Temp%\2ndPass.reg
Echo [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\RunOnce] >> %Temp%\2ndPass.reg
Echo "command0"="%1:\\W2K\\Run2.bat %1 " >> %Temp%\2ndPass.reg
RegEdit /S %Temp%\2ndPass.reg
Del %Temp%\2ndPass.reg
	ShutDown /R /F

On the second attempt to logon we go straight to the desktop , but don't try to use it just yet, as we still have to install Media Player 9 and possibly more applications, which is done by \W2K\Run2.bat.  The batch file gets launched by GuiRunOnce which was setup by the RegEdit command in \W2K\Run1a.bat.

\W2K\Run2.bat

rem startup delay to allow disk thrashing to subside before proceeding
Ping -n 121 127.0.0.1 > nul
%SystemRoot%\system32\bootexctrl.exe /u defrag_native
	rem second pass of updates
%1:\W2K\RunOnce\Windows2000-DirectX9-KB975560-x86-ENU.exe /Passive /NoRestart
%1:\W2K\RunOnce\Windows2000-DirectX9-KB975562-x86-ENU.exe /Passive /NoRestart
%1:\W2K\RunOnce\Windows2000-DirectX9-KB2780091-X86-ENU.exe /Passive /NoRestart
%1:\W2K\RunOnce\WMP09-Setup-98Me2000.exe /Q
%1:\W2K\RunOnce\Windows2000-KB941569-x86-ENU.exe /Passive /NoRestart
%1:\W2K\RunOnce\Windows2000-WindowsMedia-KB952069-x86-ENU.exe /Passive /NoRestart
%1:\W2K\RunOnce\Windows2000-WindowsMedia-KB954155-x86-ENU.exe /Passive /NoRestart
%1:\W2K\RunOnce\Windows2000-WindowsMedia-KB968816-x86-ENU.exe /Passive /NoRestart
%1:\W2K\RunOnce\Windows2000-WindowsMedia9-KB973540-x86-ENU.exe /Passive /NoRestart
%1:\W2K\RunOnce\Windows2000-WindowsMedia-KB977816-x86-ENU.exe /Passive /NoRestart
%1:\W2K\RunOnce\Windows2000-WindowsMedia-KB979402-x86-ENU.exe /Passive /NoRestart
	rem support Bashrat the Sneaky's Driver Packs
%SystemDrive%\DPsFnshr.exe
	rem add Windows Explorer to Quick Launch
Set DefaultUserProfile=%SystemDrive%\Documents and Settings\Default User
MkDir "%DefaultUserProfile%\Application Data\Microsoft\Internet Explorer\Quick Launch"
Copy "%DefaultUserProfile%\Start Menu\Programs\Accessories\Windows Explorer.lnk" "%UserProfile%\Application Data\Microsoft\Internet Explorer\Quick Launch\"
Copy "%DefaultUserProfile%\Start Menu\Programs\Accessories\Windows Explorer.lnk" "%DefaultUserProfile%\Application Data\Microsoft\Internet Explorer\Quick Launch\"
	
rem silent installers go here
	
rem browser plugins
%1:\W2K\RunOnce\install_flash_player_ax_32bit-11-1-102-55.exe -install
%1:\W2K\AddOns\install_flash_player_32bit-11-1-102-55.exe -install
%1:\W2K\AddOns\Shockwave_Installer_Full-11-6-1-629.exe /S
%1:\W2K\AddOns\Silverlight-4-1-10329-0.exe /Q
	rem install & configure Libre Office (defaults shown)
If exist %1:\W2K\AddOns\LibO_3.6.7.2_Win_x86_install_multi.msi msiexec /I %1:\W2K\AddOns\LibO_3.6.7.2_Win_x86_install_multi.msi ALLUSERS=1 ADDLOCAL=ALL SELECT_WORD=1 SELECT_EXCEL=1 SELECT_POWERPOINT=1 /Qr /NoRestart /Log %Temp%\LibreOfficeInstall.log
msiexec /I %1:\W2K\AddOns\LibO_3.6.7.2_Win_x86_helppack_en-US.msi /Passive /NoRestart /Log %Temp%\LibreOfficeHelpInstall.log
msiexec /I %1:\W2K\AddOns\LibO_3.6.7.2_Win_x86_helppack_en-GB.msi /Passive /NoRestart /Log %Temp%\LibreOfficeHelpInstall.log
Move "%ProgramFiles%\LibreOffice 3.6\help\en-GB" "%ProgramFiles%\LibreOffice 3.6\help\en"
Copy %1:\W2K\AddOns\soffice.od* "%AllUsersProfile%\Templates\"
	rem PDF readers
%1:\W2K\AddOns\SumatraPDF-2.1.1-install.exe /S
msiexec /I %1:\W2K\AddOns\FoxitReader543.0920_enu.msi /Passive /NoRestart /Log %Temp%\FoxitReaderInstall.log
	rem image editors / managers
%1:\W2K\AddOns\gimp-2.6.7-i686-setup.exe /Silent /SP- /NoRestart
%1:\W2K\AddOns\gimp-help-2-2.6.0-en-setup.exe /Silent
	Copy /B %1:\W2K\AddOns\iview???_setup.exe %Temp%\iview_setup.exe
%Temp%\iview_setup.exe /silent /group=1 /allusers=1
Del %Temp%\iview_setup.exe
Copy /B %1:\W2K\AddOns\iview*plugins_setup.exe %Temp%\iview_plugins_setup.exe
%Temp%\iview_plugins_setup.exe /silent
Del %Temp%\iview_plugins_setup.exe
	rem nLite
%1:\W2K\AddOns\nLite-1.4.9.3.setup.exe /Silent /NoRestart
	rem Google Earth
%1:\W2K\AddOns\GoogleEarthWin-5-1-3535-3218.exe /S /V"ALLUSERS=1 /Passive /NoRestart"
	rem FTP & BitTorrent clients
%1:\W2K\AddOns\FileZilla_3.7.4.1_win32-setup.exe /S
%1:\W2K\AddOns\uTorrent-3-1-2-26821.exe /PerformInstall 2
	%1:\W2K\AddOns\Vuze_5600_Installer32.exe -q
If exist %1:\W2K\AddOns\Vuze_5600_Installer32.exe ping -n 41 127.0.0.1 > nul
Kill Azureus.exe
SubInACL /File "%ProgramFiles%\Vuze" /Grant=BuiltIn\Users=R
SubInACL /Subdirectories "%ProgramFiles%\Vuze"\ /Grant=BuiltIn\Users=R
	rem (almost) every video codec known to man
%1:\W2K\AddOns\vlc-1.1.11-win32.exe /S
	%1:\W2K\AddOns\K-Lite_Codec_Pack_710_Mega.exe /Silent /NoRestart /LoadInf="%1:\W2K\AddOns\klcp_mega_unattended.ini"
%1:\W2K\AddOns\Quicktimealt181lite.exe /Silent /NoRestart /LoadInf="%1:\W2K\AddOns\qtalt.ini"
%1:\W2K\AddOns\Real_Alternative_202_Lite.exe /Silent /NoRestart
	rem DVD backup utility
%1:\W2K\AddOns\dvdshrink32setup.exe /Silent /NoRestart
	rem Daemon Tools (Part 2, uninstall toolbar)
%1:\W2K\AddOns\DTLite4356-0091.exe /S
"%ProgramFiles%\DAEMON Tools Toolbar\uninst.exe" /S
	rem basic freeware CD/DVD burners
Copy /B %1:\W2K\AddOns\cdbxp_setup*.exe %Temp%\cdbxp_setup.exe
%Temp%\cdbxp_setup.exe /Silent /NoRestart
Del %Temp%\cdbxp_setup.exe
	%1:\W2K\AddOns\NeroBurnRightsInstaller.exe /Silent /BurnRights:All
%1:\W2K\AddOns\SetupImgBurn_2.5.8.0.exe /S
	rem defrag
%SystemRoot%\system32\uDefrag -r -v --all-fixed
	rem setup for the next pass
Set NextBatch=Run3.bat
Echo Windows Registry Editor Version 5.00 > %Temp%\NextPass.reg
Echo. >> %Temp%\NextPass.reg
Echo [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\RunOnce] >> %Temp%\NextPass.reg
Echo "command0"="%1:\\W2K\\%NextBatch% %1 " >> %Temp%\NextPass.reg
If exist %1:\W2K\%NextBatch% RegEdit /S %Temp%\NextPass.reg
Del %Temp%\NextPass.reg
	rem VirtualBox Drivers
"%ProgramFiles%\7-Zip\7z" X %1:\W2K\AddOns\VBoxGuestAdditions.iso -O%Temp%\VirtualBox
%Temp%\VirtualBox\VBoxGuestAdditions.exe /S
%Temp%\VirtualBox\VBoxWindowsAdditions-x86.exe /depth=32 /xres=1280 /yres=1024 /S
RmDir /S /Q %Temp%\VirtualBox
Xcopy "%UserProfile%\Start Menu\Programs\Oracle VM VirtualBox Guest Additions" "%AllUsersProfile%\Start Menu\Programs\Oracle VM VirtualBox Guest Additions\" /e
Xcopy "%UserProfile%\Start Menu\Programs\Sun VirtualBox Guest Additions" "%AllUsersProfile%\Start Menu\Programs\Sun VirtualBox Guest Additions\" /e
	
rem driver installers go here
%1:\W2K\AddOns\Modem\Setup.exe /S
	
rem Spybot - Search and Destroy
%1:\W2K\AddOns\spybotsd162.exe /Silent /SP- /Components="" /tasks="!launchsdhelper,!launchteatimer,!quicklaunchicon" /NoRestart
%1:\W2K\AddOns\spybotsd_includes.exe /S
"%ProgramFiles%\Spybot - Search & Destroy\SpybotSD.exe" /taskbarhide /autoimmunize /autoclose
	rem Avast anti-virus - rerun setup to install additional languages
%1:\W2K\AddOns\avast_free_antivirus_setup-8-0-1497-376.exe /Silent /SP- /NoRestart
If exist %1:\W2K\AddOns\avast_free_antivirus_setup-8-0-1497-376.exe ping -n 121 127.0.0.1 > nul
%1:\W2K\AddOns\vpsupd.exe /Silent
	rem Comodo Firewall
%1:\W2K\AddOns\Comodo2.exe
	rem optional menu reorganization
CMD /R %1:\W2K\MenuReorg.bat
	rem VirtualPC drivers (ejects CD, must be the last command of the last batch file)
"%ProgramFiles%\7-Zip\7z" X %1:\W2K\AddOns\VMAdditions.iso -O%Temp%\VirtualPC
msiexec /I %Temp%\VirtualPC\Windows\VirtualMachineAdditions.msi ADDLOCAL=ALL /Passive /ForceRestart
	ShutDown /R /F

You can have as many application install reboot passes as desired.  To do this simply set the system to auto-logon (in step 6) as many times as required and place the appropriate number of batch files in the \W2K\ directory of your install media.  The first 5 batch files are already written (at \Misc) with the needed handover command, but if you need more they are fairly self explanatory.  If using VirtualPC 2007 be sure to install its drivers last.

\W2K\Run3.bat

rem startup delay to allow disk thrashing to subside before proceeding
Ping -n 121 127.0.0.1 > nul
	rem you must use %1:\ when referring to files on the install media (%1 is the drive letter)
	rem silent installers go here
	rem setup for the next pass
Set NextBatch=Run4.bat
Echo Windows Registry Editor Version 5.00 > %Temp%\NextPass.reg
Echo. >> %Temp%\NextPass.reg
Echo [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\RunOnce] >> %Temp%\NextPass.reg
Echo "command0"="%1:\\W2K\\%NextBatch% %1 " >> %Temp%\NextPass.reg
If exist %1:\W2K\%NextBatch% RegEdit /S %Temp%\NextPass.reg
Del %Temp%\NextPass.reg
	ShutDown /R /F

SchTasks.exe ShutDown.exe Kill.exe Grant_Access_1.1.exe

Edited by Kurt_Aust
WYSIWYG editor
Link to comment
Share on other sites


Changelog:

11 May 07: Full rewrite of topic, changelog reset.

13 May 07: Found solution to Open Office & Adobe Reader integration problem, updated Config.zip (just choose overwrite all).

17 Jun 07: June updates, see post 9 (18th, fixed error in AFT_OpenOffice.bat).

13 Jul 07: July updates, see post 10.

18 Jul 07: Updated instructions and ******* for kb925398v2 (re post 11), also altered nLite's RunOnce and the *.bat files (see post 12).

15 Aug 07: August Updates, see post 13.

20 Aug 07: Updated instructions and ******* for kb832353 (re post 14) and Run1*.bat to support JohnDoe74's Windows Defender AddOn.

7. Sep 07: Removed kb832353 as redundant (re post 23) and moved NDP20-KB928365-X86.exe from Run2*.bat to Run1*.bat (post 24).

12 Sep 07: September Updates, see post 25.

21 Sep 07: Added information on version 5.1.2195.21 of the USP, updated AFT_OpenOffice.bat for Open Office 2.3.0.

23 Sep 07: Added W2K USP 5.1.2195.24 to my tracker as RyanVM's tracker always seems to return scrape errors for me.

12 Oct 07: October Updates (see post 27), eSnips direct download of USP 5.1.2195.24 & Hotfix pack, AV definition update support.

16 Nov 07: Quiet month (no updates), added support for "Root Certificates Update" and Spybot:S&D immunization on install.

16 Dec 07: December updates (see post 35), new fully updated .Net installers, file numbering reorder, Open Office install options.

10 Jan 08: January updates, see post 40.

16 Feb 08: February updates, see post 42.

15 Mar 08: March updates, see post 43.

15 Apr 08: April updates, see post 46.

17 May 08: May update, see post 50.

14 Jun 08: June updates, see post 54.

12 Jul 08: July updates, see post 57.

17 Aug 08: August updates, see post 61.

26 Aug 08: Added details on multi-CD installs & VM testing (notes 5 & 7 above)

16 Sep 08: September updates, see post 63.

19 Oct 08: October updates, see post 64.

15 Nov 08: November updates, see post 65.

18 Nov 08: Added Comodo Firewall support

13 Dec 08: December updates, see post 67.

16 Jan 09: January updates, see post 68.

23 Jan 09: .Net 2.0 SP2 standalone out, see post 70.

14 Feb 09: February update & added screenshot archive, see post 71.

14 Mar 09: March updates, see post 72.

3. Apr 09: Changed method of launching Run2_W2Ksp5.bat to one that allows greater flexibility, see post 75.

20 Apr 09: April updates, see post 76.

14 Jun 09: June updates, see post 77.

17 Jul 09: July updates, see post 79.

15 Aug 09: August updates, see post 85.

13 Sep 09: September updates, see post 86.

14 Nov 09: October/November updates, see posts 92-94.

18 Dec 09: December updates, see post 98.

16 Jan 10: January update, see post 100.

12 Feb 10: February update, see post 101

17 Apr 10: April updates, see post 107.

14 May 10: May updates, see post 108.

23 Jul 10: End of support updates, see post 111.

17 Sep 10: .Net & Flash updates, see post 113.

24 Jun 11: .Net and VC++ updates, see post 125.

28 Aug 11: .Net update, see post 133.

17 Oct 11: .Net update, see post 134.

20 Mar 12 : .Net update, see post 135.

14 Apr 12: Titanic memorial day, .Net update, see post 138.

13 May 12: .Net update, see post 144.

21 Jun 12: .Net update, see post 145.

15 Jul 12: MSXML update, see post 155.

30 Nov 12: .Net update, see post 168.

18 Jan 13: MSXML & .Net updates, see post 169.

17 Feb 13: .Net update, see post 170.

20 Mar 13: Added post EoL hotfixes nominated by thomasz86

25 May 13: .Net update, see post 176

17 Jun 13: .Net update, see post 177

20 Jul 13: .Net update, see post 178

10 Oct 14: Fairly significant reworking of the topic including changes to the batch files launch method, a list of supported applications and a few general updates, see post 179.

24 Oct 14: .Net update, see post 180

23 Nov 14: .Net update, see post 181

30 Apr 15: .Net update and folder rearrangement, see post 182

23 May 15: .Net update, see post 183

4 Jan 16: 7-Zip and root certificates updates plus a reworking of the grant access utility, see post 184

XP_sp2a_install.doc

Edited by Kurt_Aust
Link to comment
Share on other sites

  • 2 weeks later...

This project has undergone a major rewrite to enhance ease of use, most significantly there is now a torrent with 31 of the 38 needed executable files. Also all configuration files are now in a single archive.

Project has been updated for May, main notes for those who used the April version:

Re-read the topic, major changes

Hotfix order was stuffed, run UpdatePrep.bat to fix (didn't affect installation though)

Move all files from \WMP9 and \Utilities to \RunOnce

As there are only small changes between the bimonthly versions of the DirectX redistributable, I am considering adding the ability to update it via the torrent \ UpdatePrep.bat, opinions?

Link to comment
Share on other sites

  • 3 weeks later...

i tend to dis-agree with this for a bit though...

dont get me wrong the idea is perfect but id rather see using hfslip

or maybe a derivative special to this project...

step 1, slipstream usp5xxxxx.exe

step 2, use hfslip for directx mdac mplayer net1.1 and net2.2 and the hotfix list..

step 3, use nlite to tweak the hfsliped source....

this way you save a lot of install time for dx9 and mdac.

ather that adding driverpacks is a verry good idea.. but i would say,

lets look at the totorial for 'creating your own DP' and build ourselves a win2k version

(removing those files that arn't neaded for xp... etc (all to make these packs a bit smaller),

Edited by -I-
Link to comment
Share on other sites

adchia:

Glad to hear it was of help to you.

-I-:

I did this under nLite as while there are many ways to create an up to date XP installer, there seems to be a major dearth of Win2000 solutions. Also I am familiar with nLite and I wanted to prove to myself that it was in fact possible and I could do it.

If you wish to write a similar guide for HFslip, by all means go for it, it's not like I have a software patent on the idea. Feel free to block copy appropriate sections of this guide if you wish.

As for install time, since it's unattended, it didn't seem like all that big a deal. The batch file stage takes about 20 minutes under VirtualPC, how much time is HFslip likely to save? (this is an honest question, I've never used HFslip)

As for Driver Packs, I felt that having application AddOns was more important, so once you added drivers as well you were forced to use a DVD as the install media anyway. Also I wanted this guide to be as newbie friendly as possible, so things like editing driver packs was definitely off the agenda.

Link to comment
Share on other sites

  • 3 weeks later...

June Hotfix updates:

Delete 140-Windows2000-KB917422-x86-ENU.EXE

Delete 580-IE6.0sp1-KB931768-Windows2000-x86-ENU.exe

Move RunOnce\MDAC253-KB927779-x86-ENU.exe to Hotfix\580-MDAC253-KB927779-x86-ENU.exe

Add the following to \Hotfix

600-Windows2000-KB927891-x86-ENU.EXE [1,276,272]

620-Windows2000-KB935840-x86-ENU.EXE [564,080]

640-Windows2000-KB935839-x86-ENU.EXE [736,624]

660-IE6.0sp1-KB933566-Windows2000-x86-ENU.exe [4,189,088]

Other changes:

Moved all RunOnce commands to the batch files for easier maintenance, MDAC patch is supported by latest nLite version.

Link to comment
Share on other sites

  • 4 weeks later...

July Hotfix updates:

Add the following to \Hotfix

680-Windows2000-KB926122-x86-ENU.EXE [1,397,104]

Add the following to \RunOnce

NDP1.1sp1-KB928366-X86.exe [9,249,736]

NDP20-KB928365-X86.exe [15,394,248]

No deletions

The 2 .Net hotfixes that get saved to RunOnce are huge, 23.5 MB in total !! Hopefully it won't be too long before RyanVM updates his switchless installers and we get most of that back, however RyanVM has indicated that he is very busy at the moment so it may be a while.

EDIT: Delete

Hotfix\320-WindowsMedia6-KB925398-x86-ENU.exe

and replace it with

Hotfix\670-WindowsMedia6-KB925398-v2-x86-ENU.exe

Edited by Kurt_Aust
Link to comment
Share on other sites

Looks like this line

320-WindowsMedia6-KB925398-x86-ENU.exe [791,888]

has been replaced by WindowsMedia6-KB925398-v2-x86-ENU.exe [797,088] because thats what I obtained from Microsoft.

IGNORE TEXT ABOVE - LIST HAS BEEN UPDATED

Copy the below into a batch file and place in the Misc folder. This will rename all of Kurt's direct download list according to his numbering specifications.

@echo off

echo.

echo "File not Found" errors should not occur if all files downloaded correctly as per list above

pause

rem Renumbering of direct downloads from Microsoft for July 2007

rename ..\Hotfix\WindowsInstaller-KB893803-v2-x86.exe 020-WindowsInstaller-KB893803-v2-x86.exe

rename ..\Hotfix\Windows-KB909520-v1.000-x86-ENU.exe 100-Windows-KB909520-v1.000-x86-ENU.exe

rename ..\Hotfix\Windows2000-KB917008-x86-ENU.EXE 120-Windows2000-KB917008-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB920670-x86-ENU.EXE 160-Windows2000-KB920670-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB920683-x86-ENU.EXE 180-Windows2000-KB920683-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB921398-x86-ENU.EXE 200-Windows2000-KB921398-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB920685-x86-ENU.EXE 220-Windows2000-KB920685-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB923414-x86-ENU.EXE 240-Windows2000-KB923414-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB924191-v2-x86-ENU.EXE 260-Windows2000-KB924191-v2-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB923980-x86-ENU.EXE 280-Windows2000-KB923980-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB924270-x86-ENU.EXE 300-Windows2000-KB924270-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB926247-x86-ENU.EXE 340-Windows2000-KB926247-x86-ENU.EXE

rename ..\Hotfix\***OE6.0sp1-KB923694-Windows2000-x86-ENU.exe 360-OE6.0sp1-KB923694-Windows2000-x86-ENU.exe

rename ..\Hotfix\IE6.0sp1-KB929969-Windows2000-x86-ENU.exe 380-IE6.0sp1-KB929969-Windows2000-x86-ENU.exe

rename ..\Hotfix\Windows2000-KB928843-x86-ENU.EXE 400-Windows2000-KB928843-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB924667-x86-ENU.EXE 420-Windows2000-KB924667-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB918118-x86-ENU.EXE 440-Windows2000-KB918118-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB926436-x86-ENU.EXE 460-Windows2000-KB926436-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB925902-x86-ENU.EXE 480-Windows2000-KB925902-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB930178-x86-ENU.EXE 500-Windows2000-KB930178-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB931784-x86-ENU.EXE 520-Windows2000-KB931784-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB932168-x86-ENU.EXE 540-Windows2000-KB932168-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB920213-x86-ENU.EXE 560-Windows2000-KB920213-x86-ENU.EXE

rename ..\Hotfix\MDAC253-KB927779-x86-ENU.exe 580-MDAC253-KB927779-x86-ENU.exe

rename ..\Hotfix\Windows2000-KB927891-x86-ENU.EXE 600-Windows2000-KB927891-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB935840-x86-ENU.EXE 620-Windows2000-KB935840-x86-ENU.EXE

rename ..\Hotfix\Windows2000-KB935839-x86-ENU.EXE 640-Windows2000-KB935839-x86-ENU.EXE

rename ..\Hotfix\IE6.0sp1-KB933566-Windows2000-x86-ENU.exe 660-IE6.0sp1-KB933566-Windows2000-x86-ENU.exe

rename ..\Hotfix\WindowsMedia6-KB925398-v2-x86-ENU.exe 670-WindowsMedia6-KB925398-v2-x86-ENU.exe

rename ..\Hotfix\Windows2000-KB926122-x86-ENU.EXE 680-Windows2000-KB926122-x86-ENU.EXE

Edited by dbrunton
Link to comment
Share on other sites

Updated post #1 and the torrent for 670-WindowsMedia6-KB925398-v2-x86-ENU.exe as reported by dbrunton.

Also rewrote the nLite RunOnce file and the 2 batch files to fix a problem I discovered when I added a USB card reader to my RMware testbed. With the older version an "Invalid parameter" error dialogue box would pop-up when any attempt was was made to access the card reader during installation.

Link to comment
Share on other sites

  • 4 weeks later...

August Hotfix updates

Deletions

Hotfix\260-Windows2000-KB924191-v2-x86-ENU.EXE

Hotfix\380-IE6.0sp1-KB929969-Windows2000-x86-ENU.exe

Hotfix\660-IE6.0sp1-KB933566-Windows2000-x86-ENU.exe

RunOnce\WindowsMedia9-KB917734-x86-ENU.exe

Additions

Hotfix\690-Windows2000-KB921503-x86-ENU.EXE [756,712]

Hotfix\700-Windows2000-KB938829-x86-ENU.EXE [619,376]

Hotfix\710-IE6.0sp1-KB937143-Windows2000-x86-ENU.exe [4,189,088]

Hotfix\720-Windows2000-KB936021-x86-ENU.EXE [925,552]

Hotfix\730-IE6.0sp1-KB938127-Windows2000-x86-ENU.exe [1,498,528]

RunOnce\WindowsMedia9-KB936782-x86-ENU.exe [2,300,320]

EDIT: Delete

RunOnce\WindowsMedia-Q828026-x86-ENU.exe

and replace it with

RunOnce\WindowsMedia-KB832353-ENU.exe[2,861,608]

EDIT Mark2:

Delete RunOnce\WindowsMedia-KB832353-ENU.exe

As reported by "the_guy" in post 23 both Q828026 and KB832353 are redundant.

Edited by Kurt_Aust
Link to comment
Share on other sites

Works. Very nice.

With August hotfixes it only needed 7 security updates and 1 Malicious Software Tool from Windows Update to complete Express update.

One hardware device error which I think you may have got.

"The class installer has denied the request to install or upgrade this device" The device is classed as a MEDIA device and seems to be a gameport and won't install from Add/Remove Hardware or Device Manager after all of the setup has finished.

But it found pretty much everything else which impressed me. Some ATI codecs had to be got from Windows Update but that's nothing.

A 1 Gb DVD disc with 975 Mb of drivers and addon applications was used on a system with 640 Mb of RAM and a 200 Gb hard disk with a 1.3 GHz Duron processor. Installation time approx 1 hr to 2 hrs.

Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
  • Recently Browsing   0 members

    • No registered users viewing this page.
×
×
  • Create New...