MSFN Forums > Ashampoo Burning Studio 9

MSFN Forums > Unattended Windows Discussion & Support > Application Installs

Raoul90

Jun 17 2009, 02:26 PM

Hey,

Does someone have a working AutoIT script for Ashampoo Burning Studio 9, since the script voor v8 doesnt work with it.

Thanks in advance!

beats

Jun 17 2009, 03:03 PM

Ashampoo Burning Studio 9 uses Inno Setup, so it should be possible to install it silently with /sp- /silent /norestart.

steviewonder

Jun 17 2009, 03:07 PM

Just add pskill for default browser command or you will get the browser opening

so mine is like this so if I install Browser in a different order, they are covered:

CODE

ashampoo_burning_studio_8_804_sm.exe /VERYSILENT /SUPPRESSMSGBOXES /NORESTART /SP-
    pskill firefox.exe
        pskill IEXPLORE.EXE
        pskill opera.exe
    pskill ashampoo_burning_studio_8_804_sm.exe
    pskill burningstudio.exe

beats

Jun 17 2009, 03:17 PM

Oh, does v9 still open a browser? If that's the case, you could also use Windows native taskkill command.

TASKKILL /F /IM firefox.exe
TASKKILL /F /IM iexplore.exe

etc.

Highspeedmac

Oct 15 2009, 11:57 AM

Here is a Working Script for version 9.20. I just modified the one for version 8 to work for version 9.20.

QUOTE

; Serial number
$SN = "xxxxxx-xxxxxx-xxxxxx"

Please replace the "x"'s in the below script with your SN.

Tested: working in VM.

CODE

Opt("TrayIconDebug", 1)

; Executable file name
$EXECUTABLE = "ashampooburningstudio9.20sm.exe"
; Serial number
$SN = "xxxxxx-xxxxxx-xxxxxx"

$PreviousInstallation = RegRead("HKLM\Software\Microsoft\Windows\CurrentVersion\Uninstall\Ashampoo Burning Studio 8_is1", "InstallLocation")
If FileExists($PreviousInstallation & "\burningstudio.exe") Then
    MsgBox(0x40010, @ScriptName, "Please uninstall previous version of Ashampoo Burning Studio before using this script", 4)
    Exit
EndIf

; Disable the default internet browser (to prevent Ashampoo Burning Studio to open it)
$DefBrowser = RegRead("HKCR\HTTP\shell\open\command\", "")
RegDelete("HKCR\HTTP\shell\open\command\", "")

; Run the installer
RunWait($EXECUTABLE & " /sp- /verysilent /norestart")

; Close Ashampoo Burning Studio process
ProcessWait("burningstudio9.exe")
$PID = ProcessExists("burningstudio9.exe")
If $PID Then
    ProcessClose($PID)
EndIf

Sleep(1000)

; Kill Internet Explorer process if was started
$PID = ProcessExists("IEXPLORE.EXE")
If $PID Then
    ProcessClose($PID)
EndIf

; Settings
RegWrite("HKLM\Software\Ashampoo\Ashampoo Burning Studio 9", "RegKey", "REG_SZ", $SN)
RegWrite("HKLM\Software\Ashampoo\Ashampoo Burning Studio 9", "InfoChannelsEnabled", "REG_DWORD", "0")
RegWrite("HKLM\Software\Ashampoo\Ashampoo Burning Studio 9\ash_inet", "Enabled", "REG_DWORD", "0")

; Restore the default internet browser
RegWrite("HKCR\HTTP\shell\open\command\", "", "REG_SZ", $DefBrowser)

simpleman

Oct 23 2009, 02:37 AM

@Highspeedmac

thx for your script, works fine
only msn toolbar installation window pops up!!
Can you modify your script to kill this popup??

thx in advance

radix

Oct 24 2009, 05:44 AM

@simpleman
Try this script:

CODE

#cs ----------------------------------------------------------------------------

AutoIt Version: 3.3.0.0
Author:         myName

Ashampoo Burning Studio 9.20
Application site: http://www2.ashampoo.com/webcache/html/1/product_2_2210___USD.htm

Script Function:
    Template AutoIt script.

#ce ----------------------------------------------------------------------------

; Script Start - Add your code below here

Opt("TrayIconDebug", 1)

; Installer file name
$Installer = "ashampoo_burning_studio_9_9.20_sm.exe"
; Serial number
$SN = "xxxxxx-xxxxxx-xxxxxx"

$PreviousInstallation = RegRead("HKLM\Software\Microsoft\Windows\CurrentVersion\Uninstall\Ashampoo Burning Studio 9_is1", "InstallLocation")
If StringRight($PreviousInstallation, 1) = '\' Then
    $PreviousInstallation = StringTrimRight($PreviousInstallation, 1)
EndIf
If FileExists($PreviousInstallation & "\burningstudio9.exe") Then
    MsgBox(0x40010, @ScriptName, "Please uninstall previous version of Ashampoo Burning Studio before using this script", 4)
    Exit
EndIf

; Save and disable the default internet browser (to prevent Ashampoo Burning Studio installer to open it at the end of installation)
$DefaultHttpBrowser = RegRead("HKCR\http\shell\open\command\", "")
$DefaultHttpsBrowser = RegRead("HKCR\https\shell\open\command\", "")
RegDelete("HKCR\http\shell\open\command\", "")
RegDelete("HKCR\https\shell\open\command\", "")

; Start checking
AdlibEnable('_Adlib')

; Run the installer
RunWait($Installer & " /sp- /verysilent /norestart")

Sleep(2000)

; Settings
RegWrite("HKLM\Software\Ashampoo\Ashampoo Burning Studio 9", "RegKey", "REG_SZ", $SN)
RegWrite("HKLM\Software\Ashampoo\Ashampoo Burning Studio 9", "InfoChannelsEnabled", "REG_DWORD", "0")
RegWrite("HKLM\Software\Ashampoo\Ashampoo Burning Studio 9\ash_inet", "Enabled", "REG_DWORD", "0")

; Restore the default internet browser
RegWrite("HKCR\http\shell\open\command\", "", "REG_SZ", $DefaultHttpBrowser)
RegWrite("HKCR\https\shell\open\command\", "", "REG_SZ", $DefaultHttpsBrowser)

; Delete page folder and Desktop icon
DirRemove(@AppDataCommonDir & "\page", 1)
FileDelete(@DesktopCommonDir & "\Go to WWW.THE-PAGE.COM.lnk")

; Stop checking
AdlibDisable()

Func _Adlib()
   ; Close MSN toolbar installation process
    $PID = ProcessExists("toolbarsetup_SL1.0_ash_de-DE.exe")
    If $PID Then
        ProcessClose($PID)
    EndIf

   ; Close Ashampoo Burning Studio process
    $PID = ProcessExists("burningstudio9.exe")
    If $PID Then
        ProcessClose($PID)
    EndIf

   ; Close Internet Explorer process if was started
    $PID = ProcessExists("IEXPLORE.EXE")
    If $PID Then
        ProcessClose($PID)
    EndIf
EndFunc

Func OnAutoItStart()
   ; One script instance only
    If WinExists(@ScriptName & '_Interpreter') Then Exit
    AutoItWinSetTitle(@ScriptName & '_Interpreter')
EndFunc

Raoul90

Oct 24 2009, 09:57 AM

Thanks radix, but people probably have to edit this point: toolbarsetup_SL1.0_ash_de-DE.exe, since not everyone is GER.

radix

Oct 25 2009, 04:10 AM

I have extracted the installer using the latest version of innounp, and the only executable file I found, which can install a toolbar is {tmp}\toolbarsetup_SL1.0_ash_de-DE.exe

Raoul90

Oct 25 2009, 06:03 AM

QUOTE (radix @ Oct 25 2009, 11:10 AM)

I have extracted the installer using the latest version of innounp, and the only executable file I found, which can install a toolbar is {tmp}\toolbarsetup_SL1.0_ash_de-DE.exe

Ok, well thats weird.

Highspeedmac

Oct 27 2009, 04:00 PM

QUOTE (simpleman @ Oct 23 2009, 04:37 AM)

@Highspeedmac

thx for your script, works fine
only msn toolbar installation window pops up!!
Can you modify your script to kill this popup??

thx in advance

That's funny, I don't get any MSN popups or MSN installs with the script.. Guessing they must have updated the install...

I have since dropped this app, after finding it was burning more coasters then good CD/DVD's..

simpleman

Nov 6 2009, 01:17 AM

thx radix, works fantastic!!!

This is a "lo-fi" version of our main content. To view the full version with more information, formatting and images, please click here.