@ECHO OFF
:: SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION

:: ==========================================================================
:: =  Portions of accompanying executable files (C) Microsoft Corporation   =
:: =  This includes:                                                        =
:: =  REG v2.0 Registry Console Tool For Windows 2000                       =
:: =  Portions of accompanying executable files (C) Sysinternals            =
:: =  http://www.sysinternals.com/ntw2k/freeware/pstools.shtml              =
:: =  PsLoggedOn v1.31 Logon Session Displayer                              =
:: =  PsGetSid v1.41 Translates SIDs to names and vice versa                =
:: =  EXEs should be copied onto your executable path ie %windir%\system32  =
:: =                                                                        =
:: =  Set values to avoid wizard on 1st launch.                             =
:: =  Set Interface language for the logged on user.                        =
:: =                                                                        =
:: =  Registry Key [HKEY_USERS\<SID>\Software\TUGZip]                       =
:: =  transEnable dword value is set to 1                                   =
:: =  transLanguage value is set to <language_file_name_ini>                =
:: =                                                                        =
:: ==========================================================================

:: http://www.tugzip.com/
:: TUGZip - The Free Archiving Utility - © 2002-2004 Christian Kindahl
:: silent install (innosetup)
tugzip31.exe /verysilent /sp-
:: copy language file
if not exist "c:\program files\tugzip\languages" md "c:\program files\tugzip\languages"
copy /y french.ini "c:\program files\tugzip\languages"

psloggedon -l %LOGONSERVER% | find /V "SMS" |find "\" >%TEMP%\%~n0.logon.tmp
for /F "tokens=1,2,3" %%k in (%TEMP%\%~n0.logon.tmp) do set mUser=%%m

psgetsid %mUser% | find "S-"> %TEMP%\%~n0.getsid.tmp
for /F %%k in (%TEMP%\%~n0.getsid.tmp) do set mSid=%%k

set mKey="HKU\%mSid%\Software\TUGZip"

reg add %mKey% /v "transEnable" /t REG_DWORD /d "1" /f
reg add %mKey% /v "transLanguage" /d "%ProgramFiles%\TUGZip\Languages\french.ini" /f

::set classic|explorer|combined view-style
reg add %mKey% /v "viewStyle" /t REG_DWORD /d "0" /f
::enable|disable 32 bits alpha blended icons
reg add %mKey% /v "guiXPIcons" /t REG_DWORD /d "0" /f
::enable|disable TUGzip shell extension
reg add %mKey% /v "shlEnable" /t REG_DWORD /d "1" /f
::set TUGzip version info
reg add %mKey% /v "versionInfo" /d "3" /f

GOTO EOF

:EOF
if exist %TEMP%\%~n0.*.tmp del %TEMP%\%~n0.*.tmp
set mKey=
set mUser=
set mSid=