WinPE 3.0 & Sytantec Ghost

[ner]

Hi all,

I have created a new bootable CD under WinPE 3.0 and have also created a simple menu (thanks to you all at MSFN) and it works all OK. The only issue I have is that after restoring the image, Ghost exits back to the cmd prompt, and in order to restart the system i need to type in "Exit". Does anyone know what i can do, i have attached the menu screenshot and the ghost command used is~:

GHOST32.EXE -clone,MODE=restore,SRC=R:\IMAGE.GHO,dst=1 -sure -quiet -span -FX (now the -rb switch used by ghost will restart the PC, but i want to go back to the main menu- can this be done?)

Edited May 15, 2009 by ner

[gadget]

Search for PESHUTDOWN.EXE on this forum

[IcemanND]

Post your code, that may help us see what you need to do.

[ner]

the menu code is here:

@ECHO OFF

CLS

:LOOP

ECHO.SYSTEM RECOVERY KIT MENU V2.0

ECHO.

ECHO.

ECHO A. Start System Recovery Kit - Fully automated

ECHO B. Start System Recovery Kit - Manual

ECHO C. Run ExplorerXP

ECHO D. Capture Image using Microsoft Imagex

ECHO E. Apply Image using Microsoft Imagex

ECHO F. Run Diskpart - 1 partition creation and setup for disk 0

ECHO G. Start Backup Recovery - Fully Automated

ECHO H. Start Symantec Norton Ghost

ECHO I. Start Symantec Norton Ghost Explorer

ECHO Q. Quit Menu

ECHO.

:: SET /P prompts for input and sets the variable

:: to whatever the user types

SET Choice=

SET /P Choice=Type the letter and press Enter:

:: The syntax in the next line extracts the substring

:: starting at 0 (the beginning) and 1 character long

IF NOT '%Choice%'=='' SET Choice=%Choice:~0,1%

ECHO.

:: /I makes the IF comparison case-insensitive

IF /I '%Choice%'=='A' GOTO ItemA

IF /I '%Choice%'=='B' GOTO ItemB

IF /I '%Choice%'=='C' GOTO ItemC

IF /I '%Choice%'=='D' GOTO ItemD

IF /I '%Choice%'=='E' GOTO ItemE

IF /I '%Choice%'=='F' GOTO ItemF

IF /I '%Choice%'=='G' GOTO ItemG

IF /I '%Choice%'=='H' GOTO ItemH

IF /I '%Choice%'=='I' GOTO ItemI

IF /I '%Choice%'=='Q' GOTO End

ECHO "%Choice%" is not valid. Please try again.

ECHO.

GOTO Loop

:ItemA

RECOVERY32.EXE -clone,MODE=restore,SRC=R:\IMAGE.GHO,dst=1 -sure -quiet -span -RB

GOTO Again

:ItemB

RECOVERY32.EXE

GOTO END

:ItemC

Explorerxp.exe /s

GOTO END

:ItemD

imagex_capture.cmd

GOTO END

:ItemE

imagex_apply.cmd

goto END

:Itemf

Diskpart.cmd

goto END

:ItemG

GHOST32.EXE -clone,MODE=restore,SRC=D:\BACKUP.GHO,dst=1 -sure -quiet -span -RB

goto END

:ItemH

GHOST32.EXE

goto END

:ItemI

GHOSTexp.EXE

goto END

:QUIT

:End

see i have updated the last switch on the ghost command to read -rb and have taken away the -fx - this re-boots the pc OK, but i wanted to go back to the menu, but i get back to the cmd prompt, if i type in "Menu" it works...

[IcemanND]

Replace your 'goto END' to 'goto LOOP' where you want to return to your menu.

If this menu is running from the Startnet.cmd, add an EXIT command as the last line in startnet.cmd to cause the reboot.

[ner]

Thanks IcemanND: Just updated and testing now..

[ner]

Thank you so much!

Worked 100%

[Tripredacus]

Replace your 'goto END' to 'goto LOOP' where you want to return to your menu.

If this menu is running from the Startnet.cmd, add an EXIT command as the last line in startnet.cmd to cause the reboot.

Alternatively, he could also use the Q. option to run 'wpeutil reboot' correct?

[IcemanND]

That should also work

[gadget]

Deleted.

My post about PEShutdown is so dated, please ignore it.

Edited May 20, 2009 by gadget