; usage: script.exe copy|move source [ destination ]

; CMenu settings:
; Within editor, select New Item -> Custom command.
; Add suitable caption, browse for this compiled script and then
; add into the Commandline 'copy "custom path\to\copy\to"'.
; you can just use copy or move without any
; other parameter for default destination search.
; set the append file checkbox and then click OK button to accept.

Global $action, $destination

Switch $CMDLINE[0]
Case 2
_CheckAction()
$destination = FileSelectFolder($action & ' source to', '')
If Not @error And $destination <> '' Then
$source = $CMDLINE[2]
_PerformAction()
EndIf
Case 3
_CheckAction()
$destination = FileSelectFolder($action & ' source to', '', Default, $CMDLINE[2])
If Not @error And $destination <> '' Then
$source = $CMDLINE[3]
_PerformAction()
EndIf
Case Else
_HelpMsgBox()
EndSwitch

Exit

Func _CheckAction()
; set $action to copy or move
Switch $CMDLINE[1]
Case 'copy'
$action = 'copy'
Case 'move'
$action = 'move'
Case Else
_HelpMsgBox()
EndSwitch
EndFunc

Func _HelpMsgBox()
; show a Msgbox with helpful details
Local $text = _
$CMDLINE[0] & ' parameters passed. 2 or 3 parameters required.' & @CRLF & @CRLF & _
'Command used:' & @CRLF & _
$CMDLINERAW & @CRLF & @CRLF & _
'Usage:' & @CRLF & _
'"' & @ScriptName & '" copy|move source [destination]' & @CRLF & @CRLF & _
'Description:' & @CRLF & _
'Use "copy" or "move" as 1st parameter.' & @CRLF & _
'Use a valid source file or folder as 2nd parameter.' & @CRLF & _
'Use an optional, valid destination folder path as 3rd parameter.'
MsgBox(0, Default, $text)
Exit
EndFunc

Func _PerformAction()
; call the copy or move function dependant on $action
If $action = 'copy' Then
_Copy($source, $destination)
Else
_Move($source, $destination)
EndIf
EndFunc

Func _Copy($source, $destination)
; copy file or folder
Local $oShellApp = ObjCreate("shell.application")
If Not @error Then
$oShellApp.NameSpace($destination).CopyHere($source)
EndIf
EndFunc

Func _Move($source, $destination)
; move file or folder
Local $oShellApp = ObjCreate("shell.application")
If Not @error Then
$oShellApp.NameSpace($destination).MoveHere($source)
EndIf
EndFunc

http://www.4shared.com/file/23674969/e97b1362/SendToA3X.html