Jump to content

Automatically create multi-boot folders and files


geitonaki
 Share

Recommended Posts

Edit: New version.

You can automatically create the multi-boot folders and files using my batch file for any version of Windows 2000, XP, 2003. Everything needed is included in the file I have uploaded.

File attached so people don't need to wait for RapidShare's download ticket ~ Alanoll

Here I will post only the main batch file:

create_boot_folder.cmd


@echo off
if [%1] == [] goto :usage
if [%2] == [] goto :usage
if [%3] == [] goto :usage
if [%4] == [] goto :usage
if [%5] == [] goto :usage
if not [%6] == [] goto :usage
if not exist "%~f1" (
echo Directory "%~f1" does not exist.
goto :usage
)
if not exist "%~f2" (
echo Directory "%~f2" does not exist.
goto :usage
)
if exist "%~f2\%3" (
echo "%~f2\%3" already exists so nothing to do, please delete it manually
goto :end
)

set pth=%~f1
set aio=%~f2
call set pth=%%pth:%aio%=%%
if "%pth%" == "%~f1" (
echo "%~f1" must be under "%~f2".
goto :end
)

if exist "%1\I386\TXTSETUP.SIF" (
set src_dir=%1\I386
set dest_dir=%2\%3
set archit=I386
) else if exist "%1\AMD64\TXTSETUP.SIF" (
set src_dir=%1\AMD64
set dest_dir=%2\%4
set archit=AMD64
) else (
echo Cannot find TXTSETUP.SIF in I386 or AMD64 in %1
)

type "%src_dir%\TXTSETUP.SIF" | findstr /r ",_[1-9] ,[1-9]_" | sed -e s/"=.*"/""/g -e s/" .*"/""/g > out.txt
type out.txt | sed -e s/".$"/"_"/g > out_.txt

mkdir "%dest_dir%"

for /f %%i in ('type out.txt') do copy "%src_dir%\%%i" "%dest_dir%" > nul 2>&1
for /f %%i in ('type out_.txt') do copy "%src_dir%\%%i" "%dest_dir%" > nul 2>&1

copy "%src_dir%\BOOTFONT.BIN" "%dest_dir%" > nul 2>&1
copy "%src_dir%\BOOTFONT.BIN" "%2" > nul 2>&1

mkdir "%dest_dir%\SYSTEM32"
copy "%src_dir%\system32\*.*" "%dest_dir%\SYSTEM32" > nul 2>&1

set pth=%pth:\=\\%
type "%src_dir%\TXTSETUP.SIF" | sed -e s/"SetupSourcePath = \""/"SetupSourcePath = \"%pth%"/g > "%dest_dir%\TXTSETUP.SIF"
unix2dos "%dest_dir%\TXTSETUP.SIF"

del "%dest_dir%\NTDLL.DLL" > nul 2>&1

if "%archit%" == "AMD64" (
mkdir "%2\%3"
copy "%1\I386\NTDETECT.COM" "%2\%3" > nul 2>&1
)

if "%5" == "1" (
copy SETUPLDR.BIN "%2\%3" > nul 2>&1
) else (
copy "%1\I386\SETUPLDR.BIN" "%2\%3" > nul 2>&1
)
start /w xvi32.exe "%2\%3\SETUPLDR.BIN" /S=replaceI386.xsc "%3"
if "%archit%" == "AMD64" (
start /w xvi32.exe "%2\%3\SETUPLDR.BIN" /S=replaceAMD64.xsc "%4"
)

copy BOOT.BIN "%2\%3.bin" > nul 2>&1
start /w xvi32.exe "%2\%3.bin" /S=universalrepl.xsc "I386" "%3"

del OUT.txt > nul 2>&1
del OUT_.txt > nul 2>&1

copy "%1\CDROM*.*" "%2"\ > nul 2>&1
copy "%1\WIN51*.*" "%2"\ > nul 2>&1

goto :end

:usage
echo Usage: %~n0 setup_dir aio_dir boot_dir1 boot_dir2 flag_for_using_cracked_setupldr
goto :end

:end

Edit: New version so that you don't need to subst your aio-dvd dir anymore.

File attached ~ Alanoll

Create_MultiBoot_Folders_And_Files.zip

Edited by Alanoll
Link to comment
Share on other sites


Download the self extracting rar file in the first post, execute it and it will ask where to install. Browse to your AIO-DVD folder. When finished it will create #TOOLS in there, open create_boot_folders.cmd which calls create_boot_folder.cmd, modify it in your needs and execute it.

It will create the boot folders, modify setupldr.bin, modify txtsetup.sif, create the boot sector and copy the tag files. Everything described in http://flyakite.msfnhosting.com/ for Windows 2000/XP/2003 is made automatically B). Doesn't this topic deserve to be sticky :)?

@amd64lover

please give us feedback for 64bit version of windows since I don't have an amd64 to test, but I am pretty sure that everything should be fine.

Edited by geitonaki
Link to comment
Share on other sites

@geitonaki

the 64bit installed PERFECTLY!!! i used your method to disable the checksum and created XP64 & PRO64 folders and everything worked great. i will try your batch file and see how it works. thanks

Edited by amd64lover
Link to comment
Share on other sites

That's the second file of yours I've attached so people don't have to go to that dreadful site...

I'll try this later on...

But as for the sticky...I do believe a random suggestion in a post does nothing. Let alone one for your OWN topic. It's just not really polite in all honesty.

I'll unsticky the old thread, but there really isn't any need for this to be a sticky, or the other page. They're still on the first page of the forum, and a simple search should bring these up.

Link to comment
Share on other sites

That's the second file of yours I've attached so people don't have to go to that dreadful site...

Having 150kb limit for each post how could I uploaded here? My only option was to upload to rapidshare.de

whoops, guess I should have adde the :P smiley so you know I wasn't trying to say you did something wrong. Next time though, if you need something attached, you could just send it to me and I'll upload and attach it to yourpost.

Link to comment
Share on other sites

  • 4 weeks later...
  • 1 month later...

Just a quick question now. I have been looking through the posts and the files and had a play but i just can't seem to get my head around the coding in create_boot_folders.cmd

I just seem to get the same message as hardlocke did.

Could someone please post a working copy so i can get a better handle on it.

Much appriciated.

Link to comment
Share on other sites

That's the second file of yours I've attached so people don't have to go to that dreadful site...

Having 150kb limit for each post how could I uploaded here? My only option was to upload to rapidshare.de

Rapidshare.de actually changed their method of downloading, you just gotta type in the Verify code, and you get the download now. :thumbup

Link to comment
Share on other sites

Just a quick question now. I have been looking through the posts and the files and had a play but i just can't seem to get my head around the coding in create_boot_folders.cmd

I just seem to get the same message as hardlocke did.

Could someone please post a working copy so i can get a better handle on it.

Much appriciated.

I have uploaded a new version, check it out and post how it worked for you, the syntax is now:

Usage: create_boot_folder setup_dir aio_dir boot_dir1 boot_dir2 flag_for_using_cracked_setupldr

You have to open create_boot_folders.cmd with notepad, modify the included examples and then run it by double clicking the file

Link to comment
Share on other sites

All righty man. I just did a basic test of your multi-boot dvd prog. It created the the boot stuff perfectly. Since I don't have an x64 rig, I can only test out the cracked setupldr.bin via server2003. I'll post results later. So far so good man. You've done an awesome job!

Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share

  • Recently Browsing   0 members

    • No registered users viewing this page.


×
×
  • Create New...