How to hide certain windows 7 updates?

[ndog]

I am trying to 'hide' certain updates in Windows 7 which are

important (1) - Update for Windows 7 (KB971033)

Optional (34) - Arabic Language Pack - Windows 7 Service Pack 1 (KB2483139)

...

Ukrainian Language Pack - Windows 7 Service Pack 1 (KB2483139)

I am doing this on about 20 laptops (different models, requires sysprep) this week for a education provider, and I would like to do via automation, eg script

As far as I am aware the windows updates database is stored here - c:\windows\softwaredistribution\Datastore\DataStore.edb

Editing this file will not be easy via script, unless someone knows how to do via powershell, vbs etc...

If I use WSUS server, can it auto hide these updates for me?

Regards

[Tripredacus]

If I use WSUS server, can it auto hide these updates for me?

If you use WSUS, as long as you do not make that update available to your users, it won't show up for them.

[ndog]

Hi everyone.

Heres how to hide updates via script. Please make sure you are connected to internet first and can see microsoft.com.

hideKBs.vbs

Dim hideupdates(7)
hideupdates(0) = "Microsoft Security Essentials - KB2267621"
hideupdates(1) = "Microsoft Security Essentials - KB2691894"
hideupdates(2) = "Bing Desktop"
hideupdates(3) = "Windows Internet Explorer 9 for Windows 7"
hideupdates(4) = "Windows Internet Explorer 9 for Windows 7 for x64-based Systems"
hideupdates(5) = "KB971033"
hideupdates(6) = "Update for Windows 7 for x64-based Systems (KB971033)"
hideupdates(7) = "KB2483139"

set updateSession = createObject("Microsoft.Update.Session")
set updateSearcher = updateSession.CreateupdateSearcher()

Set searchResult = updateSearcher.Search("IsInstalled=0 and Type='Software'")

For i = 0 To searchResult.Updates.Count-1
	set update = searchResult.Updates.Item(i)
	For j = LBound(hideupdates) To UBound(hideupdates) 
		'MsgBox hideupdates(j)
		if instr(1, update.Title, hideupdates(j), vbTextCompare) = 0 then
	  		'Wscript.echo "No match found for " & hideupdates(j)
		else
			Wscript.echo "Hiding " & hideupdates(j)
			update.IsHidden = True
		end if
	Next
Next

Have a good day

[MagicAndre1981]

Does your Script also work with foreign language Windows 7 versions?

[bphlpt]

This looks like it has real potential! It's a shame it has to be connected to the internet rather than offline, but it's better than having to do it completely manually. Now if there was only an easy way to get the full names of the all the updates you desire to hide, especially the 34 "xxxxx Language Pack - Windows 7 Service Pack 1 (KB2483139)" updates, into your script. Thanks for getting us this far!

Cheers and Regards