Command or Batch to list all Files in a Directory and output to TXT fi

[Pantner]

Ok, a while ago, i found a command on this site (i think) that would list all the files in a single directory and then output them to a TXT file...

im setting up a new Unattended install, and need t do the updates, im using the SVCPACK method...

does anyone know wat it is???

i tried searching, but came up with nada

[druiddk]

Hi,

Well you could use this command to output it to a txt file:

dir /B C:\LOCATION\OF\KB\FILES\*.EXE > C:\WHERE\TO\OUTPUT\FILE.TXT

Just make sure you dont have any other EXE files in the same folder.

Edited December 22, 2005 by druiddk

[Shamwari]

Are you trying to automate the patching of your XP source with the latest hofixes? If you are, you could use the following cmd found at Gadgets and Tech news:

@Echo off
rem ////////////////////////////////////////////////////////////////////////////
rem // IntegrateAll.bat
rem // This Batch file integrates the hotfixes for Windows XP SP2
rem // Syntax:
rem //   Integrateall <DistributionFolder>
rem ////////////////////////////////////////////////////////////////////////////

if "%~1" == "-p" goto Process

rem ////////////////////////////////////////////////////////////////////////////
rem // Main routine
rem // %1 contains Options
rem //

rem //
rem // Verify that we are pointing to a distribution folder base
rem //
if exist "%~1\I386" goto FolderExists

echo -- "%~1" is not a distribution folder.
echo Syntax:
echo   IntegrateAll ^<DistributionFolder^>
goto END

:FolderExists

echo ::: Integrating Updates :::

set DISTDIR="%~1"
set HFINT="%~1\i386\svcpack\HFINT.DAT"
set HFINTTEMP="%~1\i386\svcpack\HFINT.TMP"

rem // 
rem // Do 885835 and then 885250 to start with. There is a conflict here. So
rem // we need to do some special processing. Note: 885835 is superceeded by
rem // 885250 but we want an entry so that the hotfix show as installed
rem //
call %0 -p KB885835 "KB885835.exe" 

rem // Modify the line mrxsmb.sys (change it to mrxsmb.sys.tmp)
for /f "usebackq" %%L in (%HFINT%) DO (
 if %%L==mrxsmb.sys (
  echo %%L.tmp>>%HFINTTEMP%
 ) else (
  echo %%L>>%HFINTTEMP% )
)
move /y %HFINTTEMP% %HFINT% > NUL

rem // Integrate 85250  
call %0 -p KB885250 "KB885250.exe" 

rem // Modify the line back (change the mrxsmb.sys.tmp back to mrxsmb.sys)
for /f "usebackq" %%L in (%HFINT%) DO (
 if %%L==mrxsmb.sys.tmp ( 
  echo mrxsmb.sys>>%HFINTTEMP%
 ) else (
   echo %%L>>%HFINTTEMP% 
 )
)
move /y %HFINTTEMP% %HFINT% > NUL

rem //
rem // Now integrate all the rest of the hotfixes.

call %0 -p KB873339 "KB873339.exe" 
call %0 -p KB885626 "KB885626.exe" 
call %0 -p KB885836 "KB885836.exe" 
call %0 -p KB886185 "KB886185.exe" 
call %0 -p KB887742 "KB887742.exe" 
call %0 -p KB888113 "KB888113.exe" 
call %0 -p KB888302 "KB888302.exe" 
call %0 -p KB890046 "KB890046.exe" 
call %0 -p KB890859 "KB890859.exe" 
call %0 -p KB891781 "KB891781.exe" 
call %0 -p KB893066 "KB893066.exe" 
call %0 -p KB893756 "KB893756.exe" 
call %0 -p KB893803 "KB893803.exe" 
call %0 -p KB894391 "KB894391.exe" 
call %0 -p KB896358 "KB896358.exe" 
call %0 -p KB896422 "KB896422.exe" 
call %0 -p KB896423 "KB896423.exe" 
call %0 -p KB896424 "KB896424.exe" 
call %0 -p KB896428 "KB896428.exe" 
call %0 -p KB896688 "KB896688.exe" 
call %0 -p KB899587 "KB899587.exe" 
call %0 -p KB899589 "KB899589.exe" 
call %0 -p KB899591 "KB899591.exe" 
call %0 -p KB900725 "KB900725.exe" 
call %0 -p KB901017 "KB901017.exe" 
call %0 -p KB901214 "KB901214.exe" 
call %0 -p KB902400 "KB902400.exe" 
call %0 -p KB904706 "KB904706.exe" 
call %0 -p KB905414 "KB905414.exe" 
call %0 -p KB905749 "KB905749.exe" 

echo.
echo ::: Done :::
echo.

goto END

rem ////////////////////////////////////////////////////////////////////////////
rem ////////////////////////////////////////////////////////////////////////////
:Process
rem //
rem // %2 will contain the KB number
rem // %3 will contain the Exe file name
rem //

echo Integrating %2
"%~3" /integrate:%DISTDIR% /passive

:EndProcess
goto END

rem ////////////////////////////////////////////////////////////////////////////

:END

Edited December 22, 2005 by Shamwari

[Pantner]

@druiddk, thats the one!

@Shamwari...hmm, thats a little too complicated for me me thinks...but thanks anyway...

[Oleg_II]

Pantner

You can find a great script here.