Chip finding software

[compass]

i want to know about how to find out a chipset & other dirvers with a software

Because if we installed a fresh computer with out driver knoledge ..

we want to open & findout the chipset , audio , lan ,is their any solution ? (third party tools )

contribute ur ideas ...

Thankyou ...

[RogueSpear]

Are you looking for a GUI application? If so SiSoftware Sandra gives you more information than you'd ever want. It has customizable reports and can run in a client/server configuration as well.

If you're handy with VBscript you could always tap WMI to get the same information and that's free. Just takes a little work to get the script to your liking.

[Martin Zugec]

Have a look at project PnPBased here on MSFN. I am using it for installing software based on PnP identificator.

For installing chipset drive, I prefer using this:

'Automaticka instalacia ovladacov pre chipset a nastavenie biosu
'Martin Zugec
'12.7.2004
'20.9.2004

Option Explicit
On Error Resume Next

Dim objWMIService, objShell
Dim strComputerSystem, arrayComputerSystems, strInstallPath
Dim strTypPocitaca
Dim arrayPnP, strNIC

Set objWMIService = GetObject("winmgmts:root\cimv2")
Set arrayComputerSystems = objWMIService.InstancesOf("Win32_ComputerSystem", 48)
Set objShell = Wscript.CreateObject("Wscript.shell")

strInstallPath = Left(WScript.ScriptFullName,Len(Wscript.ScriptFullName) - Len(WScript.ScriptName + "n")) & "\"

for each strComputerSystem in arrayComputerSystems
 Select Case Trim(LCase(strComputerSystem.Model)) 
	Case "latitude d600"
 	 funcNainstalovanieChipsetu("d600")
	Case "latitude d610"
 	 funcNainstalovanieChipsetu("d610")
 	 Case "optiplex gx150"
 	 funcNainstalovanieChipsetu("gx150")
  Case "optiplex gx260"
 	 funcNainstalovanieChipsetu("gx260")
  Case "optiplex gx270"
 	 funcNainstalovanieChipsetu("gx270")
	Case "optiplex gx280"
 	 funcNainstalovanieChipsetu("gx280")
  Case Else 
 	 Call OdoslanieMailu
 End Select
next

Call RestartPocitaca

Set objWMIService = Nothing
Set arrayComputerSystems = Nothing
Set objShell = Nothing

Wscript.Quit(0)

Sub OdoslanieMailu

	Dim objEmail, objNetwork
	Dim strComputerName

	Set objEmail = CreateObject("CDO.Message")
	Set objNetwork = CreateObject("Wscript.Network")

	strComputerName = objNetwork.ComputerName

	With objEmail
   	 .From =  strComputerName & "@domain.com"
   	 .To = "USD_Install@domain.com"
   	 .Subject = "Error"
   	 .Textbody = "Nepodarilo sa nainstalovat ovladac pre chipset. Identifikator dosky je " & strComputerSystem.Model & "Pokial sa jedna o pocitac rady GX150, GX260 alebo GX270, preposlite tento mail na mzugec@pre.cz spolu s nazvom pocitaca (OptiPlex GX150 a pod). Pokial sa jedna o starsie pocitace, automaticka instalacia chipsetu nie je podporovana."
   	 .Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
   	 .Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.domain.com"
   	 .Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
   	 .Configuration.Fields.Update
   	 .Send
	End With

	Set objEmail = Nothing
	Set objNetwork = Nothing

End Sub

Function funcNainstalovanieChipsetu(strTypPocitaca)
	objShell.Run strInstallPath & strTypPocitaca & "\Chipset\setup.exe -b -s", 1, True
	'wscript.echo ". Nainstalovany chipset pre pocitac " & strTypPocitaca
End Function

Sub RestartPocitaca
	objShell.Run "shutdown.exe -r -f -t 01", 0, False
End Sub