Remote network shut down

[Maleko]

Looking for a good (ideally free!) netowkr shut down software.

As were getting tired of having to go round and shut all the work stations down at the end of the day!

So we want a program that lists computers in a domain, and enable us to send the command to shut them all down!

Cheers guys!

[Gouki]

Shutdown.exe ? It will not list the computers on the Domain, however, you can make a batch file with all the computers. (Entered manually)

Not a solution?

Google gave me this:

http://www.emco.is/remoteshutdown/rsdfeatures.html

I think they have a Free Version and a Profissional Version (not free).

Flash tutorial available here: http://www.emco.is/download/remoteshutdown...ctive_demo.html

Edited March 21, 2006 by Gouki

[Maleko]

looks like very good software, but only the client side is free..and costs a bit to buy

[kyuuzo]

I use psshutdown.exe with a text file.

http://www.sysinternals.com

[Gouki]

Making a batch file using shutdown.exe would also work good.

[SecretNinja]

how about http://www.beyondlogic.org/solutions/remot.../BeyondExec.htm

[nmX.Memnoch]

No need to use BeyondExec...shutdown.exe supports remote shutdowns with the -m switch.

Instead of doing it manually you could write a cmd file/script that parses all of the workstations that are online using net view, and then pass the shutdown command from there. Something like:

net view | find "partial_workstation_name" > workstations.txt

I could do something for you, but it'll be KiXtart based as that's what I deal with...someone else here may be able to do something with VBS if you prefer that.

C:\>shutdown.exe /?
Usage: shutdown.exe [-i | -l | -s | -r | -a] [-f] [-m \\computername] [-t xx] [-
c "comment"] [-d up:xx:yy]

		No args				 Display this message (same as -?)
		-i					  Display GUI interface, must be the first option
		-l					  Log off (cannot be used with -m option)
		-s					  Shutdown the computer
		-r					  Shutdown and restart the computer
		-a					  Abort a system shutdown
		-m \\computername	   Remote computer to shutdown/restart/abort
		-t xx				   Set timeout for shutdown to xx seconds
		-c "comment"			Shutdown comment (maximum of 127 characters)
		-f					  Forces running applications to close without war
ning
		-d [u][p]:xx:yy		 The reason code for the shutdown
								u is the user code
								p is a planned shutdown code
								xx is the major reason code (positive integer less than 256)
								yy is the minor reason code (positive integer less than 65536)

[libin]

shutdown.exe is a good tool. you can use it , and you need not install other softwares.

[Gouki]

shutdown.exe is a good tool. you can use it , and you need not install other softwares.

Yes. You'r right. However, it does not provide a LAN scan system, that from what I understood, is what Maleko is looking for.

Making a batch file would work, but it definatly gives more work than just scanning.

[nmX.Memnoch]

I went ahead with the KiX script. You can grab the KiXtart executables from http://www.kixtart.org/ (646KB download). If you're running any NT based OS all you need from the zip archive is KIX32.EXE. Just drop it in %SYSTEMROOT% (your Windows directory). The manual is also included in the zip archive in case you want to browse through it.

Now create a new empty directory. In that directory, create two new text files; one named remote_shutdown.cmd and one named remote_shutdown.kix. The KiX code below is documented so it should be fairly easy to decipher. If you want a good KiX editor check out AdminScriptEditor. It also does VBS, HTML, XML, CMD, AutoIt and several other languages.

Copy and paste the following into remote_shutdown.cmd.

%SYSTEMROOT%\KIX32.EXE .\remote_shutdown.kix

Copy and paste the following into remote_shutdown.kix.

/* --------------------------------------------------------------------
Author : Curtis Brabham
Date   : 22 Mar 2006
Purpose: Remote shutdown of multiple workstations.
Note 1 : This  script  depends  on  a  standardized  workstation/server
		 naming convention for successful operation.

Note 2 : shutdown.exe requires that you have  Administrator  privileges
		 on the remote computer.

Instructions:
=============
- Change the $TIMEOUT value to adjust the  wait period before  shutdown
  is initiated on the workstation.

- Change the $COMMENT value to change  the  message  displayed  on  the
  workstation/server prior to shutdown initiation.

- Edit the $WKSTR value for the  workstation  string.  Change  ********
  to a value that is common in all workstation names.
  Example:
  Computers in the Human Resources department  of  company  XYZ  use  a
  standardized computer naming convention.  The convention is:

  Company   Workstation/Laptop   Department	   Unique Number
  XYZ	   WK or LP			 HR			   ###

  So a workstation in Human Resources of company XYZ with an  inventory
  ID  of  A31  would  be  named  XYZWKHRA31.   The  common  string  for
  workstations in HR is "XYZWKHR" so you would set $WKSTR to "XYZWKHR".
  This would result in shutting down all workstations   that are online
  in the HR department.
-------------------------------------------------------------------- */

Break On
$X = SetTitle("Running Remote Shutdown Script...")
$TIMEOUT  = "30"
$COMMENT  = "After hours automated shutdown script."
; ------------------------------------------------------------------
$WKSTR   = "********"  ; <<<<<<< EDIT THIS VALUE
; ------------------------------------------------------------------

; Query for online workstations and dump output to a text file
Shell '%COMSPEC% /C NET VIEW | FIND "$WKSTR" > "@SCRIPTDIR\workstations.txt"'

; Open the text file and read each line for workstation names
If Open(1,"@SCRIPTDIR\workstations.txt",2) = 0
   $WK = ReadLine(1)
   While @ERROR = 0
	  If InStr($WK,"\\")
	; Trim trailing spaces from the text line
		 $WK = Trim(SubStr($WK,1,30))
		 ? "Attempting to shutdown $WK"
	; Run shutdown.exe for each workstation
		 Shell '%COMSPEC% /C shutdown.exe -s -m $WK -t $TIMEOUT -c "$COMMENT" -f'
	  EndIf
	; Read the next line and loop back to the If statement
	  $WK = ReadLine(1)
   Loop
 ; Close the text file after reading the last line
   $X = Close(1)
EndIf

; Delete the text file.
; Comment this line out if you want to review the text file.
Del "@SCRIPTDIR\workstations.txt"

; Exit the script
Exit

Edited March 23, 2006 by nmX.Memnoch