Windows 2000 Unattend?

**holygrail_4** · March 15, 2004

Hi all

I've done the XP unattended CD and all worked well. My only query is for my working environment, 2000 is the prefered OS.

Do the same steps work under 2000 as per XP? I know they're closley linked (NT5 vs NT5.1) but will this make the process different?

Perhaps someone could post a guide specific to Windows 2000?

Cheers

**Alanoll** · March 16, 2004

most of it is the same.

if you used a svcpack.inf, i believe the top portion is different (the Version tag) and that's just been recently answered.

You could most likely use the same Winnt.sif but change the ProductKey and everything accordingly. You may also want to have a look at the deploy documentation for Win2k and that might answer alot of your questions

**diesel_98a** · March 16, 2004

there is really no guide, it is pretty much the same as xp, search the forum, this has been touched on many times. if u are using the same software & want about the same type of setup, just copy it over from winxp to win2k.

**AirMaleDFW** · March 16, 2004

I am working on a Win2K disk now and there are a number of things to look out for. First of all, I'm updating IE from 5.5 to 6.0 SP1 in SVCPACK. IE 6 SP1 writes a number of items to RunOnceEx. I'm also installing MS Java and updating MDAC from the 2.53 that Win2K SP4 comes with to 2.8. The MDAC install also writes to RunOnceEx and does so right on top of some IE6 SP1 keys (not good).

I've worked those out and some things other updates do. The only item I had to do outside of SVCPACK is the MDAC hotfix (KB832483). It didn't like my updating to a new MDAC and then updating that in the same SVCPACK stage. I had to do KB832483 in RunOnceEx.

I'll post some files and notes on what the various updates do to the run keys shortly.

**holygrail_4** · March 16, 2004

Thanks to all who replied. I must confess I hadn't tried it yet - was keen to get the info before I got myself utterly confused and angry.

Yeah AirMale, my main query would be stuff like IE cause you don't have to do this in XP. Apologies for the duplicate posting - I tried searching first but couldn't find anything useful.

Cheers

**Shotgun** · March 16, 2004

I'm currently ironing out the last details of my Win2K SP4 Unattended CD. I install using Wraith's Xplode installer. I install IE 6 SP1 first then let it finish the RunOnceEx settings on the first logon, then do a reboot and on a 2nd login install everything else. Up to this point, it has worked well for my needs and I'm currently trying to automate user permissions and some minor stuff before publishing a guide for it.

**Alanoll** · March 16, 2004

just out of curiousity...

after the IE6 install has entered the entries in RunOnceEX, has anyone tried while still in setup (i dunno if possible, haven't touched 2k in a while) to try and open regedit and export the entries, then move them to another number so you can continue to use RunOnceEX with other values after it?

Just out of curiousity.

**AirMaleDFW** · March 16, 2004

I used XPCREATE so i'll reference the directories that it uses. Critical updates I named CQxxxxxx.EXE and recommended updates I named RQxxxxxx.EXE. Otherwise I named them something that indicated what they were.

SVC-HF1:

CQ329115.EXE, CQ823182.EXE, CQ823559.EXE, CQ824105.EXE, CQ824141.EXE, CQ824146.EXE, CQ825119.EXE, CQ826232.EXE, CQ828026.EXE, CQ828028.EXE, CQ828035.EXE, CQ828749.EXE, RQ818043.EXE, RQ820888.EXE, RQ822831.EXE, RQ829558.EXE

SVC-HF2:

CJS56NEN.EXE, CQ330994.EXE, CQ832894.EXE, ROOTCERT.EXE, VBS56NEN.EXE

SVC-DAS:

MDAC_TYP.EXE

SVC-DAH:

CQ832483.EXE

SVC-PRE:

R_DX90b.EXE

SVC-WMP:

R_MPSetup.EXE

SVC-X2M:

R_DOTNET.EXE, R_JVIEW.EXE

SVC-EXE:

IE6SP1.EXE, MSJ-2K.EXE, QCHAIN.EXE, REGIE6.EXE, REG_OEX.EXE, T13_START.EXE

I halt XPC before it creates an ISO because it generates a SVCPACK.INF in alphabetical order. Some updates should be done before others so I rearange SVCPACK.INF, re-compress and place it CDROOT\I386.

SVCPACK.INF

[Version] 
Signature="$Windows NT$" 
MajorVersion=5 
MinorVersion=0 
BuildNumber=2195  

[SetupData] 
CatalogSubDir="\i386\svcpack" 

[SetupHotfixesToRun] 
;Copy over reg.exe, shutdown.exe and do some other minor things
T13_START.EXE

;Install IE6 SP1
IE6SP1.EXE 

;Remove the RunOnceEx keys placed by the IE6 install and register the DLL's by Regsvr32
REG_IE6.EXE 

;Install MS Java 3810
MSJ-2K.EXE 

;Install MDAC 2.8 and replace version 2.5
MDAC_TYP.EXE /Q:A /R:N 

;Remove the RunOnceEx keys placed by the MDAC installation and register the DLL's by Regsvr32
REG_MDAC.EXE 

;Install Outlook Express Update for IE6 SP1
CQ330994.EXE /Q:A /R:N 

;Remove the RunOnceEx keys placed by 330994 and register the DLL's by Regsvr32
REG_OEX.EXE

MPSETUP.EXE /Q:A /R:N 
329115.EXE /Q /U /O /N /Z 
818043.EXE /Q /U /O /N /Z 
820888.EXE /Q /U /O /N /Z 
822831.EXE /Q /U /O /N /Z 
823182.EXE /Q /U /O /N /Z 
823559.EXE /Q /U /O /N /Z 
824105.EXE /Q /U /O /N /Z 
824141.EXE /Q /U /O /N /Z 
824146.EXE /Q /U /O /N /Z 
825119.EXE /Q /U /O /N /Z 
826232.EXE /Q /U /O /N /Z 
828026.EXE /Q /U /O /N /Z 
828028.EXE /Q /U /O /N /Z 
828035.EXE /Q /U /O /N /Z 
828749.EXE /Q /U /O /N /Z 
829558.EXE /Q /U /O /N /Z 
CQ832894.EXE /Q:A /R:N 
ROOTCERT.EXE /Q:A /R:N 
R_DOTNET.EXE /Q:A /R:N 
R_DX90B.EXE /Q:A /R:N 
R_JVIEW.EXE /Q:A /R:N 
VBS56NEN.EXE /Q:A /R:N 
CJS56NEN.EXE /Q:A /R:N 
; If you don't wish to update your MDAC to 2.8 with MDAC_TYP
; (it's not critical or recommended)
; you can probably do 832483 here... I had to do in the RunOnceEx stage
;CQ832483.EXE
QCHAIN.EXE

[ProductCatalogsToInstall] 
KB329115.CAT 
KB820888.CAT 
KB822831.CAT 
KB823182.CAT 
KB823559.CAT 
KB824105.CAT 
KB824141.CAT 
KB824146.CAT 
KB825119.CAT 
KB826232.CAT 
KB828028.CAT 
KB828035.CAT 
KB828749.CAT 
KB829558.CAT 
Q330994.CAT 
Q818043.CAT 
Q828026.CAT 
Q832894.CAT 
VBS56NEN.CAT 
JS56NEN.CAT

The first thing I do in SVCPACK.INF is a T13_START.CMD file (repackaged with IExpress into an EXE). This copies over reg.exe and shutdown.exe from Windows XP so I can do registry manipulation via cmd file. The shutdown.exe I didn't end up using.

T13_START.CMD

@ECHO OFF

:: Make the %SYSTEMDRIVE%\TEMP directory and copy the
:: updates and applications there for later installation via
:: RunOnceEx in the registry

MKDIR %SYSTEMDRIVE%\TEMP >NUL 

START /WAIT APPS.EXE >NUL 

:: Move the WinXP file "reg.exe" to the %WINDIR%\system32 directory so we can reg modify via command line
:: Move the WinXP file "shutdown.exe" to the %WINDIR%\system32 directory so we can command line shutdown / reboot

MOVE /Y reg.exe %WINDIR%\system32
MOVE /Y shutdown.exe %WINDIR%\system32

:: Stop the Messenger service because it is nothing but a hole for
:: popups over the internet... it is intended for INTRANET corporate use
:: DISABLE that Messenger service and then set the IIS Services (WWW, FTP and Mail)
:: as MANUAL startup instead of AUTOMATIC

NET STOP MESSENGER >NUL 
NET STOP W3SVC >NUL 
NET STOP MSFtpsvc >NUL 
NET STOP SMTPSVC >NUL 

SET KEY=HKLM\SYSTEM\CurrentControlSet\Services

REG ADD %KEY%\Messenger /V Start /t REG_DWORD /d 0x00000004 /f >NUL 
REG ADD %KEY%\W3SVC /V Start /t REG_DWORD /d 0x00000003 /f >NUL 
REG ADD %KEY%\MSFtpsvc /V Start /t REG_DWORD /d 0x00000003 /f >NUL 
REG ADD %KEY%\SMTPSVC /V Start /t REG_DWORD /d 0x00000003 /f >NUL 

SET KEY=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx

REG ADD %KEY%\1 /VE /D "Installing MS Updates" /f >NUL 
REG ADD %KEY%\1 /V 1 /D "\"%SYSTEMDRIVE%\TEMP\MS UPDATES\CQ832483.EXE"" /f >NUL 

:EOF
Exit

The second item in SVCPACK is installing IE6SP1. After that installs, I remove all of the keys it places in RunOnceEx and run them via Regsvr32. Here are the keys that the IE6SP1 install places in RunOnceEX:

Windows Registry Editor Version 5.00

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx]
"Flags"=dword:00000a38
"Title"="Windows Update"

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\101]
@="Browsing Services"
"002"="C:\\WINNT\\system32\\mlang.dll|DllRegisterServer"
"004"="C:\\WINNT\\system32\\browseui.dll|DllRegisterServer"
"005"="C:\\WINNT\\system32\\browseui.dll|DllInstall|I"
"007"="C:\\WINNT\\system32\\shdocvw.dll|DllRegisterServer"
"008"="C:\\WINNT\\system32\\shdocvw.dll|DllInstall|I"
"009"="C:\\WINNT\\system32\\urlmon.dll|DllRegisterServer"
"010"="C:\\WINNT\\system32\\browsewm.dll|DllRegisterServer"
"012"="C:\\WINNT\\system32\\mshtml.dll|DllRegisterServer"
"013"="C:\\WINNT\\system32\\msrating.dll|DllRegisterServer"
"017"="C:\\WINNT\\system32\\plugin.ocx|DllRegisterServer"
"018"="C:\\WINNT\\system32\\sendmail.dll|DllRegisterServer"
"020"="C:\\WINNT\\system32\\asctrls.ocx|DllRegisterServer"
"021"="C:\\WINNT\\system32\\inetcpl.cpl|DllInstall|I"
"022"="C:\\WINNT\\system32\\mshtml.dll|DllInstall|I"
"027"="C:\\WINNT\\system32\\mshtmled.dll|DllRegisterServer"
"033"="C:\\WINNT\\system32\\proctexe.ocx|DllRegisterServer"
"034"="C:\\WINNT\\system32\\mshta.exe /register"
"036"="C:\\WINNT\\system32\\dxtrans.dll|DllRegisterServer"
"037"="C:\\WINNT\\system32\\dxtmsft.dll|DllRegisterServer"
"035"="C:\\WINNT\\system32\\mstime.dll|DllRegisterServer"
"003"="C:\\WINNT\\system32\\comctl32.dll|DllInstall|I"
"029"="C:\\WINNT\\system32\\corpol.dll|DllRegisterServer"

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\102]
@="Internet Tools"
"002"="C:\\WINNT\\system32\\imgutil.dll|DllRegisterServer"
"003"="C:\\WINNT\\system32\\pngfilt.dll|DllRegisterServer"
"009"="C:\\WINNT\\system32\\msxml3.dll|DllRegisterServer"

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\103]
"019"="C:\\WINNT\\system32\\csseqchk.dll|DllRegisterServer"

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\104]
@="System Services"
"002"="C:\\WINNT\\system32\\actxprxy.dll|DllRegisterServer"
"004"="C:\\WINNT\\system32\\cdfview.dll|DllRegisterServer"
"007"="C:\\WINNT\\system32\\inseng.dll|DllRegisterServer"
"008"="C:\\WINNT\\system32\\iesetup.dll|DllInstall|i"
"013"="C:\\WINNT\\system32\\webcheck.dll|DllRegisterServer"
"014"="C:\\WINNT\\system32\\occache.dll|DllRegisterServer"
"015"="C:\\WINNT\\system32\\occache.dll|DllInstall|i"
"024"="C:\\WINNT\\system32\\iepeers.dll|DllRegisterServer"
"030"="C:\\Program Files\\Common Files\\Microsoft Shared\\MSInfo\\ieinfo5.ocx|DllRegisterServer"
"079"="C:\\WINNT\\system32\\msident.dll|DllRegisterServer"
"020"="C:\\WINNT\\system32\\cryptdlg.dll|DllRegisterServer"

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\500]
"002"="C:\\WINNT\\system32\\digest.dll|DllInstall|i,HKLM"
"003"="C:\\WINNT\\system32\\wininet.dll|DllInstall|i,HKLM"
"010"="C:\\WINNT\\system32\\urlmon.dll|DllInstall|i,HKLM"
"019"="C:\\WINNT\\system32\\msieftp.dll|DllRegisterServer"
"087"="C:\\WINNT\\system32\\tdc.ocx|DllRegisterServer"
"088"="C:\\Program Files\\Common Files\\Microsoft Shared\\VGX\\vgx.dll|DllRegisterServer"

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\800]
"000"="C:\\WINNT\\system32\\inetcomm.dll|DllRegisterServer"
"001"="C:\\Program Files\\Outlook Express\\msoe.dll|DllRegisterServer"
"002"="C:\\Program Files\\Outlook Express\\oeimport.dll|DllRegisterServer"
"003"="C:\\Program Files\\Outlook Express\\oemiglib.dll|DllRegisterServer"
"004"="C:\\Program Files\\Common Files\\System\\directdb.dll|DllRegisterServer"
"005"="C:\\WINNT\\system32\\msoeacct.dll|DllRegisterServer"
"006"="C:\\Program Files\\Common Files\\System\\wab32.dll|DllRegisterServer"
"007"="C:\\Program Files\\Outlook Express\\wabimp.dll|DllRegisterServer"
"008"="C:\\Program Files\\Outlook Express\\wabfind.dll|DllRegisterServer"

I delete those keys and run them via Regsvr32 here...

REG_IE6.CMD

@ECHO OFF

:: Delete the RunOnceEx keys added by the IE6SP1 install and issue those commands now

SET KEY=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx

REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx /v Title /f >NUL 
REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx /v Flags /f >NUL 

REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\101 /f >NUL 
REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\102 /f >NUL 
REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\103 /f >NUL 
REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\104 /f >NUL
REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\500 /f >NUL 
REG DELETE HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\800 /f >NUL 

::
:: ECHO The 101 section
::

REGSVR32.EXE /s %WINDIR%\system32\mlang.dll
REGSVR32.EXE /s %WINDIR%\system32\browseui.dll
REGSVR32.EXE /s /i %WINDIR%\system32\browseui.dll
REGSVR32.EXE /s %WINDIR%\system32\shdocvw.dll
REGSVR32.EXE /s /i %WINDIR%\system32\shdocvw.dll
REGSVR32.EXE /s %WINDIR%\system32\urlmon.dll
REGSVR32.EXE /s %WINDIR%\system32\browsewm.dll
REGSVR32.EXE /s %WINDIR%\system32\mshtml.dll
REGSVR32.EXE /s %WINDIR%\system32\msrating.dll
REGSVR32.EXE /s %WINDIR%\system32\plugin.ocx
REGSVR32.EXE /s %WINDIR%\system32\sendmail.dll
REGSVR32.EXE /s %WINDIR%\system32\asctrls.ocx
REGSVR32.EXE /s /i %WINDIR%\system32\inetcpl.cpl
REGSVR32.EXE /s /i %WINDIR%\system32\mshtml.dll
REGSVR32.EXE /s %WINDIR%\system32\mshtmled.dll
REGSVR32.EXE /s %WINDIR%\system32\proctexe.ocx
%WINDIR%\system32\mshta.exe /register
REGSVR32.EXE /s %WINDIR%\system32\dxtrans.dll
REGSVR32.EXE /s %WINDIR%\system32\dxtmsft.dll
REGSVR32.EXE /s %WINDIR%\system32\mstime.dll
REGSVR32.EXE /s /i %WINDIR%\system32\comctl32.dll
REGSVR32.EXE /s %WINDIR%\system32\corpol.dll

::
:: ECHO The 102 section
::

REGSVR32.EXE /s %WINDIR%\system32\imgutil.dll
REGSVR32.EXE /s %WINDIR%\system32\pngfilt.dll
REGSVR32.EXE /s %WINDIR%\system32\msxml3.dll

::
:: ECHO The 103 section
::

REGSVR32.EXE /s %WINDIR%\system32\csseqchk.dll

::
:: ECHO The 104 section
::

REGSVR32.EXE /s %WINDIR%\system32\actxprxy.dll
REGSVR32.EXE /s %WINDIR%\system32\cdfview.dll
REGSVR32.EXE /s %WINDIR%\system32\inseng.dll
REGSVR32.EXE /s /i %WINDIR%\system32\iesetup.dll
REGSVR32.EXE /s %WINDIR%\system32\webcheck.dll
REGSVR32.EXE /s %WINDIR%\system32\occache.dll
REGSVR32.EXE /s /i %WINDIR%\system32\occache.dll
REGSVR32.EXE /s %WINDIR%\system32\iepeers.dll
REGSVR32.EXE /s "%ProgramFiles%\Common Files\Microsoft Shared\MSInfo\ieinfo5.ocx"
REGSVR32.EXE /s %WINDIR%\system32\msident.dll
REGSVR32.EXE /s %WINDIR%\system32\cryptdlg.dll

::
:: ECHO The 500 section
::

REGSVR32.EXE /s /i:HKLM %WINDIR%\system32\digest.dll
REGSVR32.EXE /s /i:HKLM %WINDIR%\system32\wininet.dll
REGSVR32.EXE /s /i:HKLM %WINDIR%\system32\urlmon.dll
REGSVR32.EXE /s %WINDIR%\system32\msieftp.dll
REGSVR32.EXE /s %WINDIR%\system32\tdc.ocx
REGSVR32.EXE /s "%ProgramFiles%\Common Files\Microsoft Shared\VGX\vgx.dll"

::
:: ECHO The 800 section
::

REGSVR32.EXE /s %WINDIR%\system32\inetcomm.dll
REGSVR32.EXE /s "%ProgramFiles%\Outlook Express\msoe.dll"
REGSVR32.EXE /s "%ProgramFiles%\Outlook Express\oeimport.dll"
REGSVR32.EXE /s "%ProgramFiles%\Outlook Express\oemiglib.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\\directdb.dll"
REGSVR32.EXE /s %WINDIR%\system32\msoeacct.dll
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\\wab32.dll"
REGSVR32.EXE /s "%ProgramFiles%\Outlook Express\wabimp.dll"
REGSVR32.EXE /s "%ProgramFiles%\Outlook Express\wabfind.dll"

:EOF
Exit

The MDAC_TYP (MDAC 2.8 install) writes RunOnceEx keys as well... and in some of the same key locations as IE6SP1 so they would have gotten trampled. I remove the MDAC RunOnceEx keys and run via Regsvr32.

REG_MDAC.CMD

@ECHO OFF

:: Delete the RunOnceEx keys added by the MDAC_TYP.EXE install and issue those commands now
:: REG DELETE doesn't accept variables like %KEY% so you must be explicit

REG DELETE "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\800" /f >NUL 
REG DELETE "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\801" /f >NUL 
REG DELETE "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\802" /f >NUL 
REG DELETE "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\990" /f >NUL 

::
:: ECHO The 2nd 800 section (overlapping the IE6SP1 800 section) is added by the MDAC_TYP.EXE 2.8 install
::

REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\ADO\msado15.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\ADO\msador15.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\ADO\msadrh15.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\ADO\msadomd.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\ADO\msadox.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\ADO\msjro.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\MSADC\msadce.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\MSADC\msadcf.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\MSADC\msadco.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\MSADC\msadds.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\MSADC\msdaprst.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\MSADC\msdarem.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\MSADC\msdfmap.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\OLE DB\oledb32.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\OLE DB\msxactps.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\OLE DB\msdaenum.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\OLE DB\msdaurl.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\OLE DB\msdatt.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\OLE DB\msdasql.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\OLE DB\msdaosp.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\OLE DB\msdaora.dll"
REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\OLE DB\msdaps.dll"

::
:: ECHO The 801 section added by the MDAC_TYP.EXE 2.8 install
::

REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\OLE DB\sqlxmlx.dll"

::
:: ECHO The 802 section added by the MDAC_TYP.EXE 2.8 install
::

REGSVR32.EXE /s "%ProgramFiles%\Common Files\System\OLE DB\sqloledb.dll"

::
:: ECHO The 990 section added by the MDAC_TYP.EXE 2.8 install
::

rundll32.exe shell32.dll,Control_FillCache_RunDLL
%WINDIR%\system32\odbcconf.exe /S /Lv %WINDIR%\dasetup.log /F %WINDIR%\system32\mdaccore.rsp
%WINDIR%\system32\odbcconf.exe /S /Lv %WINDIR%\dasetup.log /F %WINDIR%\system32\redist.rsp
secedit /configure /db %WINDIR%\system32\..\inf\bidintrx.sdb /cfg %WINDIR%\system32\..\inf\bidintrx.inf /log %WINDIR%\system32\..\inf\bidintrx.log

:EOF
Exit

After the IE6SP1 Outlook Express update (KB330994), I remove the RunOnceEx keys added and run via Regsvr32.

REG_OEX.CMD

@ECHO OFF

:: Delete the RunOnceEx keys added by the IE6SP1 Outlook Express update and issue those commands now
:: REG DELETE doesn't accept variables like %KEY% so you must be explicit

REG DELETE "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx\OEWAB OS Setup" /f >NUL 

::
:: ECHO The OE WAB section added by the Outlook Express Update KB330994
::

REGSVR32.EXE /s %WINDIR%\system32\msoeacct.dll
REGSVR32.EXE /s "%ProgramFiles%\Outlook Express\wabfind.dll"

:EOF
Exit

For the rest of SVCPACK.INF, no other RunOnceEx keys are generated so it is free for your application installs or other items.

**Geezer** · March 16, 2004

@AirMaleDFW,

That looks great! It looks like you put some real time into it. Thanks.

I also used XPCREATE to do a 2k CD. Everything was fine when laid out per GMs website, except that if Q330994 was in SVC-HF2, a few of us were getting a lockup at the first logon, before the desktop appeared. See the thread Here.

I think you have probably solved that problem. It's a lot more complicated than I had time for; I just ran Q330994 in GuiRunOnce. If I get around to it, I will try a simplified version, and post my results in the 2kcreate thread (with credit to you).

-Geezer

**evilvoice** · March 16, 2004

I have one question about unattended w2k...I have found that w2k allows themes (yes, the same ones as xp, I did not know this, but if you type themes and load a .theme file it is the same) Is there a way in winnt.sif to automatically apply a theme? I have not tried anything, but also I did not know that there were themes in 2k.

**n00b** · March 16, 2004

The only thing you need to worry about is that you cannot install IE6SP1 and its hotfixes at one shot. You must install them separately.

**Shotgun** · March 17, 2004

@AirMaleDFW: Wow. You really outdid yourself!

I once read the registry entries, using a PAUSE from a .cmd file at RunOnceEntry 000000000000 then using the task manager to run regedit, but being the lazy person I am I did not thought of exporting them.

Those keys really help with my install, which among other things, does NOT install Outlook Express. At one point got to use the IEAK but then I compared the infs, ini's and cabs produced by it and the original Cab used by IE6SP1 install then made some changes to the install.ins in BRANDING.CAB to avoid the setup from installing OE and WAB in the original IE6SP1 install files. The OE dir still gets created, and after applying the OE update hotfix (it also alters some IE files) I delete the files and voila! No OE.

The trouble I'm having is that even as an administrator I can't remove the Outlook Express directory. I'll review the OE registry settings to see if I can untie it from the registry and be able to eliminate the OE directory completely.

**evilvoice** · March 17, 2004

@AirMaleDFW: I see that you call all this within svcpack.inf...but at looking at your post, you have REGIE6.EXE, REG_OEX.EXE, T13_START.EXE as .CMD files...is your svcpack.ing correct, or is your post correct. (Im talking about the headings above the quoted area...

REG_IE6.CMD

@ECHO OFF

:: Delete the RunOnceEx keys added by the IE6SP1 install and issue those commands now

SET KEY=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx

**AirMaleDFW** · March 17, 2004

@evilvoice: Some people use a "CMDOW" program to hide their cmd windows (perhaps you've seen reference to it elsewhere). I tried it out and the command window flashes on the screen before disappearing. I didn't like that. I repackage command files with IExpress into an *.exe. The IExpress repack totally hides the command window when the cmd file is extracted and executed. I learned this from GreenMachine and he has a mini tutorial / example of IExpress useage here... IExpress Useage

So, REGIE6.EXE is just my REG_IE6.CMD file repacked... and the same with the others noted.

**Bilou_Gateux** · March 17, 2004

@shotgun

Can you reply and make available your modifications to install.ins and branding.cab to disable OE install to others MSFN members.

I'm very interested to make this at installation.

The same way, i would like to disable NetMeeting installation.

The Folder for these applications are created somewhere by registry value in HKEY_LOCAL_MACHINE or HKEY_USER key.

When i change the default location of PFiles folder in the registry

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion]

"ProgramFilesDir"="C:\\Program Files"

to

"ProgramFilesDir"="D:\\Program Files"

and reboot, folders that don't exist are created in my new Path D:\Program Files

and are empty.

@AirMaleDFW

Great works, i will have a try tomorrow at works.

Sign In

Windows 2000 Unattend?

Recommended Posts

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members