Delte all %WinDir%\*.bmp BUT ONE.

[BoardBabe]

I'd like to delete all *.bmp files in %WinDir% but boot.bmp in my cleanup.cmd.

whats the best way to do this?

[gosherm]

REN %WinDir%\boot.bmp boot.pmb
del %WinDir%\*.bmp /F /Q
REN %WinDir%\boot.pmb boot.bmp

It's cheap, but you'll be able to figure out what's going on when you look at it again a year from now

Edited November 16, 2005 by gosherm

[BoardBabe]

lol yeh that's a cheap way of doing it.. anyone else?

[oioldman]

@gosherm, exactly they way my head was going with that.

[gosherm]

Ok, how about this?

for /F "usebackq" %%i in (`dir /b %WinDir%\*.bmp`) do (
  if %%i equ boot.bmp (
	REM Found boot.bmp
  ) else (
	del /f /q %%i
  )
)

My suggestion is to still use the first solution as

1) it is cleaner and

2) it has less overhead

Edit:

Hmm... I suppose this could actually be simplified a little bit to:

for /F "usebackq" %%i in (`dir /b %WinDir%\*.bmp`) do (
  if %%i neq boot.bmp (
	del /f /q %%i
  )
)

Edited November 16, 2005 by gosherm

[BoardBabe]

Your last example there seems to be more like what im looking for.

[gosherm]

Glad I could be of service

[BoardBabe]

Now how about if there are TWO files i'd not like to delete. (Just for learning how this works...)

eg. boot1.bmp and boot2.bmp

Oh.. and it did'nt work

It searched for the file in the location where the batch were executed.

I put a testbatch on C:\ and the result were

C:\>test2.cmd

Finner ikke C:\Blå

Finner ikke C:\Bobler.bmp

Finner ikke C:\Fjær.bmp

Finner ikke C:\Fluefisker.bm

Finner ikke C:\Jade.bmp

Finner ikke C:\Kaffekopp.bmp

Finner ikke C:\Pastell.bmp

Finner ikke C:\Rododendron.b

Finner ikke C:\Santa

Finner ikke C:\Storm

Finner ikke C:\Ullteppe.bmp

Edited November 16, 2005 by BoardBabe

[gosherm]

%windir% is going to be your windows folder (i.e. c:\windows), not the drive root (%systemdrive%). It shouldn't have removed any files from C:\.

As far as multiple files, this is where the second solution gets messy because the IF statement can't handle complex statements (i.e. if (a=b OR a=c) then). So, you're left with:

for /F "usebackq" %%i in (`dir /b %WinDir%\*.bmp`) do (
  if %%i neq boot.bmp (
	if %%i neq boot2.bmp (
	  del /f /q %%i
	)
  )
)

Whereas the first solution gives you:

REN %WinDir%\boot.bmp boot.pmb
REN %WinDir%\boot2.bmp boot2.pmb
del %WinDir%\*.bmp /F /Q
REN %WinDir%\boot.pmb boot.bmp
REN %WinDir%\boot2.pmb boot2.bmp

Edited November 16, 2005 by gosherm

[BoardBabe]

Hmm recheck that script, cause it deletes boot.bmp also

[gosherm]

Hmm... it shouldn't be... though I did find one problem.

Try this as a test:

for /F "usebackq tokens=*" %%i in (`dir /b %WinDir%\*.bmp`) do (
  if %%i neq boot.bmp (
	if %%i neq boot2.bmp (
	  echo deleting "%%i"
	) else (
	  echo saving "%%i"
	)
  ) else (
	echo saving "%%i"
  )
)

and this as the final:

for /F "usebackq tokens=*" %%i in (`dir /b %WinDir%\*.bmp`) do (
  if %%i neq boot.bmp (
	if %%i neq boot2.bmp (
	  del /f /q "%%i"
	)
  )
)

[BoardBabe]

Now it does exclude boot.bmp, but it's still something wrong with the path. I put this in test.cmd on c:\ and the result of #2 is (translated):

Could not find C:\Jade.bmp

Could not find C:\Pastell.bmp

etc.

Maybe it should be

del /f /q "%WinDir%\%%i"

?

[gosherm]

Doh! I think you're right... I can't believe I missed that.

[BoardBabe]

Hehe I was

Thank's for the help!

PS. the (del) /f is not needed as the files are not write protected.

Edited November 17, 2005 by BoardBabe

[BoardBabe]

This seems to work also

for /f "usebackq tokens=*" %%i in (`dir /b "%winDir%\*.bmp"`) do if %%i neq boot.bmp del /q "%WinDir%\%%i"

Edited November 19, 2005 by BoardBabe