Duplicated User Accounts

[`Felix`]

Hey Felix!

I've been testing UPC for some days now, and I have a few things to report..

1. When a duplicated userfolder is detected and deleted the originally folder doesn't appear in "My Computer"

Ok so in the log is it reporting that it is deleting your original account too? need more information here... i need to try and duplicate the problem so i can fix it

2. The Popup only says "Duplicated profile dected", with the buttons "Yes"and "No". This isn't even a question. I really liked your previously version with the help button, and the possibility to write my own popup. (I would also like to translate this to my norwegian XP by time)

3. The popup is being displayed no mather what. Even if there isn't a duplicated account. It also creates the logfile, even though it doesn't delete anything.

4. I can't get the RESTART option to work. I have to restart manually. Is it necessary to restart? Is is not enough to logof the user like in the first version? Just asking.

Yes you do for all the profiles to be fully released from system control.

5. A SILENT option would be great. That way I won't have to answar yes during RunOnceEX. This wasn't a issue in the first version as I could edit the cmd-file myself. Can't do that now.

That's all.....

I also want to thank you for the work you have done so far. You are great!!

<{POST_SNAPBACK}>

Ok well the easiest thing i can do is just give you the source. here it is below With this you can remove the popup (for silent) or change it to include help and add anything else you like. Please let me know about clear changes you have made so i can keep updating my source. Let me know about the first issue you raise so i can address that asap. I have not been able to reproduce that issue here and did orginally test for that situation.

@ECHO OFF
:: Fix and Delete Duplicate Profiles 1.1.17
:: Copyright 2005, `felix`
:: Last updated: March 3, 2005

IF %OS%!==! GOTO:EOF
setlocal
If /I "%1"=="RESTART" SET RS=YES
set theNum=0
set KEY=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList
set gtid=getsid \\%computername% %username% \\%computername% %username%
for /f "Tokens=7" %%i in ('%gtid%^') do (set UserSID=%%i)
set qry1=reg query "%KEY%" /v ProfilesDirectory
set qry2=reg query "%KEY%" /s
set qry3=reg query "%KEY%\%USERSID%" /v ProfileImagePath
set fnd1=FIND /I "Documents and Settings" 
set fnd2=FIND /I "ProfileImagePath"
set fnd3=FIND /I "AllUsersProfile"
set fnd4=FIND /I "DefaultUserProfile"
set fnd5=FIND /I "LocalService"
set fnd6=FIND /I "NetworkService"
set fnd7=FIND /I "%UserName%"
for /f "Tokens=1,2*" %%i in ('%qry1%^|%fnd1%') do (set DocSetDir0=%%k)

CALL:CheckCurrentLocal
CALL:CheckIfDuplicate
if %RS%==YES call:restartIt
GOTO:EOF

:CheckCurrentLocal
:: Check the registry to and make sure the profiles are correct based
:: a totally clean default installation.  If duplicate profiles are
:: found based on reinstall or lost of user account information, we
:: correct the paths to the correct directories here.
FOR /f "Tokens=1,2*" %%i in ('%qry2%^|%fnd3%') do if /i not "%%k"=="All Users" (
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList" /v AllUsersProfile /d "All Users" /f >NUL )
FOR /f "Tokens=1,2*" %%i in ('%qry2%^|%fnd4%') do if /i not "%%k"=="Default User" (
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList" /v DefaultUserProfile /d "Default User" /f >NUL )
FOR /f "delims=\ Tokens=1,2*" %%i in ('%qry2%^|%fnd5%') do if /i not "%%k"=="LocalService" (
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\S-1-5-19" /v ProfileImagePath /d "%DocSetDir0%\LocalService" /f >NUL )
FOR /f "delims=\ Tokens=1,2*" %%i in ('%qry2%^|%fnd6%') do if /i not "%%k"=="NetworkService" (
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\S-1-5-20" /v ProfileImagePath /d "%DocSetDir0%\NetworkService" /f >NUL )
FOR /f "delims=\ Tokens=1,2*" %%i in ('%qry2%^|%fnd7%') do if /i not "%%k"=="%UserName%" (
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\%UserSID%" /v ProfileImagePath /d "%DocSetDir0%\%UserName%" /f >NUL )
GOTO:EOF

:CheckIfDuplicate
::Let the user know something is happening...
popup /YN /HF "userprofilechecker.hlp" /IS /M "Duplicate User Profile Detected" /T "User Profile Checker 1.1.16"
if errorlevel 7 EXIT
:: Now we actually check againist the registry for duplicates
:: Normally they will be username.computername, all users.windows,
:: default user.windows, localservice.nt authority and networkservice.nt authority.
:: the last 3 are hidden.
CALL:Header
FOR /f "Tokens=1,2*" %%i in ('%qry2%^|%fnd3%') do if /i "%%k"=="All Users" (CALL:DoIt "All Users" "%DocSetDir0%")
FOR /f "Tokens=1,2*" %%i in ('%qry2%^|%fnd4%') do if /i "%%k"=="Default User" (CALL:DoIt "Default User" "%DocSetDir0%")
FOR /f "delims=\ Tokens=1,2*" %%i in ('%qry2%^|%fnd5%') do if /i "%%k"=="LocalService" (CALL:DoIt "LocalService" "%DocSetDir0%")
FOR /f "delims=\ Tokens=1,2*" %%i in ('%qry2%^|%fnd6%') do if /i "%%k"=="NetworkService" (CALL:DoIt "NetworkService" "%DocSetDir0%")
FOR /f "delims=\ Tokens=1,2*" %%i in ('%qry3%^|%fnd7%') do if /i "%%k"=="%UserName%" (CALL:DoIt "%UserName%" "%DocSetDir0%")
CALL:Footer
GOTO:EOF

:Header
:: We output the list of directories to the log so we have a record
:: of the directories deleted and to check the script loaded.
> c:\AllUsersProfilefix.log echo Fix and Remove Duplicate Profiles 1.1.17
>> c:\AllUsersProfilefix.log echo Copyright 2005, `felix`
>> c:\AllUsersProfilefix.log echo www.simplify-i-t.com
>> c:\AllUsersProfilefix.log echo Automatically Generated %DATE:~-10%.
>> c:\AllUsersProfilefix.log echo --------------------------------------------------------------------------------
>> c:\AllUsersProfilefix.log echo.
>> c:\AllUsersProfilefix.log echo This computer was found to have one or more duplicate system or user profiles.
>> c:\AllUsersProfilefix.log echo.
>> c:\AllUsersProfilefix.log echo The following registry key has been updated with restored values.
>> c:\AllUsersProfilefix.log echo  "%KEY%"
>> c:\AllUsersProfilefix.log echo.
GOTO:EOF

:Footer
>> c:\AllUsersProfilefix.log echo.
>> c:\AllUsersProfilefix.log echo --------------------------------------------------------------------------------
>> c:\AllUsersProfilefix.log echo This issue is possibly caused by the following reasons:
>> c:\AllUsersProfilefix.log echo * The computer operating system has been reinstalled.
>> c:\AllUsersProfilefix.log echo * The computer operating system has been restore from a back-up image.
>> c:\AllUsersProfilefix.log echo.
>> c:\AllUsersProfilefix.log echo For more information please see Microsoft Knowledge Base Article link below:
>> c:\AllUsersProfilefix.log echo http://support.microsoft.com/default.aspx?...kb;en-us;314045
>> c:\AllUsersProfilefix.log echo.
GOTO:EOF

:Doit
:: We check to make sure it is not a valid user directory and 
:: unhide all the directories that are hidden first so we can
:: build the list to remove them.
for /f "usebackq delims= tokens=1,2" %%i IN (`dir /a /b "%~2\%~1*"`) DO IF /i "%%i" NEQ "%~1" attrib -a -s -h "%~2\%%i"
for /f "usebackq delims= tokens=1,2" %%i IN (`dir /ad /b "%~2\%~1*"`) DO IF /i "%%i" NEQ "%~1" call:flagIt %~2\%%i
GOTO:EOF

:flagIt
:: The list of duplicate/unrequired directories is built
:: and added to the Local Machine RunOnce key to be removed
:: at next boot.
:: The directories can not be removed before a reboot because the
:: system still has them loaded even know we have changed the paths
:: in the registry.
set /a theNum=%theNum%+1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce" /v RemoveDuplicateProfile%theNum% /d "%comspec% /C RMDIR /S /Q """%*"""" /f >NUL
>> c:\AllUsersProfilefix.log echo  %theNum%. %* has been deleted!
GOTO:EOF

:restartIt
shutdown -r -f -t 90 -c "%computername%" needs to restart to finish the update to the user profiles."
GOTO:EOF
endlocal

[esas]

Hi!

I've been looking at the source and made some changes.

@ECHO OFF

:: Fix and Delete Duplicate Profiles 1.1.17

:: Copyright 2005, `felix`

:: SILENT option added by esas

:: Last updated: March 10, 2005

IF %OS%!==! GOTO:EOF

setlocal

::Check for options (RESTART or SILENT)

If /I "%1"=="RESTART" SET RS=YES

If /I NOT "%1"=="RESTART" SET RS=NO

if %RS%==NO goto CheckmoreRS

if %RS%==YES goto SkipCheckmoreRS

:CheckmoreRS

If /I "%2"=="RESTART" SET RS=YES

If /I NOT "%2"=="RESTART" SET RS=NO

:SkipCheckmoreRS

If /I "%1"=="SILENT" SET SL=YES

If /I NOT "%1"=="SILENT" SET SL=NO

if %SL%==NO goto CheckmoreSL

if %SL%==YES goto SkipCheckmoreSL

:CheckmoreSL

If /I "%2"=="SILENT" SET SL=YES

If /I NOT "%2"=="SILENT" SET SL=NO

:SkipCheckmoreSL

set theNum=0

set KEY=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList

set gtid=getsid \\%computername% %username% \\%computername% %username%

for /f "Tokens=7" %%i in ('%gtid%^') do (set UserSID=%%i)

set qry1=reg query "%KEY%" /v ProfilesDirectory

set qry2=reg query "%KEY%" /s

set qry3=reg query "%KEY%\%USERSID%" /v ProfileImagePath

set fnd1=FIND /I "Documents and Settings"

set fnd2=FIND /I "ProfileImagePath"

set fnd3=FIND /I "AllUsersProfile"

set fnd4=FIND /I "DefaultUserProfile"

set fnd5=FIND /I "LocalService"

set fnd6=FIND /I "NetworkService"

set fnd7=FIND /I "%UserName%"

for /f "Tokens=1,2*" %%i in ('%qry1%^|%fnd1%') do (set DocSetDir0=%%k)

CALL:CheckCurrentLocal

CALL:CheckIfDuplicate

if %RS%==YES call:restartIt

GOTO:EOF

:CheckCurrentLocal

:: Check the registry to and make sure the profiles are correct based

:: a totally clean default installation.  If duplicate profiles are

:: found based on reinstall or lost of user account information, we

:: correct the paths to the correct directories here.

FOR /f "Tokens=1,2*" %%i in ('%qry2%^|%fnd3%') do if /i not "%%k"=="All Users" (

reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList" /v AllUsersProfile /d "All Users" /f >NUL )

FOR /f "Tokens=1,2*" %%i in ('%qry2%^|%fnd4%') do if /i not "%%k"=="Default User" (

reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList" /v DefaultUserProfile /d "Default User" /f >NUL )

FOR /f "delims=\ Tokens=1,2*" %%i in ('%qry2%^|%fnd5%') do if /i not "%%k"=="LocalService" (

reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\S-1-5-19" /v ProfileImagePath /d "%DocSetDir0%\LocalService" /f >NUL )

FOR /f "delims=\ Tokens=1,2*" %%i in ('%qry2%^|%fnd6%') do if /i not "%%k"=="NetworkService" (

reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\S-1-5-20" /v ProfileImagePath /d "%DocSetDir0%\NetworkService" /f >NUL )

FOR /f "delims=\ Tokens=1,2*" %%i in ('%qry2%^|%fnd7%') do if /i not "%%k"=="%UserName%" (

reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\%UserSID%" /v ProfileImagePath /d "%DocSetDir0%\%UserName%" /f >NUL )

GOTO:EOF

:CheckIfDuplicate

::Let the user know something is happening unless SILENT option in used...

if %SL%==YES goto Skippopup

popup /YN /HF "userprofilechecker.hlp" /IS /M "Duplicate User Profile Detected" /T "User Profile Checker 1.1.16"

if errorlevel 7 EXIT

:Skippopup

:: Now we actually check againist the registry for duplicates

:: Normally they will be username.computername, all users.windows,

:: default user.windows, localservice.nt authority and networkservice.nt authority.

:: the last 3 are hidden.

CALL:Header

FOR /f "Tokens=1,2*" %%i in ('%qry2%^|%fnd3%') do if /i "%%k"=="All Users" (CALL:DoIt "All Users" "%DocSetDir0%")

FOR /f "Tokens=1,2*" %%i in ('%qry2%^|%fnd4%') do if /i "%%k"=="Default User" (CALL:DoIt "Default User" "%DocSetDir0%")

FOR /f "delims=\ Tokens=1,2*" %%i in ('%qry2%^|%fnd5%') do if /i "%%k"=="LocalService" (CALL:DoIt "LocalService" "%DocSetDir0%")

FOR /f "delims=\ Tokens=1,2*" %%i in ('%qry2%^|%fnd6%') do if /i "%%k"=="NetworkService" (CALL:DoIt "NetworkService" "%DocSetDir0%")

FOR /f "delims=\ Tokens=1,2*" %%i in ('%qry3%^|%fnd7%') do if /i "%%k"=="%UserName%" (CALL:DoIt "%UserName%" "%DocSetDir0%")

CALL:Footer

GOTO:EOF

:Header

:: We output the list of directories to the log so we have a record

:: of the directories deleted and to check the script loaded.

> c:\AllUsersProfilefix.log echo Fix and Remove Duplicate Profiles 1.1.17

>> c:\AllUsersProfilefix.log echo Copyright 2005, `felix`

>> c:\AllUsersProfilefix.log echo www.simplify-i-t.com

>> c:\AllUsersProfilefix.log echo Automatically Generated %DATE:~-10%.

>> c:\AllUsersProfilefix.log echo --------------------------------------------------------------------------------

>> c:\AllUsersProfilefix.log echo.

>> c:\AllUsersProfilefix.log echo This computer was found to have one or more duplicate system or user profiles.

>> c:\AllUsersProfilefix.log echo.

>> c:\AllUsersProfilefix.log echo The following registry key has been updated with restored values.

>> c:\AllUsersProfilefix.log echo  "%KEY%"

>> c:\AllUsersProfilefix.log echo.

GOTO:EOF

:Footer

>> c:\AllUsersProfilefix.log echo.

>> c:\AllUsersProfilefix.log echo --------------------------------------------------------------------------------

>> c:\AllUsersProfilefix.log echo This issue is possibly caused by the following reasons:

>> c:\AllUsersProfilefix.log echo * The computer operating system has been reinstalled.

>> c:\AllUsersProfilefix.log echo * The computer operating system has been restore from a back-up image.

>> c:\AllUsersProfilefix.log echo.

>> c:\AllUsersProfilefix.log echo For more information please see Microsoft Knowledge Base Article link below:

>> c:\AllUsersProfilefix.log echo http://support.microsoft.com/default.aspx?...kb;en-us;314045

>> c:\AllUsersProfilefix.log echo.

GOTO:EOF

:Doit

:: We check to make sure it is not a valid user directory and

:: unhide all the directories that are hidden first so we can

:: build the list to remove them.

for /f "usebackq delims= tokens=1,2" %%i IN (`dir /a /b "%~2\%~1*"`) DO IF /i "%%i" NEQ "%~1" attrib -a -s -h "%~2\%%i"

for /f "usebackq delims= tokens=1,2" %%i IN (`dir /ad /b "%~2\%~1*"`) DO IF /i "%%i" NEQ "%~1" call:flagIt %~2\%%i

GOTO:EOF

:flagIt

:: The list of duplicate/unrequired directories is built

:: and added to the Local Machine RunOnce key to be removed

:: at next boot.

:: The directories can not be removed before a reboot because the

:: system still has them loaded even know we have changed the paths

:: in the registry.

set /a theNum=%theNum%+1

reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce" /v RemoveDuplicateProfile%theNum% /d "%comspec% /C RMDIR /S /Q """%*"""" /f >NUL

>> c:\AllUsersProfilefix.log echo  %theNum%. %* has been deleted!

GOTO:EOF

:restartIt

shutdown -r -f -t 90 -c "%computername% needs to restart to finish the update to the user profiles."

GOTO:EOF

endlocal

As you can see I've added a SILENT option. It can be used with or without the RESTART option, and it doesn't mather in whitch order you put the options.

The reson the RESTART option didn't work before was a error in the shutdown line.

I removed the " after the %computername% and it worked.

You might want to put the UserprofileChecker.hlp in the UPC.rar. I wasn't using it untill I saw I had to in the source. Figured it build in with the UPC.exe or something.

It still creates the logfile and launches the popup (If the SILENT option isn't used) even though there isn't duplicated user account. A little irritating.

Ok so in the log is it reporting that it is deleting your original account too? need more information here... i need to try and duplicate the problem so i can fix it

No the log only report that it has deleted the new account. Except for this the original account seems find.

[Bebbetufs]

Is there an updated package available for download somewhere?

[Acheron]

This method is new to me but it sounds cool.

I would like to see an option to do all this stuff before a user actually logons.

AFAIK all changes upto T13 are copied to the Default User Account. However this account is created directly after the commands from cmdlines.txt have passed (T12)

More interesting is that this account is not in use during install but the generic System Account is used.

The Administrator account is created at first logon after the reboot.

Is it possible to run this script at T9 [setupParams] to move the newly created Default User.001 Account to Default User, overwriting existing files and change the appropiate registry entries, since it's not yet in use.

This would be cool in use when you have specific software settings not stored in the registry, custom shortcuts etc, documents folder, history, favorites etc. from a previous installation. All you would have to do is a unique username for each system.

If anyone has experience with this please reply

[Acheron]

I have worked this out. For me it's not necessary to keep the existing user profiles. So I use this:

WinNT.sif

[SetupParams]
    UserExecute="cmd.exe /C adminchange.cmd"

cmdlines.txt

[COMMANDS]
"runonceex.cmd"
"rundll32.exe iernonce.dll,RunOnceExProcess"

RunOnceEx.cmd

@echo off
FOR %%a IN (C D E F G H I J K L M N O P Q R S T U V W X Y Z) DO ((( set drv=%%a:) & (call :setupdocs))
)
goto :ending

:setupdocs
FOR /F "tokens=7 delims=:= " %%a IN ( 'vol %drv%' ) DO (
IF /I %%a==Documenten (
set docsdrive=%drv%
)
IF /I %%a==nLite (
set CDDRIVE=%drv%
goto :endloop
)
)
:endloop
GOTO :EOF
:ending
IF not defined docsdrive set docsdrive=%systemdrive%
IF NOT Defined CDDRIVE set CDDRIVE=%CD%^\^.^.
cacls "%docsdrive%\Profieldata\" /E /T /P Administrators:F
rmdir /S /Q "%docsdrive%\Profieldata"
reg add "HKLM\Software\Microsoft\Windows NT\CurrentVersion\Profilelist" /v "ProfilesDirectory" /t REG_EXPAND_SZ /d "%docsdrive%\Profieldata" /f

AdminChange.cmd

@echo off
FOR %%a IN (C D E F G H I J K L M N O P Q R S T U V W X Y Z) DO ((( set drv=%%a:) & (call :setupdocs))
)
goto :ending

:setupdocs
FOR /F "tokens=7 delims=:= " %%a IN ( 'vol %drv%' ) DO (
IF /I %%a==Documenten (
set docsdrive=%drv%
)
IF /I %%a==nLite (
set CDDRIVE=%drv%
goto :endloop
)
)
:endloop
GOTO :EOF
:ending
IF not defined docsdrive set docsdrive=%systemdrive%
IF NOT Defined CDDRIVE set CDDRIVE=%CD%^\^.^.
::get systemsid
for /f "skip=1" %%a in ('psgetsid') do set sid=%%a
::set adminsid
set adminsid=%sid%-500
for /f "tokens=2* delims=\" %%a in ('reg query "hklm\software\microsoft\windows nt\currentversion\profilelist\%adminsid%" /v "ProfileImagePath"') do set pid=%%b
reg add "HKLM\Software\Microsoft\Windows NT\CurrentVersion\Profilelist" /v "ProfilesDirectory" /t REG_EXPAND_SZ /d "%docsdrive%\Profieldata" /f
reg add "HKLM\Software\Microsoft\Windows NT\CurrentVersion\Profilelist\%adminsid%" /v "ProfileImagePath" /t REG_EXPAND_SZ /d "%docsdrive%\Profieldata\Administrator" /f
XCOPY /C /H /E /O /I /Y "%systemdrive%\Documents and Settings" "%docsdrive%\Profieldata"
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce" /v "CleanProfile" /d "cmd.exe /C \"RMDIR /S /Q \"%systemdrive%\Documents and Settings\"\"" /f
EXIT

You need psgetsid btw.

Edited October 2, 2005 by hp38guser

[gunsmokingman]

I do not know if this will help but here a VBS script that list all users

on a local computer. It will leave this UserList.txt in where it was ran from.

On Error Resume Next

Const HKEY_LOCAL_MACHINE = &H80000002 : Const Write = 2

Dim Fso : Set Fso = CreateObject("Scripting.FileSystemObject")

Dim Ts : Set Ts = Fso.OpenTextFile("UserList.txt", Write,True)

strComputer = "."

Set objRegistry=GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")

strKeyPath = "SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList"

objRegistry.EnumKey HKEY_LOCAL_MACHINE, strKeyPath, arrSubkeys

For Each objSubkey In arrSubkeys

    strValueName = "ProfileImagePath"

    strSubPath = strKeyPath & "\" & objSubkey

    objRegistry.GetExpandedStringValue HKEY_LOCAL_MACHINE,strSubPath,strValueName,strValue

    Ts.WriteLine strValue

Next

Ts.close

[Schmitty]

How do you set the silent parameter when using UserProfileChecker.cmd?

[esas]

Hey!

It's been a while since I used this stuff, so I don't remember everything about it.

I'm posting the last file I made. You don't need all the extra files anymore, since they are al compiled into this new one.

To run the script silent just run "UPC.exe SILENT"

I think I have to start working on this again after reading the new posts..

UPC.rar

[`Felix`]

Hey!

It's been a while since I used this stuff, so I don't remember everything about it.

I'm posting the last file I made. You don't need all the extra files anymore, since they are al compiled into this new one.

To run the script silent just run "UPC.exe SILENT"

I think I have to start working on this again after reading the new posts..

Goodone esas - the only thing i notice is that when you run it (without the silient option) that it tell you there is "Duplicate user profile detected" even when there is not. Other than that looks good - I noticed you cleaned up the code as well - well done

[Schmitty]

Hey!

It's been a while since I used this stuff, so I don't remember everything about it.

I'm posting the last file I made. You don't need all the extra files anymore, since they are al compiled into this new one.

To run the script silent just run "UPC.exe SILENT"

I think I have to start working on this again after reading the new posts..

Hi Esas,

I would like to know if this will work on machines which don't have the user profiles set at the default location of Documents & Settings, as mine uses a path of C:\Users or %systemdrive%\Users (basically the same path).

And, is the silent parameter supposed to restart the machine automatically? I tried running the new exe but it didn't even attempt to restart.

[ccc]

I realize this is an old thread.

But if any of the experts here are still around, could you please help out on this thread:

http://www.msfn.org/board/index.php?showtopic=86965

Thanks.