Hey Guys !!!

Please, i need some help.

Anybody know what i have to do , to integrate a mui pack file in installation of windows vista ?

I show you a example:

Windows Vista Internacional Coporate DVD - PiterPen Release , X86 version have more than 10 languages for selection...my pack is PT-BR , i need to integrate this pack.

My vista dvd x64 have 3 languages, I need to integrate 1 more, the pt-br.

thank's

just to be sure that PT-BR u have is x64 too ?

if not u cant use it

I also interested in knowing how to integrate MUI packs, anyone know how?

Edited June 27, 200719 yr by nam265

I've modified some scripts, that I've found and put the whole process to one batch. It will integrate the given Language pack into all editions of Vista DVD.

Tested and working.

Integrate langpack.cmd

@Echo Off
Echo Enter path to Windows AIK:
Echo Example: C:\Program Files\Windows AIK
Set /p WAIK=
Echo.
Echo Enter path for mounting WIM file:
Echo Example: D:\VistaWork\Mount
Set /p WIM=
Echo.
Echo Enter path to directory with Vista DVD copied:
Echo Example: D:\VistaWork\DVD
Set /p WD=
Echo.
Echo Enter path to language pack:
Echo Example: D:\VistaWork\LP\lp.cab
Set /p LP=
Echo.
Echo Enter path for extracting the language pack:
Echo Example: D:\VistaWork\LPEXT
Set /p ELP=
Echo.
Echo Enter language pack ID:
Echo Example: en-US
Set /p LANG=
Echo.
Echo Select the Vista edition:
Echo Example: 1
Echo 1 - BUSINESS
Echo 2 - HOMEBASIC
Echo 3 - HOMEPREMIUM
Echo 4 - ULTIMATE
Echo 5 - BUSINESSN
Echo 6 - HOMEBASICN
Echo 7 - STARTER
Set /p EDITION=
Echo.

"%WAIK%\Tools\x86\Imagex.exe" /mountrw "%WD%\Sources\install.wim" %EDITION% "%WIM%"
"%WAIK%\Tools\PETools\peimg.exe" /list "%WIM%\Windows"
"%WAIK%\Tools\PETools\peimg.exe" /import="%LP%" "%WIM%\windows"
"%WAIK%\Tools\PETools\peimg.exe" /install=*LanguagePack* "%WIM%\windows"
"%WAIK%\Tools\x86\intlcfg.exe" -genlangini -dist:"%WD%" -image:"%WIM%" -f
"%WAIK%\Tools\PETools\peimg.exe" /lang=%LANG% "%WIM%\Windows"
"%WAIK%\Tools\PETools\peimg.exe" /timezone=%LANG% "%WIM%\Windows"
"%WAIK%\Tools\PETools\peimg.exe" /list "%WIM%\Windows"
"%WAIK%\Tools\x86\Imagex.exe" /unmount /commit "%WIM%"

Rd /S /Q "%ELP%"
Mkdir "%ELP%"
Expand "%LP%" -f:* "%ELP%"
Xcopy "%ELP%\setup\sources\%LANG%\*" "%WD%\sources\%LANG%" /cherkyi
Xcopy "%ELP%\sources\license\%LANG%\*" "%WD%\sources\license\%LANG%" /cherkyi
"%WAIK%\Tools\x86\Imagex.exe" /mountrw "%WD%\Sources\boot.wim" 2 "%WIM%"
Xcopy "%ELP%\setup\sources\%LANG%\*" "%WIM%\sources\%LANG%" /cherkyi
Xcopy "%ELP%\sources\license\%LANG%\*" "%WIM%\sources\license\%LANG%" /cherkyi
Copy "%WD%\sources\Lang.ini" "%WIM%\sources\Lang.ini"
"%WAIK%\Tools\x86\Imagex.exe" /unmount /commit "%WIM%"
Rd /S /Q "%ELP%"
Mkdir "%ELP%"

echo End of language pack integration.
pause

Edited July 2, 200719 yr by mhyll

Hope it helps.

can i select which one i want to slip? and do i need any stuff to do this or only the cmd? what is about the right folders?

You need Windows AIK (WAIK) installed.

If you don't want to download whole 900MB package, I can upload MiniPETools which contains all needed.

If you create folder structure like in Examples it will work.

You can select only one edition, by deleting the others from CMD.

Numbers:

1-BUSINESS

2-HOMEBASIC

3-HOMEPREMIUM

4-ULTIMATE

5-BUSINESSN

6-HOMEBASICN

7-STARTER

You can download MiniPETools at:

http://photography.ic.cz/MiniPETools.exe

mhyll, thank you but I can't distribute the peimg ms tool, I wish I could, then hotfixes would be supported as well. Now I gotta write my own routines but that might not even be possible with this new package thingy.

Couldn't you add it as requirements for running vLite, just like .NET??? MiniPETools have only 5MB.

Or maybe just like option.

And add routines, to check, if this is installed. If yes, hotfix and language slipstream will be available in vLite, if not, it will be unavailable.

Edited July 2, 200719 yr by mhyll

Vista has .NET in it, everyone running nLite have .NET. MiniPETools isn't MS product, too weird to make that requirement.

Too much work for optional features. When done it has to be supported from the box.

Vista has .NET in it, everyone running nLite have .NET. MiniPETools isn't MS product, too weird to make that requirement.

Too much work for optional features. When done it has to be supported from the box.

Maybe you can include MiniPETools.

Did they rewrite peimg from nothing?

Did they rewrite peimg from nothing?

I don't know. I just rewrote the script. You can check it in the earlier post. It allows selecting edition, into which you want to integrate tha langpack. Also did some automations. Check and write, if something can be better.

can i select which one i want to slip? and do i need any stuff to do this or only the cmd? what is about the right folders?

I rewrote the script to allow this.