Pro / Cons has anyone tried this?

[bob3128]

I am currently toying with the idea of using a bootable DVD which contains Win XP and all my current applications. My will %OEM%\$1\install directory contains a batch file that will search for the DVD drive and then run the installers from the DVD drive.

This process is in the early stages of testing can anyone see any disadvantages to this?

(I am assuming this would be a quicker install than copying all the applications from the %OEM%\$1\install directory to the Hard disk before installing the app? .)

(Example of the batch file)

@echo off

title Application Install Batch

:Menu1

cls

ECHO Do you want to script / batch install basic apps

echo (Acrobat / Winzip / Office etc)

Echo.

set /p userinp=choose a letter (y or n):

set userinp=%userinp:~0,1%

if "%userinp%"=="Y" goto APP

if "%userinp%"=="y" goto APP

if "%userinp%"=="n" goto END

if "%userinp%"=="N" goto END

CLS

echo.

echo invalid choice please select "y" or "n"

pause

goto Menu1

:APP

if exist d:\#Adobe#\AdbeRdr60_enu_full.goto DAPP

if exist e:\#Adobe#\AdbeRdr60_enu_fullgoto EAPP

if exist f:\#Adobe#\AdbeRdr60_enu_fullgoto FAPP

if exist g:\#Adobe#\AdbeRdr60_enu_fullgoto GAPP

Goto END

:DAPP

echo Now installing Acrobat Reader

start /wait d:\#Adobe#\AdbeRdr60_enu_full.exe -p"-s /v\"/qn\""

Echo Now installing another app

Start /wait d:\

goto END

:EAPP

echo Now installing Acrobat Reader

start /wait e:\#Adobe#\AdbeRdr60_enu_full.exe -p"-s /v\"/qn\""

Echo Now installing another app

Start /wait e:\

goto END

:FAPP

echo Now installing Acrobat Reader

start /wait f:\#Adobe#\AdbeRdr60_enu_full.exe -p"-s /v\"/qn\""

Echo Now installing another app

Start /wait f:\

goto END

:GAPP

echo Now installing Acrobat Reader

start /wait g:\#Adobe#\AdbeRdr60_enu_full.exe -p"-s /v\"/qn\""

Echo Now installing another app

Start /wait g:\

goto END

:END

[Tsunami]

It would be better/shorter if you did something like this:

@ECHO OFF
TITLE Application Install Batch


:Menu1
ECHO Do you want to script / batch install basic apps
ECHO (Acrobat / Winzip / Office etc)
ECHO.

SET /P USERINP=Choose a letter (Y or N): 
SET USERINP=%USERINP:~0,1%

IF /I "%USERINP%" == "Y" GOTO App
IF /I "%USERINP%" == "N" GOTO End

CLS
ECHO.
ECHO Invalid choice, please select "Y" or "N"

PAUSE
GOTO Menu1


:App
FOR %%D IN (D E F G) DO IF EXIST %%D:\#Adobe#\AdbeRdr60_enu_full.exe SET D=%%D
IF NOT EXIST %D%:\#Adobe#\AdbeRdr60_enu_full.exe GOTO End

ECHO Now installing Acrobat Reader
START /WAIT %D%:\#Adobe#\AdbeRdr60_enu_full.exe -p"-s /v\"/qn\""

ECHO Now installing another app
START /WAIT %D%:\


:End

But, if you don't want to change it, it still looks fine to me

[SC00BS]

This process is in the early stages of testing can anyone see any disadvantages to this?

Can't see any disadvantages. I currentl use a multi-os dvd with all my apps installing from CD.

I then use wpi to allow for additional apps to be installed after build if necessary.

i have the wpi.hta to autorun. CD serves as dual purpose that way.

[hasi001]

sc00bs is right - try WPI.

[CoffeeFiend]

I do something a bit similar, using a choice.com clone. During the install, it'll ask for some optionnal components (mostly big/unusual apps) and will default to yes after 10 seconds or such. Eventually, I might come up with some way of using "answer files" on a floppy or usb memory stick or such to select them (and change other settings) before starting the install. WPI may be good for some, but it's not what I'm looking for...

[gunsmokingman]

Try This It produces a Inputbox that will go to the spot in the batch file

Adjust it to your needs

echo off
mode con: cols=55 lines=2
title My App To Install
color f8



:TheLoop
 > Exmple.vbs echo strUserIn = InputBox("Do you want to script / batch install basic apps"^& vbnewline ^&_
>> Exmple.vbs echo "Type A To Install Acrobat " ^& vbnewline ^& "Type B To Install Winzip" ^& vbnewline ^&_
>> Exmple.vbs echo "Type C To Install Office" ^& vbnewline ^& "Type Quit To Exit") 
>> Exmple.vbs echo Set fs = CreateObject("Scripting.FileSystemObject") 
>> Exmple.vbs echo strFileName = fs.BuildPath(Wscript.ScriptFullName ^& "\..", "Exmple.cmd") 
>> Exmple.vbs echo strFileName = fs.GetAbsolutePathName(strFileName) 
>> Exmple.vbs echo Set ts = fs.OpenTextFile(strFileName, 2, True)
>> Exmple.vbs echo ts.WriteLine "set Exmple=" ^& strUserIn 
>> Exmple.vbs echo ts.Close

start /w Wscript.exe Exmple.vbs
del Exmple.vbs
call Exmple.cmd 
ping -n 1 127.0.0.1>nul 
del Exmple.cmd
goto %Exmple%

:A
cls
color 2b
Title Here Box 1
echo Fill This In
ping -n 3 127.0.0.1>nul
goto TheLoop

:B
color 4f
cls
color 2b
Title Here Box 2
echo Fill This In
ping -n 3 127.0.0.1>nul
goto TheLoop

:C
color 9e
cls
color 2b
Title Here Box 3
echo Fill This In
ping -n 3 127.0.0.1>nul
goto TheLoop


:Quit
echo Completed
ping -n 3 127.0.0.1>nul

exit

I have added a yes or no MSGBox To The Above script