windows xp hotfix tracker?

[graysky]

I know I read about something like this but can't find the URL. I'm looking for a util that will print a list of the installed hotfixes. Linky anyone?

[spacesurfer]

belarc advisor. google for it. there's a free version. great tool and inventories your system as well.

[gunsmokingman]

Here a VBS script that will list the installed updates on the computer.

Save As UpdatesList.vbs

Option Explicit 
 Dim Act :Set Act = CreateObject("WScript.Shell")
 Dim Fso :Set Fso = CreateObject("Scripting.FileSystemObject") 
 Dim Cmp :Cmp  = "."
 Dim Wmi :Set Wmi = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & Cmp & "\root\cimv2")
 Dim Col :Set Col = Wmi.ExecQuery("Select * from Win32_QuickFixEngineering")
 Dim Lne :Lne = Chr(171) & _
 " ------------------------------------------------------------------------------------------------- " _
 & Chr(187) 
 Dim Obj, Ts, Txt
  Txt = Act.SpecialFolders("Desktop") & "\Updates.txt"
  Set Ts = Fso.CreateTextFile(Txt)
   Ts.WriteLine Lne
   For Each Obj in Col
	Ts.WriteLine "  Hot Fix ID			 : " & Obj.HotFixID
	If Not Obj.HotFixID = "File 1" Then
	 If Len(Obj.Description) = 0 Then
	   Ts.WriteLine "  Description			: No Information"
	  Else
	   Ts.WriteLine "  Description			: " & Obj.Description
	  End If 
	  If Len(Obj.InstalledBy) = 0 Then
	   Ts.WriteLine "  Installed By		   : No Information"
	  Else
	   Ts.WriteLine "  Installed By		   : " & Obj.InstalledBy
	  End If 
	  If Len(Obj.InstalledOn) = 0 Then
	   Ts.WriteLine "  Installed On		   : No Information"
	  Else
	   Ts.WriteLine "  Installed On		   : " & Obj.InstalledOn
	  End If   
	 End If
	 If Len(Obj.ServicePackInEffect) = 0 Then
	  Ts.WriteLine "  Service Pack In Effect : No Information"
	 Else
	  Ts.WriteLine "  Service Pack In Effect : " & Obj.ServicePackInEffect
	 End If
	Ts.WriteLine Lne
   Next
   Ts.Close
  Act.Run("Notepad.exe " & Chr(34) & Txt & Chr(34)),1,True 
  Obj = MsgBox(vbcrlf & vbtab & "Did You Want To Keep This Report?" & _
			   vbCrLf & Txt & vbtab ,4132,"Keep Or Delete")
   If Obj = 7 Then Fso.DeleteFile(Txt),True