Skip to content
View in the app

A better way to browse. Learn more.
MSFN

A full-screen app on your home screen with push notifications, badges and more.

To install this app on iOS and iPadOS
  1. Tap the Share icon in Safari
  2. Scroll the menu and tap Add to Home Screen.
  3. Tap Add in the top-right corner.
To install this app on Android
  1. Tap the 3-dot menu (⋮) in the top-right corner of the browser.
  2. Tap Add to Home screen or Install app.
  3. Confirm by tapping Install.

cfosspeed

alperefe
in Application Installs

Featured Replies

is there anyone knowing how to install cfosspeed in unattended way? :unsure: ı searched the forum but ı couldnt find!

it seems unpacked already but there is a setup file! sfx may be?? :} thanx alot!

Edited by alperefe


extract content (already done)

look in setup.ini (or similar)

and replace 0 by 1 for skip_welcome , skip_other ...

and you can just run setup to install silently ...

  • Author

yeah ı found it and did what you said but it didnt work. when ı changed the parameters it says "some of the files are corrupted" but when ı edit it like before, it is ok! :} ı think ı ll try sfx. thanx anyway!

yes try to find a solution , because I havn't this , I have just downloaded and fast studied .. goodluck and post your solution ... Goodbye.

I have an AutoIT script that works fine. A little tricky in that some of the controls don't click correctly, so you have to send keys (alt-N for next for example). I've verified that it installs the downloaded 212 version cleanly on a real system and in a VMware VM.

; ----------------------------------------------------------------------------
;
; AutoIt Version: 3.1.0
; Author:		 A.N.Other <myemail@nowhere.com>
;
; Script Function:
;	Template AutoIt script.
;
; ----------------------------------------------------------------------------

AutoITSetOption ("SendKeyDelay", 20)
AutoItSetOption("WinDetectHiddenText", 1)
AutoItSetOption("TrayIconDebug", 1)

Run (@WindowsDir & "\Temp\cfosspeed\setup.exe")
WinActivate ("cFosSpeed Installation Wizard")
WinWaitActive ("cFosSpeed Installation Wizard")
;ControlClick ("cFosSpeed Installation Wizard", "", "&Next")
Send ("!N")

ControlClick ("cFosSpeed Installation Wizard", "If you accept", "Button1")
Send ("!N")

WinWaitActive ("cFosSpeed Installation Wizard", "Set system restore")
ControlClick ("cFosSpeed Installation Wizard", "Set system restore", "Button1")
Send ("!N")

WinWaitActive ("cFosSpeed Installation Wizard", "installation directory")
Send ("!N")

$ret = 0
While $ret == 0
  $ret = WinWaitActive ("cFosSpeed Installation Wizard", "TCP receiver window", 5)
  if $ret == 0 then WinActivate ("cFosSpeed Installation Wizard", "TCP receiver window")
Wend
Send ("!N")

$ret = 0
While $ret == 0
  $ret = WinWaitActive ("cFosSpeed Installation Wizard", "Installation successful", 5)
  if $ret == 0 then WinActivate ("cFosSpeed Installation Wizard", "Installation successful")
Wend
ControlClick ("cFosSpeed Installation Wizard", "", "Finish")

; Now close the **** Explorer window it opens
$ret = 0
While $ret == 0
  $ret = WinWaitActive ("cFos Traffic Shaping", "", 5)
  if $ret == 0 then WinActivate ("cFos Traffic Shaping")
Wend
WinClose ("cFos Traffic Shaping")

; Move the desktop icons and move the start menu
FileMove (@DesktopDir & "\cFos Traffic Shaping.lnk", @ProgramsCommonDir & "\cFosSpeed Traffic Shaping\cFos Traffic Shaping.lnk")
FileMove (@DesktopDir & "\cFosSpeed Features.lnk",   @ProgramsCommonDir & "\cFosSpeed Traffic Shaping\cFosSpeed Features.lnk")
DirMove (@ProgramsCommonDir & "\cFosSpeed Traffic Shaping", @ProgramsCommonDir & "\Network Utilities\cFosSpeed Traffic Shaping")

Exit

It expects to see the unpacked installer in c:\windows\temp\cfospeed - just unpack it with winrar or whatever. The last section moves the desktop icons and the program group to where I want them - change to suit yourself.

D.

  • 2 years later...

this script for cfosspeed 4.21

Opt("SendKeyDelay",20)

Opt("WinWaitDelay",100)

Opt("WinTitleMatchMode",4)

Opt("WinDetectHiddenText",1)

Opt("MouseCoordMode",0)

Run('cfosspeed-v421-build1400.exe')

WinActivate ("cFosSpeed Installation Wizard")

WinWaitActive ("cFosSpeed Installation Wizard")

Send("{ALTDOWN}n{ALTUP}")

WinWaitActive ("cFosSpeed Installation Wizard")

ControlClick ("cFosSpeed Installation Wizard", "If you accept", "Button1")

Send("{ALTDOWN}n{ALTUP}")

WinWaitActive ("cFosSpeed Installation Wizard")

Send("{ALTDOWN}n{ALTUP}")

$ret = 0

While $ret == 0

$ret = WinWaitActive ("cFosSpeed Installation Wizard", "", 5)

if $ret == 0 then WinActivate ("cFosSpeed Installation Wizard", "")

Wend

Send("{ALTDOWN}n{ALTUP}")

$ret = 0

While $ret == 0

$ret = WinWaitActive ("cFosSpeed Installation Wizard", "TCP receiver window", 5)

if $ret == 0 then WinActivate ("cFosSpeed Installation Wizard", "TCP receiver window")

Wend

Send("{ALTDOWN}n{ALTUP}")

$ret = 0

While $ret == 0

$ret = WinWaitActive ("cFosSpeed Installation Wizard", "Installation successful", 5)

if $ret == 0 then WinActivate ("cFosSpeed Installation Wizard", "Installation successful")

Wend

ControlClick ("cFosSpeed Installation Wizard", "", "Finish")

$SF_1 = "cfosspeed-v421-build1400.exe"

If WinExists ( $SF_1 ) Then Exit

AutoItWinSetTitle ( $SF_1)

little modification from Halfwalker script :)

Edit

Edited by radix

radix have you turned off system restore on your windows ? because with your script the installer stops at the system restore point. please check and thanks for the help

post-90547-1206327028_thumb.jpg

Edited by johndoe74

radix have you turned off system restore on your windows ? because with your script the installer stops at the system restore point. please check and thanks for the help

It's turn off.

That window appear if System Restore is turn on (turn off is unchecked).

I will upload a new version when I come back from work.

Edited by radix

cfosspeed 4.20.1389 32 Bit version here

Edited by radix

hi radix, thanks for the update. installation progresses just fine but at the end, the the traffic shaping internet explorer window pops up!post-90547-1206376781_thumb.jpg

hi radix, thanks for the update. installation progresses just fine but at the end, the the traffic shaping internet explorer window pops up!post-90547-1206376781_thumb.jpg

That window doesn't appear to me.

But something similar pops up when I turned internet connection on and then launched Opera.

post-125681-1206377474_thumb.jpg

Edited by radix

Try again. 

cfosspeed 4.20.1389 32 Bit version:

Opt("TrayIconDebug", 1)
Opt("SendKeyDelay", 200)
; Executable file name
$EXECUTABLE = "cfosspeed-v420.exe"
; Installation folder
$INSTALLLOCATION = @ProgramFilesDir & "\cFosSpeed"
; Set system restore point
$RestorePoint = "0"
; Optimize TCP receiver window size
$Optimize = "1"
; Registration
; If you want to try cfosspeed for 30 days, let $Registration = "0". Else set $Registration = "1" and read below.
; In order to register cfosspeed silently, you need to install cfosspeed, copy key file into installation folder
; and reboot computer. After logon, when cfosspeed start, enter the password.
; Then goto this registry key: HKEY_LOCAL_MACHINE\SOFTWARE\cFos\cFosSpeed and copy the value from valuename Password2 below
; at $Password without commas and backslash. Copy your key file in the same folder with installer and compiled script and repack.
$Registration = "0"
$KeyFileName = "key.cfosspeed"
$Password = ""
; Run cfosspeed on Windows startup
$Autostart = "1"

If FileExists($INSTALLLOCATION & "\cfosspeed.exe") Then
	MsgBox(0x40010, @ScriptName, "Please uninstall previous version of cfosspeed before using this script", 4)
	Exit
EndIf

; Read from registry if System Restore is turn on or off
$DisableSR = RegRead("HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore", "DisableSR")

; Run the installer
Run($EXECUTABLE)

; Welcome to cFosSpeed v4.20!
WinWait("cFosSpeed Installation Wizard", "Welcome to cFosSpeed v4.20!")
WinActivate("cFosSpeed Installation Wizard", "Welcome to cFosSpeed v4.20!")
ControlClick("cFosSpeed Installation Wizard", "", "Button2")

; cFosSpeed 4.20.1389 Nutzungslizenz und Gewährleistung
WinWait("cFosSpeed Installation Wizard", "cFosSpeed 4.20.1389 Nutzungslizenz und Gewährleistung")
WinActivate("cFosSpeed Installation Wizard", "cFosSpeed 4.20.1389 Nutzungslizenz und Gewährleistung")
ControlCommand("cFosSpeed Installation Wizard", "", "Button1", "Check", "")
ControlClick("cFosSpeed Installation Wizard", "", "Button3")

; Start checking for two windows with "Set system restore point." and "You are online with the following connection:" text inside
AdlibEnable('_Adlib')

; Specify an installation directory.
WinWait("cFosSpeed Installation Wizard", "Specify an installation directory.")
WinActivate("cFosSpeed Installation Wizard", "Specify an installation directory.")
If $DisableSR = "0" Then
	ControlClick("cFosSpeed Installation Wizard", "", "Button5")
EndIf
If $DisableSR = "1" Then
	ControlClick("cFosSpeed Installation Wizard", "", "Button4")
EndIf

; Optimize TCP receiver window size. (Recommended)
WinWait("cFosSpeed Installation Wizard", "Optimize TCP receiver window size. (Recommended)")
WinActivate("cFosSpeed Installation Wizard", "Optimize TCP receiver window size. (Recommended)")
If $Optimize = "0" Then
	ControlCommand("cFosSpeed Installation Wizard", "", "Button1", "UnCheck", "")
EndIf
If $DisableSR = "0" Then
	ControlClick("cFosSpeed Installation Wizard", "", "Button7")
EndIf
If $DisableSR = "1" Then
	ControlClick("cFosSpeed Installation Wizard", "", "Button6")
EndIf

; Installation successful.
WinWait("cFosSpeed Installation Wizard", "Installation successful.")
WinActivate("cFosSpeed Installation Wizard", "Installation successful.")
If $DisableSR = "0" Then
	ControlClick("cFosSpeed Installation Wizard", "", "Button8")
EndIf
If $DisableSR = "1" Then
	ControlClick("cFosSpeed Installation Wizard", "", "Button7")
EndIf

; Stop checking for two windows with "Set system restore point." and "You are online with the following connection:" text inside
AdlibDisable()

Sleep(2000)

; Kill browser process
$PID = ProcessExists("IEXPLORE.EXE")
If $PID Then
	ProcessClose($PID)
EndIf
$PID = ProcessExists("Opera.exe")
If $PID Then
	ProcessClose($PID)
EndIf
$PID = ProcessExists("firefox.exe")
If $PID Then
	ProcessClose($PID)
EndIf

; Registration
If $Registration = "1" Then
	FileCopy($KeyFileName, $INSTALLLOCATION, 1)
	RegWrite("HKLM\SOFTWARE\cFos\cFosSpeed", "Password2", "REG_BINARY", $Password)
EndIf

; Block cfosspeed to run on Windows startup
If $Autostart = "0" Then
	RegDelete("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", "cFosSpeed")
EndIf

; Delete shortcut cFosSpeed Features from Desktop folder
FileDelete(@DesktopDir & "\cFosSpeed Features.lnk")

Func _Adlib()
; Set system restore point.
	If WinExists("cFosSpeed Installation Wizard", "Set system restore point.") Then
		WinActivate("cFosSpeed Installation Wizard", "Set system restore point.")
		If $RestorePoint = "0" Then
			ControlCommand("cFosSpeed Installation Wizard", "", "Button1", "UnCheck", "")
		EndIf
		ControlClick("cFosSpeed Installation Wizard", "", "Button4")
	EndIf
; You are online with the following connection:
	If WinExists("cFosSpeed Installation Wizard", "You are online with the following connection:") Then
		WinActivate("cFosSpeed Installation Wizard", "You are online with the following connection:")
		ControlClick("cFosSpeed Installation Wizard", "", "Button1")
		If $DisableSR = "0" Then
			ControlClick("cFosSpeed Installation Wizard", "", "Button6")
		EndIf
		If $DisableSR = "1" Then
			ControlClick("cFosSpeed Installation Wizard", "", "Button5")
		EndIf
	EndIf
EndFunc

Edited by radix

Create an account or sign in to comment
Go to topic listing

Recently Browsing 0

  • No registered users viewing this page.

Account

Navigation

Configure browser push notifications
Chrome (Android)
  1. Tap the lock icon next to the address bar.
  2. Tap Permissions → Notifications.
  3. Adjust your preference.
Chrome (Desktop)
  1. Click the padlock icon in the address bar.
  2. Select Site settings.
  3. Find Notifications and adjust your preference.