Jump to content

WinPE 2.0 simple Ghost Menu HTA

keythom

By keythom
in Windows PE

 Share

Recommended Posts

keythom

keythom

Posted
Posted (edited)

Most of the WinPE help seems to tend toward advanced plug-ins to create a live cd desktop.

I like that too, but my main need at work is maintaining a simple and easy imaging platform for technicians.

If anyone is looking for something like that, here is my first stab at a solution.

Some features:

  • dynamically creates image options from directory structure = easy updating, no editing WinPE image
  • displays a separate details panel for each image for in-depth image info, version history, notes, etc
  • relies on a basic WinPE 2.0 image with only stock add-ins = easy to build and maintain

pegho.png

To begin, you'll need a working WinPE 2.0 with WMI, Scripting, XML, HTA packages installed.

Networking needs to be functional also.

There is a ton of help on this site and others for getting that far.

I really recommend the PXE or RIS/WDS bootable WIM setup.

Add a line in the startnet.cmd to create a mapped drive to your image location, example:

net use z: \\server\imageShare

In the image share location, create a new directory for the imaging HTA to use, example:

z:\winpe

This path is hardcoded into the HTA and you may need to change it for your situation, see notes in HTA itslef.

Referring to the screencap above and using the example mapped drive z:, here is a description of how things should work:

  • category buttons (Dell WS, HP WS,...) are generated from subdirectory names in z:\winpe
  • shortcut links in category subdirs point to image targets
  • radio button entries are created from shortcut links in each category subdir
  • radio button names are created from description field of shortcut
  • details for each image are linked from an .htm file with the same name as the .gho target

When creating shortcut links, be sure to use the mapped drive path instead of a unc path.

The quick and easy way I have made the details files is saving from Excel as .htm. Name it the same as a .gho and it should display, sometimes takes a little experimenting to make it look right. An obvious upgrade would be to use a nice spreadsheet control or something, but I took the simple way.

We'll be using ImageX for more images pretty soon and this interface should be easy to adapt for that also because the buttons are only command lines actually.

Hope this can help some people. I'm no web designer or code engineer, so there is a lot to be improved but it is meeting our needs currently.

Thank you,

Fisher

if you like the backgound in there, here it is:

http://i171.photobucket.com/albums/u290/keythom/pe.jpg

Here is the HTA code:

<html>
<!--
'********************************************************************
'*
'*  File:          wizard.hta
'*  Author:        greg & fisher
'*  Created:       Mar 2007
'*  Modified:
'*  Version:       .9
'*
'*  Description:   windows imaging platform
'*
'*  Dependencies:  tested on and for WinPE 2.0 with WMI, Scripting,
'*                 XML, HTA packages
'*  Notes:         Line 26      - might want to make this "normal" when you are
'*                                testing and don't want the hta fullscreen
'*                 Line 58      - customize your headings here
'*                 Line 72, 101 - confirm directory.name path, this would be a mapped
'*                                drive to the filer where the images shorcut dir is
'*                 Line 193     - confirm background image source location
'*                 Line 200     - confirm path to ghost executable
'*
'********************************************************************
-->

<!****************************************************************************>
<!* HTA Header                                                                >
<!****************************************************************************>
<HEAD>
<TITLE>Imaging Application</TITLE>
<HTA:APPLICATION
        BORDER           = None
        APPLICATION      = Yes
	WINDOWSTATE      = normal
	INNERBORDER      = No
	SHOWINTASKBAR    = Yes
	SCROLL           = No
	APPLICATIONNAME  = "Windows PE Wizard"
        NAVIGABLE        = Yes
>
<!-- external stylesheet -->
<link rel="stylesheet" type="text/css" href="htaStyle.css" />
</HEAD>

<!****************************************************************************>
<!* Begin Script                                                              >
<!****************************************************************************>
<script Language=VBScript>

'****************************************************************************
'* Globals
'* setup global script parameters
'****************************************************************************
Option Explicit
Dim strTaskValue, objShell, objFso, strBody, objWmiService
Set objShell         = CreateObject("WScript.Shell")
Set objFso           = CreateObject("Scripting.FileSystemObject")
Set objWMIService    = GetObject   ("winmgmts:\\.\root\cimv2")

'****************************************************************************
'* Window_OnLoad
'* load up behavior and preferences
'****************************************************************************
Sub Window_Onload
  self.Focus()
  strBody = "<H1>PE Build and Recovery Environment</H1>" &_
  "<H2>Select Images to apply an OS image using Ghost.<BR><BR>" &_
  "Please select an image category:<BR><BR>"
  enumDirs
End Sub

'****************************************************************************
'* enumDirs
'* find directories and create category buttons
'****************************************************************************
Sub enumDirs
Dim colSubfolders, objFolder, fileName
'enumerate folders in images folder
  Set colSubfolders = objWMIService.ExecQuery _
    ("Associators of {Win32_Directory.Name='z:\winpe'} Where AssocClass = Win32_Subdirectory ResultRole = PartComponent")
'create html buttons from each folder name
  For Each objFolder in colSubfolders
    fileName = objFolder.fileName
    strBody = strBody &_
    "<button id='" & fileName & "' onClick='enumImages("" & fileName & "")'>" & fileName & "</BUTTON>"
  Next
'post resulting html body to document
  strBody        = strBody & "<BR><HR><BR>"
  body.innerHTML = strBody
End Sub

'****************************************************************************
'* enumImages
'* find images and create radio buttons
'****************************************************************************
'this sub is a little messy because of limitations of win32_shortcutfile and need to go between fso and wmi for different info
'also, without the advantages of .net sorting classes, the old bubble sorting is not the funnest

Sub enumImages(fileName)
Dim colFilelist, objFile, strButtons, objShortcut, colTargetList, objTarget, x, y, strKey, strItem
ReDim arrButtons(1,-1)

'reset display element style
  details.innerHTML        = ""
  details.style.visibility = "hidden"
'  strButtons               = "<table id=buttonTable>"
'enumerate ghost image shortcuts in specific images subfolder from enumDirs
  Set colFileList = objWMIService.ExecQuery _
    ("ASSOCIATORS OF {Win32_Directory.Name='z:\winpe\" & fileName & "'} Where ResultClass = CIM_DataFile")
'find ghost image shortcut targetpath (fso)
  For each objFile in colFileList
    If objFile.Extension = "lnk" Then
    	Set objShortcut = objShell.CreateShortcut(objFile.name)
'find ghost image shortcut target (wmi)
      Set colTargetList = objWMIService.ExecQuery _
        ("Select * from CIM_Datafile Where name = '" & replace(objShortcut.targetpath,"\","\\") & "'")
'add radio button label (from fso) and radio button target (from wmi) to an array
        For each objTarget in colTargetList
          ReDim Preserve arrButtons(1,UBound(arrButtons,2)+1)
          arrButtons(0,UBound(arrButtons,2)) = objShortcut.Description
          arrButtons(1,UBound(arrButtons,2)) = "<Input type=radio name=radioList id='" & objTarget.Drive & objTarget.Path & 

objTarget.fileName &_
          "' onClick=showRadioInfo>" & objShortcut.Description & "</BUTTON><BR>"
        Next
    End If
  Next
'perform a a shell sort of the string array based on button label
      For x = 0 To UBound(arrButtons,2) - 1
        For y = x To UBound(arrButtons,2)
          If StrComp(arrButtons(0,x),arrButtons(0,y),vbTextCompare) > 0 Then
              strKey           = arrButtons(0,x)
              strItem          = arrButtons(1,x)
              arrButtons(0,x)  = arrButtons(0,y)
              arrButtons(1,x)  = arrButtons(1,y)
              arrButtons(0,y)  = strKey
              arrButtons(1,y)  = strItem
          End If
        Next
      Next
'create combined buttons html code from sorted buttons array
  For x = 0 To UBound(arrButtons,2)
    strButtons = strButtons & "<tr><td id=buttonTd>" & arrButtons(1,x) & "</td></tr>"
  Next
 ' strButtons = strButtons & "</table>"
'create a start button with start image command and append and post resulting html to body
  body.innerHTML = strBody & strButtons & "<BR><HR><BR><button id=start Accesskey=S onclick=doTask(strTaskValue)><U>S</U>tart 

Image!</BUTTON><BR>"
  start.style.visibility="hidden"
End Sub

'****************************************************************************
'* doTask
'* run task selected by radio button
'****************************************************************************
Sub doTask(doMe)
  objShell.Run doMe
End Sub

'****************************************************************************
'* showRadioInfo
'* display details of radio button selection in details divider
'****************************************************************************
Sub showRadioInfo
Dim objTextFile, Radio, strRadioValue, strDetails
'set details and start element styles
  details.style.visibility    = "visible"
  start.style.visibility      = "visible"
'find checked button
  For Each Radio in Document.getElementsByName("radioList")
    If Radio.Checked = True Then
'create imaging command line from button id
      strTaskValue =  Chr(34) & "%programfiles%\ghost8\ghost32.exe" & Chr(34) & " -clone,mode=restore,src=" & Chr(34) & 

Radio.Id & ".gho" & Chr(34) & ",dst=1"
'display image details in details element if they exist
      If objFso.FileExists(Radio.Id & ".htm") Then
        Set objTextFile = objFso.OpenTextFile(Radio.Id & ".htm", 1)
        strDetails = objTextFile.ReadAll()
      Else
'display error message in details element if no matching details file found
        strDetails = "Can't find anything!!!<BR><BR>" &_
        "Make sure the info file has the same name as the .gho and has an .htm extension."
      End If
    End If
  Next
'post resulting html to details element
  Details.innerHTML = strDetails
End Sub

'****************************************************************************
'* Reset
'* reset the tool interface, also reloads the code (helpful for programming)
'****************************************************************************
Sub Reset
  Location.Reload(True)
End Sub

</Script>
<!****************************************************************************>
<!* End Script / Begin HTML                                                   >
<!****************************************************************************>

<BODY>
<DIV id=bg>
<img src=winpe.bmp>
</DIV>

<DIV id=body></DIV>
<DIV id=details></DIV>

<DIV id=tools>
<Button id=ghost   onclick=doTask('"%programfiles%\ghost8\ghost32.exe"')>Ghost</BUTTON>     
<Button id=cmd     onclick=doTask('%comspec%')>            Cmd         </BUTTON>     
<Button id=notepad onclick=doTask('notepad')>              Notepad     </BUTTON>     
<Button id=taskmgr onclick=doTask('taskmgr')>              Taskmgr     </BUTTON>     
<Button id=close   onclick=self.close()>                   Quit        </BUTTON>     
<Button id=reset   onclick=reset>                          ResetApp    </BUTTON>     
<Button id=reboot  onclick=self.navigate('reboot.hta')>    Reboot      </BUTTON>
</DIV>
</BODY>
</HTML>

<!****************************************************************************>
<!* End HTML                                                                  >
<!****************************************************************************>

wizard.hta.txt

htaStyle.css

reboot.hta.txt

Edited by keythom
Link to comment
Share on other sites

p4ntb0y

p4ntb0y

Posted
Posted

Nice this should help some people out.

What about adding an option for images to be on a USB Drive weather they ghost or wim. This will cope with situations where you have no network conectivity an engineer could boot an UFD and load the image by USB disc

can't beleive 18 views and not one thanks!

Link to comment
Share on other sites
Stratuscaster

Stratuscaster

Posted
Posted

This is a good start, as I've been looking for something similar.

I'm unclear on where the files you provided would actually go, however. And the "z:\winpe" structure is a little hazy to me as well. Perhaps a screenshot of the explorer tree would help?

I think it's:

z:\winpe

z:\winpe\dell

z:\winpe\dell\image1.lnk

z:\winpe\dell\image1.htm

z:\winpe\dell\image2.lnk

z:\winpe\dell\image2.htm

Is that correct? And the images themselves can be elsewhere as defined by the shortcuts, yes?

Link to comment
Share on other sites
keythom

keythom

Posted
  • Author
Posted

Here's an embarrassing attempt at a graphic explanation if it helps any.

I'm sorry for any harm to your eyes.

Please let me know if you try this and if you have any trouble, I'll try to help.

For the imaging to launch, you'll need to put the ghost files into \program files\ghost8\ or set the location in the HTA. There is a comment at the top with the line number for that.

I'll update when I have some imageX incorporated.

For testing I map the drive to the ghost images location as it is set in our PE image and launch the HTA on my normal workstation. I did work for a long time using some .NET classes and was very disappointed when I ran it on WinPE though.

have a great weekend!

Fisher

pebuilding.png

Link to comment
Share on other sites
keythom

keythom

Posted
  • Author
Posted

In WinPE 2.0, I get the Access Denied error when starting an HTA from a non-system drive like a mapped drive or removable media device.

Try launching the HTA from a location on the system drive, should be X:.

Link to comment
Share on other sites
  • 2 weeks later...
tombtek99

tombtek99

Posted
Posted

Great Stuff!! I am working on something similar. A couple things I added which might be helpful to some folks.

We have about 8 locations and customizing the paths for each of them was a pain. So I called an IPCONFIG > x:\ipconfig.txt in startnet.cmd. I used a read in the txt file to map the drive based on the dns suffix (or you could use ipaddress ranges, etc). That made sure the mapping to Z:\ was consistent.

In the fat vs thin image arguement, we chose to go with 2 very, very thin xp images (Apic & Pic) with extensive post image scripting for machine specific customizations (laptop/desktop/workstation, Lenovo/HP, SP/MP, Raid/NonRaid, IDE/Sata, etc). I used the machine type wmi script from the bdd (2.0) to idenify the machine type as a text file. I put a hook on the end of my imagex.bat to call copy.vbs which copies all of the machine specific software and drivers based on x:\machinetype.txt[to the local PC before it reboots and starts sysprep. I have a call in my sysprep that launches the drivers and software installs.

We use a modified wizard.hta from December's technet in our WinPE and the net result is a KISS boot disc that is location and machine independent. The tech just clicks a button to image the machine either up, down, or up and down, and walks away until the XP mini-setup. Three screens there and then give it 5-15 mins (desktop vs laptop) and the unit is ready for data migration. We can't use accounts in sysprep (to automate the mini setup) and I don't think our users (read engineers) will be ready for automated data migration any time soon, so that is a far as we can go with automating our process.

Hope this helps.

Link to comment
Share on other sites
Stratuscaster

Stratuscaster

Posted
Posted
In WinPE 2.0, I get the Access Denied error when starting an HTA from a non-system drive like a mapped drive or removable media device.

Try launching the HTA from a location on the system drive, should be X:.

No dice - still get "Access is denied" when launching from x:\ghosthta - perhaps if I knew where you placed the HTA files?

Link to comment
Share on other sites
Jazkal

Jazkal

Posted
Posted (edited)

I launch all my HTA's via network share (mapped drives), that way I can update them without having to rebuild my WinPE Images.

In WinPE2 I use the following to call my HTA files:

cmd.exe /c Mshta.exe z:\PATH\FILENAME.hta

Edited by Jazkal
Link to comment
Share on other sites
zorphnog

zorphnog

Posted
Posted

I've found that for some reason you always have to specify the full path of the file for mshta to execute properly. So even if you are in the folder where the .hta file is located, you still have to type the full path.

X:\Windows\System32>mshta.exe X:\Windows\System32\wizard.hta

Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share
Go to topic listing

  • Recently Browsing   0 members

    • No registered users viewing this page.
×
×
  • Create New...