[Release] SPTD driver v1.42 - x86 and x64

**Avneet** · October 1, 2006

well version 1.29 works fine ..with latest daemon tools and alcohol..

**ajua** · October 1, 2006

well version 1.29 works fine ..with latest daemon tools and alcohol..

thanks, i was wondering if it works with latest alcohol. now i know for sure.

**ajua** · October 11, 2006

i have one big question here:

i read that you can install alcohol after installing this. so i run the drivers setup. rebooted my machine. then tried to launch the alcohol setup using switches but none worked. wich parameters are you guys using to install alcohol? i searched for other topics but they only seem to work with autoit. is possible to get it installed with silent switches after installed the drivers? thanks for the help.

BTW, im using alcohol latest version, 1.9.5.4521.

**Avneet** · October 11, 2006

i have one big question here:
i read that you can install alcohol after installing this. so i run the drivers setup. rebooted my machine. then tried to launch the alcohol setup using switches but none worked. wich parameters are you guys using to install alcohol? i searched for other topics but they only seem to work with autoit. is possible to get it installed with silent switches after installed the drivers? thanks for the help.
BTW, im using alcohol latest version, 1.9.5.4521.

there is no switch.. we use autoit script

**ajua** · October 11, 2006

can anyone share the script with me? so i can try to install it this way. i have never used autoit.

**Shark007** · October 12, 2006

can anyone share the script with me? so i can try to install it this way. i have never used autoit.

I'm not exactly sure who created this script, it sure wasnt me.

I believe the author is MHz.

Also, it was created for an earlier version, it may need to be modified.

This script looks for the file A120.EXE and installs it unattendedly.

You will need to download the AutoIT program to compile this to an EXE

#region - Alcohol120_retail_1.9.5.3823 install script - (Automated with WinExists functions)

Opt('TrayIconDebug', 1)

; Installer.
$executable = 'A120.exe'
; Show progess.
$splash = 0
; Default catagory folder in startmenu.
$group = 'Alcohol 120%'
; New catagory to move the default folder into.
$catagory = ''
; Installation folder in Program Files.
$directory = 'Alcohol Soft\Alcohol 120'
; Allowed time for installation.
$allowed = 60 * 1000
; Components to choose. 1 = Yes, 0 = No.
$langfiles  = 0 ; Multi-Language Files
$manual     = 0 ; Online manual
$shortcuts  = 0 ; Desktop Shortcut
$startmenu  = 1 ; Startmenu Entries
$starwind   = 0 ; iSCSI Service

; ----- Settings Complete ------

; Set components to install via registry.
$key = 'HKLM\SOFTWARE\Alcohol Soft\Alcohol 120%\AddRemove\Components'
RegWrite($key & '\SecLangFiles',    'Installed', 'Reg_Dword', $langfiles)
RegWrite($key & '\SecManual',       'Installed', 'Reg_Dword', $manual)
RegWrite($key & '\SecShortcuts',    'Installed', 'Reg_Dword', $shortcuts)
RegWrite($key & '\SecStartMenu',    'Installed', 'Reg_Dword', $startmenu)
RegWrite($key & '\SecStarWind',     'Installed', 'Reg_Dword', $starwind)

; Run the installer.
$pid = _Install()
$time = TimerInit()
$title = 'Alcohol 120%'
Do
    Select
        Case WinExists($title, 'Welcome to the Alcohol 120%')
            WinMove($title, 'Welcome to the Alcohol 120%', @DesktopWidth, 0)
            ControlClick($title, 'Welcome to the Alcohol 120%', 'Button2')

        Case WinExists($title, 'License Agreement')
            ControlClick($title, 'License Agreement', 'Button2')

        Case WinExists($title, 'Choose Components')
            ControlClick($title, 'Choose Components', 'Button2')

        Case WinExists($title, 'Choose Install Location')
            ControlClick($title, 'Choose Install Location', 'Button2')

        Case WinExists($title, 'Completing the Alcohol 120%')
            ControlCommand($title, 'Completing the Alcohol 120%', 'Button4', 'UnCheck', '')
            ControlClick($title, 'Completing the Alcohol 120%', 'Button2')

        Case Else
            Sleep(250)
    EndSelect
    If TimerDiff($time) > $allowed Then _Abort()
Until Not ProcessExists($pid)

; Exit if $startmenu = 0 from above.
If Not $startmenu Then Exit

; Remove shortcuts.
If _MainShortcut('Alcohol 120%.lnk') Then
    FileDelete('Alcohol Command Launcher.lnk')
    FileDelete('Alcohol Manual.lnk')
;~  FileDelete('Uninstall Alcohol 120%.lnk')
;~  _Desktop('Alcohol 120%.lnk')
EndIf

#endregion
Exit

Func _Install($path = 'Default')
    ; Run the installer in Default Script directory.
    Dim $splash, $processblock
    If $path = 'Default' Then $path = @ScriptDir
    If StringRight($path, 1) <> '\' Then $path = $path & '\'
    If StringInStr($executable, '\') Then $path = ''
    If Not FileExists($path & $executable) Then Exit 1
    If $processblock <> '' Then Call('_' & 'ProcessBlock')
    If $splash Then _Splash('Installing:' & StringTrimRight(StringReplace(@ScriptName, '_', ' '), 4))
    If StringRight($executable, 3) = 'msi' Then
        Return Run(@SystemDir & '\msiexec /i "' & $path & $executable & '"')
    Else
        Return Run($path & $executable)
    EndIf
EndFunc

Func _Abort()
    ; close process if exists then exit.
    Dim $pid
    If ProcessExists($pid) Then
        ProcessClose($pid)
        Exit 2
    Else
        Exit 3
    EndIf
EndFunc

Func _Desktop($shortcut)
    ; Delete a Desktop shortcut.
    If FileExists(@DesktopDir & '\' & $shortcut) Then
        Return FileChangeDir(@DesktopDir) And FileDelete($shortcut)
    ElseIf FileExists(@DesktopCommonDir & '\' & $shortcut) Then
        Return FileChangeDir(@DesktopCommonDir) And FileDelete($shortcut)
    EndIf
EndFunc

Func _MainShortcut($shortcut, $rename = '')
    ; Change working directory to correct StartMenu\Group directory.
    Dim $group, $catagory, $splash
    If $group = '' Then Return 0
    If FileExists(@ProgramsDir & '\' & $group) Then
        FileChangeDir(@ProgramsDir & '\' & $group)
    ElseIf FileExists(@ProgramsCommonDir & '\' & $group) Then
        FileChangeDir(@ProgramsCommonDir & '\' & $group)
    Else
        Return 0
    EndIf
    ; Wait for main shortcut.
    If $splash Then _Splash('Waiting for shortcuts')
    For $i = 1 To 20
        If FileExists($shortcut) Then ExitLoop
        Sleep(500)
    Next
    If $splash Then _Splash('Cleaning up:' & StringTrimRight(StringReplace(@ScriptName, '_', ' '), 4))
    ; If catagory not assigned anything, then return.
    If $catagory = '' Then Return 1
    ; Move the group folder into the catagory folder.
    If FileChangeDir('..') And DirCopy($group, $catagory & '\' & $group, 1) Then
        If DirRemove($group, 1) Then
            ; If optional rename parameter is used, then rename the group folder.
            If $rename <> '' And FileChangeDir($catagory) Then
                If DirCopy($group, $rename, 1) And DirRemove($group, 1) Then
                    Return FileChangeDir($rename)
                EndIf
            Else
                Return FileChangeDir($catagory & '\' & $group)
            EndIf
        EndIf
    EndIf
EndFunc

Func _QuickLaunch($shortcut)
    ; Delete a Quicklaunch shortcut.
    Local $subdirs = '\Microsoft\Internet Explorer\Quick Launch'
    If FileExists(@AppDataDir & $subdirs & '\' & $shortcut) Then
        Return FileChangeDir(@AppDataDir & $subdirs) And FileDelete($shortcut)
    ElseIf FileExists(@AppDataCommonDir & $subdirs & '\' & $shortcut) Then
        Return FileChangeDir(@AppDataCommonDir & $subdirs) And FileDelete($shortcut)
    EndIf
EndFunc

Func _Splash($text = '')
    ; Shows a small borderless splash message.
    Dim $splash
    If $splash Then
        If $text Then
            SplashTextOn('', $text, 500, 25, -1, 5, 1, '', 14)
        Else
            SplashOff()
        EndIf
    EndIf
EndFunc

Func _WinClose($title, $text = '')
    ; Close a window with further attempts.
    For $i = 1 To 10
        WinClose($title, $text)
        If Not WinExists($title) Then Return 1
        Sleep(500)
    Next
EndFunc

Func OnAutoItStart()
    ; A 2nd script instance will exit.
    Local $interpreter
    If StringInStr($cmdlineraw, '/dummy') Then Exit
    $interpreter = StringTrimRight(@ScriptName, 4) & ' Script Interpreter'
    If WinExists($interpreter) Then Exit
    AutoItWinSetTitle($interpreter)
EndFunc

shark

Edited May 19, 2007 by Shark007

**ajua** · October 13, 2006

well, will try to play with it. thanks for the script. even though its not for the latest version will serve me as a point to start.

**MHz** · October 14, 2006

I'm not exactly sure who created this script, it sure wasnt me.
I believe the author is MHz.

Yeah, looks like my work.

Nice move on sharing a unattended SPTD installer. Keep it going.

**Ver Greeneyes** · November 1, 2006

I probably don't need to tell you but.. SPTD drivers v1.35 have been released; you can get them at http://www.duplexsecure.com/

**Shark007** · November 1, 2006

Thanks for the headsup, and the link. I have no use for this myself, so i probably would not have found it on my own. I realize many people do have a need/use for it though.

updated to v1.35 on November 1, 2006.

shark

**Ver Greeneyes** · November 1, 2006

Hehe, glad I could help then. I got the link from the Daemon Tools website - the news post about the update said to get it there.

**mrnxdmx** · November 3, 2006

Thanx for the update

**Avneet** · November 3, 2006

the new version doesnt work with daemon tools yet.. alcohol has released a new version to support this new sptd driver .. but not daemon tools..

sharky can u plizz provide the link for the 1.29 version .. thx

**Shark007** · November 3, 2006

the new version doesnt work with daemon tools yet.. alcohol has released a new version to support this new sptd driver .. but not daemon tools.. sharky can u plizz provide the link for the 1.29 version .. thx

Thanks for the input. Older version is once again available at the usual source.

shark

**Ver Greeneyes** · November 3, 2006

Um, are you getting any problems with Daemon Tools and 1.35? 'Cuz I got the news of the release from the Daemon Tools website, Daemon Tools 4.06 installs without a problem (and without a reboot), and I've noticed no problems mounting images or using them..

Sign In

[Release] SPTD driver v1.42 - x86 and x64

Recommended Posts

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Recently Browsing 0 members