Display the producy key

[phiban]

Does anyone know a command which i can use to view a machines product key?

A little background info:

Im developing a application for my companies Network, which will retrieve a machines Product Key, also i need to know if its possible to change it?

is there a registry location for the product keys? and if so can i simply change it and then have the user re-activate?

Ta

[prx984]

well, windows 95/98/me had it in the registry, but for those of us on 2000/xp its elsewhere.

heres a utility to view the key on 2000/XP (it works on other os's too)

http://www.magicaljellybean.com/keyfinder.shtml

unfortuneatly, i wouldn't know the first place to start when making a program, but i hope that program is of help

[phiban]

cheers for the linky!

Anyone else know where it is?

[Littlebr00k]

The product key is still in the registry but it i encoded different ways in different places.

If you are programming in delphi Go Here

If you are programming in C# Go Here

Hope this helps

[phiban]

cheers great info!

[Hamins]

Try this registry key ..

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion

[phiban]

Cheers Hamins, so how do i actually read it?

The product id is just numbers?

Edited October 2, 2006 by phiban

[The Apache]

ok, ignore the programming info.

do this:

go to start, click on run, type in: regedit

now, click on the following:

1) HKEY_LOCAL_MACHINE

2) SOFTWARE

3) Microsoft

4) Windows NT

5) CurrentVersion

here's a screenshot:

[prx984]

thats product ID not product KEY

product key is usually "XXXXX-XXXXX-XXXXX-XXXXX-XXXXX"

25 characters

[Plamdi]

'==========================================================================
' NAME: GetCDKeyandSerialNumber.vbs
'
' AUTHOR: Mark D. MacLachlan , The Spider's Parlor
' URL: http://www.thespidersparlor.com
' DATE  : 3/16/2006
' (C) 2006, All Rights Reserved
'
' COMMENT:
'
'==========================================================================
Set WshShell = CreateObject("wscript.Shell")
Set WshNetwork = WScript.CreateObject("WScript.Network")
Set env = WshShell.environment("Process")
strComputer = env.Item("Computername")
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Const HKEY_LOCAL_MACHINE = &H80000002
Const UnInstPath = "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\"
Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" &_
".\root\default:StdRegProv")
strDigitalProductId="HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\DigitalProductId"
strXPKey=GetKey(WshShell.RegRead(strDigitalProductId))
Set colItems = objWMIService.ExecQuery("Select * from Win32_OperatingSystem",,48)
For Each objItem in colItems
	report = report &  "Original CD Key:"& strXPKey & vbCrLf
	report = report &  "SerialNumber: " & objItem.SerialNumber & vbCrLf
Next
MsgBox report

Function GetKey(rpk)
  Const rpkOffset=52:i=28
  szPossibleChars="BCDFGHJKMPQRTVWXY2346789"

  Do 'Rep1
  dwAccumulator=0 : j=14
	Do
	  dwAccumulator=dwAccumulator*256
	  dwAccumulator=rpk(j+rpkOffset)+dwAccumulator
	  rpk(j+rpkOffset)=(dwAccumulator\24) and 255  
	  dwAccumulator=dwAccumulator Mod 24
	  j=j-1
	Loop While j>=0
	i=i-1 : szProductKey=mid(szPossibleChars,dwAccumulator+1,1)&szProductKey
	if (((29-i) Mod 6)=0) and (i<>-1) then
	i=i-1 : szProductKey="-"&szProductKey
	End If
  Loop While i>=0 'Goto Rep1

GetKey=szProductKey
End Function

'
' WMI Script - ChangeVLKey.vbs
'
' This script changes the product key on the computer
'
'***************************************************************************

ON ERROR RESUME NEXT


if Wscript.arguments.count<1 then
   Wscript.echo "Script can't run without VolumeProductKey argument"
   Wscript.echo "Correct usage: Cscript ChangeVLKey.vbs ABCDE-FGHIJ-KLMNO-PRSTU-WYQZX"
   Wscript.quit
end if

Dim VOL_PROD_KEY
VOL_PROD_KEY = Wscript.arguments.Item(0)
VOL_PROD_KEY = Replace(VOL_PROD_KEY,"-","") 'remove hyphens if any
for each Obj in GetObject("winmgmts:{impersonationLevel=impersonate}").InstancesOf ("win32_WindowsProductActivation")

   result = Obj.SetProductKey (VOL_PROD_KEY)

   if err <> 0 then
	  WScript.Echo Err.Description, "0x" & Hex(Err.Number)
	  Err.Clear
   end if

Next

I think this is by the same author, apologies script has been modded, I've restored it to the best of my ability to be the original version.

Edited October 3, 2006 by Plamdi

[phiban]

Thanks for the help Plamdi! thanks everyone!