VBS help

[Batch User]

How do i use Set oWsh = CreateObject("WScript.Shell") to run a .exe, because I know for some reason the path is different... or something.

oWsh.Run "C:\path" Doesnt work..

Thanks.

[gunsmokingman]

Run Something And Wait For It To Finish

Dim Act : Set Act = CreateObject("Wscript.Shell")
  Act.Run("Notepad.exe"),1,True

Run Something And Not Wait For It To Finish

Dim Act : Set Act = CreateObject("Wscript.Shell")
  Act.Run("Notepad.exe"),1,False

Run Somthing With A Space In It Path

Dim Act  : Set Act = CreateObject("Wscript.Shell")
 Dim File : File  = Act.ExpandEnvironmentStrings("%ProgramFiles%\Winamp\winamp.exe")
  Act.Run(Chr(34) & File & Chr(34)),1,True

Check For File Then Run It And Wait For it To Complete

Dim Act  : Set Act = CreateObject("Wscript.Shell")
 Dim Fso  : Set Fso = CreateObject("Scripting.FileSystemObject")
 Dim File : File  = Act.ExpandEnvironmentStrings("%ProgramFiles%\Winamp\winamp.exe")
  If Fso.FileExists(File) Then 
   Act.Run(Chr(34) & File & Chr(34)),1,True
  Else 
   Act.Popup "Can Not Find Winamp",5,"Missing", 4128
  End If

Check For File Then Run It And Not Wait For it To Complete

Dim Act  : Set Act = CreateObject("Wscript.Shell")
 Dim Fso  : Set Fso = CreateObject("Scripting.FileSystemObject")
 Dim File : File  = Act.ExpandEnvironmentStrings("%ProgramFiles%\Winamp\winamp.exe")
  If Fso.FileExists(File) Then 
   Act.Run(Chr(34) & File & Chr(34)),1,False
  Else 
   Act.Popup "Can Not Find Winamp",5,"Missing", 4128
  End If

Edited December 31, 2006 by gunsmokingman

[Fredledingue]

It works, but it doesn't accept "white spaces" in the path (thought it accept long names if no white space!).

So use:

Set Fso = CreateObject("Scripting.FileSystemObject")

Set f = Fso.GetFile(MyPath)

oWsh.Run f.ShortPath

That way you are sure there will be no white space in the path

You can lauch files or exe alike.