Smaller steps in volume control

[loft]

After my 6 yo keyboard died in the line of duty I've got a new one with multimedia buttons. After a few hours I've noticed (Girder displays an OSD on volume changes) that the volume is changed (by the appropriate multimedia buttons) in steps of 4 percent each which, in some situations. is too much. I think steps of 2% each would be better.

But how to change that? I think is a setting of HID service or something. But I couldn't find it anywhere.

And another thing is that those steps are between fixed values. It doesn't metter that I've set the volume (from the mixer panel) at 37%, if I'm increasing it from the keyboart the next value will be 40 and so on, in steps of 4%.

Any idea how to change that step value? I don't want to give up on HID and start configuring Girder do work with the multimedia buttuns.

Thank you!

[LLXX]

Click the volume control icon in the system tray, click the slider, then use the up and down arrows.

[loft]

LLXX thanks for your answer but I was talking about the multimedia buttons.

I know how to set the volume from the Mixer but it's easyer form the multimedia buttons.

[DL.]

Just make sure you have the HID service on auto and that it's actually starting, and then it should work just fine (disable and/or remove Girder).

I use the multimedia keys on my Logitech Elite SE keyboard without any additional drivers or progs installed, just the HID service and Windows own drivers.

There was a bug in an earlier version of nLite (I don't know if it's fixed in the later ones) which caused the removal of an essential component (hidserv.dll) when removing Terminal Services, preventing the HID service from starting.

[[deXter]]

I use this AutoHotkey script to manage volume control on my HID Multimedia keyboard. Download AutoHotkey (1.7 MB) and install it. Copy-paste the following into notepad and save as volume.ahk

You can now double-click or run .ahk files directly. When you do that you'll see an icon in your system tray to indicate that your script is running.

; Volume On-Screen-Display (OSD) -- by Rajat 
; http://www.autohotkey.com 
; This script assigns hotkeys of your choice to raise and lower the 
; master and/or wave volume.  Both volumes are displayed as different 
; color bar graphs.

;_______User Settings_____________________________ 

; Make customisation only in this area or hotkey area only!! 

; The percentage by which to raise or lower the volume each time:
vol_Step = 4

; How long to display the volume level bar graphs:
vol_DisplayTime = 2000

; Master Volume Bar color (see the help file to use more
; precise shades):
vol_CBM = Red

; Wave Volume Bar color
vol_CBW = Blue

; Background color
vol_CW = Silver

; Bar's screen position.  Use -1 to center the bar in that dimension:
vol_PosX = -1
vol_PosY = -1
vol_Width = 150
vol_Thick = 12

; Configure the hotkeys used to control Master and Wave volumes
; Default keys for master are the Volume multimedia keys
; Default keys for wave are Ctrl + Volume multimeda keys
HotKey, Volume_Up, vol_MasterUp
HotKey, Volume_Down, vol_MasterDown
HotKey, ^Volume_Up, vol_WaveUp	;Ctrl+Volume Up
HotKey, ^Volume_Down, vol_WaveDown	;Ctrl+Volume Down


;_____Auto Execute Section__________________ 

; DON'T CHANGE ANYTHING HERE (unless you know what you're doing).

vol_BarOptionsMaster = 1:B ZH%vol_Thick% ZX0 ZY0 W%vol_Width% CB%vol_CBM% CW%vol_CW%
vol_BarOptionsWave   = 2:B ZH%vol_Thick% ZX0 ZY0 W%vol_Width% CB%vol_CBW% CW%vol_CW%

; If the X position has been specified, add it to the options.
; Otherwise, omit it to center the bar horizontally:
if vol_PosX >= 0
{
	vol_BarOptionsMaster = %vol_BarOptionsMaster% X%vol_PosX%
	vol_BarOptionsWave   = %vol_BarOptionsWave% X%vol_PosX%
}

; If the Y position has been specified, add it to the options.
; Otherwise, omit it to have it calculated later:
if vol_PosY >= 0
{
	vol_BarOptionsMaster = %vol_BarOptionsMaster% Y%vol_PosY%
	vol_PosY_wave = %vol_PosY%
	vol_PosY_wave += %vol_Thick%
	vol_BarOptionsWave = %vol_BarOptionsWave% Y%vol_PosY_wave%
}

#NoEnv
#SingleInstance 
SetBatchLines, 10ms 
Return 

;___________________________________________

vol_WaveUp:
SoundSet, +%vol_Step%, Wave
Gosub, vol_ShowBars
return

vol_WaveDown:
SoundSet, -%vol_Step%, Wave
Gosub, vol_ShowBars
return

vol_MasterUp:
SoundSet, +%vol_Step%
Gosub, vol_ShowBars
return

vol_MasterDown:
SoundSet, -%vol_Step%
Gosub, vol_ShowBars
return

vol_ShowBars:
; To prevent the "flashing" effect, only create the bar window if it
; doesn't already exist:
IfWinNotExist, vol_Wave
	Progress, %vol_BarOptionsWave%, , , vol_Wave
IfWinNotExist, vol_Master
{
; Calculate position here in case screen resolution changes while
; the script is running:
	if vol_PosY < 0
	{
; Create the Wave bar just above the Master bar:
		WinGetPos, , vol_Wave_Posy, , , vol_Wave
		vol_Wave_Posy -= %vol_Thick%
		Progress, %vol_BarOptionsMaster% Y%vol_Wave_Posy%, , , vol_Master
	}
	else
		Progress, %vol_BarOptionsMaster%, , , vol_Master
}
; Get both volumes in case the user or an external program changed them:
SoundGet, vol_Master, Master
SoundGet, vol_Wave, Wave
Progress, 1:%vol_Master%
Progress, 2:%vol_Wave%
SetTimer, vol_BarOff, %vol_DisplayTime%
return

vol_BarOff:
SetTimer, vol_BarOff, off
Progress, 1:Off
Progress, 2:Off

It's a pretty awesome script. I mean not only can you customize the step level, but by allowing you to change the master as well as the wave volume (Ctrl+Volume), you can exactly finetune your volume.

Edited January 8, 2007 by [deXter]

[DL.]

@[deXter]: That script is probably very useful, but most likely a bit more than the topic starter needs (basic volume control using the keyboard?). How often do you actually have to fine tune both the master and the wave volume, every other minute? At the rare moment when you really have to do both at the same time you could probably just change them using the mixer, instead of having to keep yet another program running in the background. Using just the built-in HID service will spare some configuring and extra files to manage, but that's your own choice to make.

[[deXter]]

On the contrary, I think it might just be the thing that the topic starter might need. I seriously doubt if its possible to change the volume step level through registry settings without using a thirdparty program/driver.

And I do often have to use the fine tuning control, as my speakers don't have volume controls and my soundcard has a builtin amp so by default I have a high volume output, so I keep my master volume at the lowest level possible. But sometimes while playing music, even this level is high so I resort to use the finetuning. And its not like finetuning needs any significant resources

Anyways, lets stop speculating what the thread starter needs and allow him/her to decide on their own, shall we?