Help can get these command to work in [GuiRunOnce]

[illusions]

Hi,

I cannot get the following batch command lines to work in GuiRunOnce.

1. delete useless favorites shortcut and folder

2. Moving Userprofile Shortcut ...

3. registering and unregistering dll in c:\windows\system32

Please refer to the following and thanks.

winnt.sif

[GuiRunOnce]

%systemdrive%\install\batch.cmd

batch.cmd

rem .... delete useless favorites shortcut and folder

ATTRIB -R "%userprofile%\Favorites" /S /D

DEL /S /Q "%userprofile%\Favorites\*.url"

DEL /S /Q "%userprofile%\Favorites\Links\*.url"

ATTRIB +R "%userprofile%\Favorites" /S /D

ECHO.

ECHO Moving Userprofile Shortcut ...

attrib -r "%userprofile%\Start Menu\Programs"

attrib -r "%userprofile%\Start Menu\Programs\Accessories"

attrib -r -h "%userprofile%\Application Data"

attrib -s "%userprofile%\Application Data\Microsoft"

attrib -r "%userprofile%\Application Data\Microsoft\Internet Explorer\Quick Launch"

move "%userprofile%\Start Menu\Programs\Internet Explorer.lnk" "%userprofile%\Start Menu\Programs\Accessories\Internet Explorer.lnk"

move "%userprofile%\Start Menu\Programs\Outlook Express.lnk" "%userprofile%\Start Menu\Programs\Accessories\Outlook Express.lnk"

move "%userprofile%\Start Menu\Programs\Remote Assistance.lnk" "%systemdrive%\Documents and Settings\All Users\Start Menu\Programs\Accessories\Remote Assistance.lnk"

move "%userprofile%\Start Menu\Programs\Windows Media Player.lnk" "%userprofile%\Start Menu\Programs\Accessories\Windows Media Player.lnk"

copy "%userprofile%\Start Menu\Programs\Accessories\Windows Media Player.lnk" "%userprofile%\Application Data\Microsoft\Internet Explorer\Quick Launch\Windows Media Player.lnk"

attrib +r "%userprofile%\Start Menu\Programs"

attrib +r "%userprofile%\Start Menu\Programs\Accessories"

attrib +r +h "%userprofile%\Application Data"

attrib +s "%userprofile%\Application Data\Microsoft"

attrib +r "%userprofile%\Application Data\Microsoft\Internet Explorer\Quick Launch"

rem .... registering and unregistering dll in c:\windows\system32

regsvr32/s wmpshell.dll

regsvr32 /s oleacc.dll

regsvr32 /s actxprxy.dll

regsvr32 /u /s zipfldr.dll

[g-force]

Is your "batch.cmd" not working or isn`t it executed?

[illusions]

I have a long list of batch command and those lines i posted are not executed during

unattended installation.

When the computer first boot it did not do the following ...

1. delete useless favorites shortcut and folder of the current user

2. Moving Userprofile Shortcut ...

3. registering and unregistering the following dll in c:\windows\system32

regsvr32/s wmpshell.dll

regsvr32 /s oleacc.dll

regsvr32 /s actxprxy.dll

regsvr32 /u /s zipfldr.dll

Edited October 8, 2009 by illusions

[g-force]

Is the batch working if you execute it on a running system (logged on)?

[Guest]

Are we sure %userprofile% is there when GuiRunOnce runs? It's one of the last things created. If it's not there you can do a HKCU runonce to call the batch file later on in the process.

[illusions]

Hi g-force,

Yes those listed batch line will work after computer reboot again and when i manually execute them.

Hi -X- ,

I guess %userprofile% is not setup yet that is why those lines are not executed.

Please advice how to do a HKCU runonce to call the batch file later after reboot.

Thanks

[Guest]

Try this...

[GuiRunOnce]

REG ADD HKCU\Software\Microsoft\Windows\CurrentVersion\Runonce /v finalcommands /d %SystemDrive%\install\batch.cmd

[Yzöwl]

Also see if this batch file serves you any better.

@ECHO OFF
SETLOCAL
SET "SMP=Start Menu\Programs"
SET "WMP=Windows Media Player"
SET "IE=Internet Explorer"
PUSHD %UserProfile%\%SMP%
DEL /F /S /Q /A "%UserProfile%\Favorites\*.url"
FOR %%a IN ("%IE%" "Outlook Express" "%WMP%") DO (
	IF EXIST "%%~a.lnk" MOVE "%%~a.lnk" Accessories)
MOVE "Remote Assistance.lnk" "%AllUsersProfile%\%SMP%\Accessories"
COPY "Accessories\%WMP%.lnk" "%AppData%\Microsoft\%IE%\Quick Launch"
PUSHD %SystemRoot%\system32
FOR %%a IN (wmpshell oleacc actxprxy) DO REGSVR32 /S %%a.dll
REGSVR32 /U /S zipfldr.dll

[Noise]

If you want to keep the default Internet Explorer shortcuts from being created, a better way is to add the following to your WINNT.SIF file:

[Branding]
	BrandIEUsingUnattended=Yes

[URL]
	Home_Page=http://www.google.com/
	AutoConfig=0

[illusions]

Thank you all for your suggestion.

As suggested using Runonce method works!

I followed the example script in this thread .

http://www.msfn.org/board/runonce-all-user...pid-431303.html

Also special thanks to Yzöwl for writing a more concise batch command for me.

Edited October 8, 2009 by illusions